Ошибка настройки сервера

Процедура ОбработкаПроведения(Отказ, РежимПроведения)         
	//  1. Получение запросом данных документа     
	Запрос = Новый Запрос;     
	Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;     
	Запрос.Текст =         
		"ВЫБРАТЬ
		|	СписаниеНоменклатурыНоменклатура.Номенклатура КАК Номенклатура,
		|	СписаниеНоменклатурыНоменклатура.Склад КАК Склад,
		|	СУММА(СписаниеНоменклатурыНоменклатура.Количество) КАК Количество
		|ПОМЕСТИТЬ НоменклатураДокумент
		|ИЗ
		|	Документ.СписаниеНоменклатуры.Номенклатура КАК СписаниеНоменклатурыНоменклатура
		|ГДЕ
		|	СписаниеНоменклатурыНоменклатура.Ссылка = &Ссылка
		|
		|СГРУППИРОВАТЬ ПО
		|	СписаниеНоменклатурыНоменклатура.Номенклатура,
		|	СписаниеНоменклатурыНоменклатура.Склад
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	НоменклатураДокумент.Номенклатура КАК Номенклатура,
		|	НоменклатураДокумент.Склад КАК Склад,
		|	НоменклатураДокумент.Количество КАК Количество
		|ИЗ
		|	НоменклатураДокумент КАК НоменклатураДокумент";
		     
	Запрос.УстановитьПараметр("Ссылка", Ссылка);     
	РезультатЗапроса = Запрос.Выполнить();
	
	//  2. Формирование движений-расход регистра     
	Движения.РегистрХранения.Очистить();     
	ВыборкаНоменклатура = РезультатЗапроса.Выбрать();
	
	Пока ВыборкаНоменклатура.Следующий() Цикл         
		Движение = Движения.РегистрХранения.ДобавитьРасход();         
		Движение.Период = Дата;
		Движение.Склад = ВыборкаНоменклатура.Склад;
		Движение.Номенклатура = ВыборкаНоменклатура.Номенклатура;         
		Движение.Количество = ВыборкаНоменклатура.Количество;     
	КонецЦикла;
	
	//  3. Запись движений в БД     
	Движения.РегистрХранения.Записывать = Истина;     
	Движения.Записать();
	
	//  4. Запрос, получающий отрицательные остатки из регистра     
	Запрос.Текст =         
		"ВЫБРАТЬ
		|	РегистрХраненияОстатки.Номенклатура КАК Номенклатура,
		|	ПРЕДСТАВЛЕНИЕССЫЛКИ(РегистрХраненияОстатки.Номенклатура) КАК НоменклатураПредставление,
		|	-РегистрХраненияОстатки.КоличествоОстаток КАК Дефецит
		|ИЗ
		|	РегистрНакопления.РегистрХранения.Остатки(
		|			&МоментВремени,
		|			(Номенклатура, Склад) В
		|				(ВЫБРАТЬ
		|					НоменклатураДокумент.Номенклатура,
		|					НоменклатураДокумент.Склад
		|				ИЗ
		|					НоменклатураДокумент)) КАК РегистрХраненияОстатки
		|ГДЕ
		|	РегистрХраненияОстатки.КоличествоОстаток < 0";
	
			
	ГраницаКонтроля = Новый Граница(МоментВремени(), ВидГраницы.Включая);     
	Запрос.УстановитьПараметр("МоментВремени", ГраницаКонтроля);     
	РезультатЗапроса = Запрос.Выполнить();
	
	//  5. Вывод сообщений о недостатке товаров     
	Если Не РезультатЗапроса.Пустой() Тогда         
		Отказ = Истина;         
		ВыборкаОшибки = РезультатЗапроса.Выбрать();         
		Пока ВыборкаОшибки.Следующий() Цикл             
			Сообщить("Товара "+ВыборкаОшибки.НоменклатураПредставление+" недостаточно в количестве "+ВыборкаОшибки.Дефецит+" шт.");         
		КонецЦикла;     
	КонецЕсли;	
КонецПроцедуры