Розница 2.3.18.13, ошибки разрешительного режима и все с этим связанное

&НаКлиенте
Процедура РМК_РасшКартинкаЧО05НаличныеНажатиеВместо(Элемент, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	РМК_Расш_ДействиеОплата="ВыполнитьЧО05Наличные()";
	Если ПроверкаЧекаНаОшибки()=Ложь Тогда
		ВыполнитьЧО05Наличные();
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура РМК_РасшКартинкаЧО06ПлатежнаяКартаНажатиеВместо(Элемент, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	РМК_Расш_ДействиеОплата="ВыполнитьЧО06ПлатежнаяКарта()";
	Если ПроверкаЧекаНаОшибки()=Ложь Тогда
		ВыполнитьЧО06ПлатежнаяКарта();
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура РМК_РасшКартинкаЧО07СложнаяОплатаНажатиеВместо(Элемент, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	РМК_Расш_ДействиеОплата="ВыполнитьЧО07СложнаяОплата()";
	Если ПроверкаЧекаНаОшибки()=Ложь Тогда
		ВыполнитьЧО07СложнаяОплата();
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Функция ПроверкаЧекаНаОшибки()
	ЕстьОшибки=Ложь;
	ТекстОшибки="";
	ПроверкаЧекаНаОшибкиНаСервере(ЕстьОшибки,ТекстОшибки);
	Если ЕстьОшибки Тогда
		Оповещение=Новый ОписаниеОповещения("ПроверкаЧекаНаОшибкиЗавершение",ЭтаФорма);
		Кнопки=Новый СписокЗначений;
		Кнопки.Добавить(0,"Закрыть");
		Если РМК_Расш_РазрешитьПробитьЧекОшибки Тогда
			Кнопки.Добавить(1,"Пробить чек с ошибками");
		КонецЕсли;
		Кнопки.Добавить(2,"Настройка разрешения");
		ПоказатьВопрос(Оповещение,ТекстОшибки,Кнопки);
	КонецЕсли;	
	Возврат ЕстьОшибки;
КонецФункции	

&НаКлиенте
Процедура ПроверкаЧекаНаОшибкиЗавершение(Результат,ДопПараметры) ЭКСПОРТ
	Если Результат=1 И РМК_Расш_РазрешитьПробитьЧекОшибки Тогда
		Выполнить(РМК_Расш_ДействиеОплата);
	КонецЕсли;
	Если Результат=2 Тогда
		Оповещение=Новый ОписаниеОповещения("ИзменитьРазрешениеПробитьЧекОшибкиЗавершение",ЭтаФорма);
		Значение=РМК_Расш_РазрешитьПробитьЧекОшибки;
		Массив = Новый Массив;
		Массив.Добавить(Тип("Булево"));
		ОписаниеТипов = Новый ОписаниеТипов(Массив);
		ПоказатьВводЗначения(Оповещение,Значение,"Разрешить пробить чек с ошибками",ОписаниеТипов);
    КонецЕсли;
КонецПроцедуры	

&НаКлиенте
Процедура ИзменитьРазрешениеПробитьЧекОшибкиЗавершение(Результат,ДопПараметры) ЭКСПОРТ
	 РМК_Расш_РазрешитьПробитьЧекОшибки=Результат;
КонецПроцедуры	

&НаСервере()
Процедура ПроверкаЧекаНаОшибкиНаСервере(ЕстьОшибки,ТекстОшибки)
	
	ОсобенностьУчетаТабак=Перечисления.ОсобенностиУчетаНоменклатуры.ТабачнаяПродукция;
	
	Запрос=Новый Запрос;
	Массив=Новый Массив;
	Для каждого стр из Объект.Товары Цикл;
		Массив.Добавить(стр.Номенклатура);
	КонецЦикла;	
	Запрос.УстановитьПараметр("Массив",Массив);
	Запрос.Текст="ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	Номенклатура.ОсобенностьУчета КАК ОсобенностьУчета
	|ИЗ
	|	Справочник.Номенклатура КАК Номенклатура
	|ГДЕ
	|	Номенклатура.Ссылка В(&Массив)";
	
	ТЗ=Запрос.Выполнить().Выгрузить();
	
	Если ТЗ.Количество()>1 Тогда
		Если ТЗ.НайтиСтроки(Новый Структура("ОсобенностьУчета",ОсобенностьУчетаТабак)).Количество()>0 Тогда
			ЕстьОшибки=Истина;
			ТекстОшибки="В чеке есть сигареты и другие товары, 
			|нужно изменить состав чека, 
			|продажу сигарет нужно оформлять отдельным чеком";
			Возврат;
		КонецЕсли;
	КонецЕсли;
	
	Если ТЗ.Количество()=1 И ТЗ[0].ОсобенностьУчета=ОсобенностьУчетаТабак Тогда
		КоличествоКМ=Объект.АкцизныеМарки.Количество();
		КоличествоТоваров=Объект.Товары.Итог("Количество");
		ТЗ=Объект.АкцизныеМарки.Выгрузить();
		Для каждого стр из ТЗ Цикл
			GTIN=""+стр.КодАкцизнойМарки;
			Если Лев(GTIN,1)="(" Тогда
				GTIN=Сред(GTIN,5,14);
			Иначе 
				GTIN=Сред(GTIN,1,14);
			КонецЕсли;
			стр.КодАкцизнойМарки=GTIN;
		КонецЦикла;	
		Запрос.УстановитьПараметр("ТЗ",ТЗ);
		Запрос.Текст="ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	ТЗ.КодАкцизнойМарки КАК КодАкцизнойМарки
		|ПОМЕСТИТЬ ВТ_ТЗ
		|ИЗ
		|	&ТЗ КАК ТЗ
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	ВТ_ТЗ.КодАкцизнойМарки КАК КодАкцизнойМарки,
		|	ОписаниеGTINИС.ВидУпаковки КАК ВидУпаковки
		|ПОМЕСТИТЬ ВТ2
		|ИЗ
		|	ВТ_ТЗ КАК ВТ_ТЗ
		|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОписаниеGTINИС КАК ОписаниеGTINИС
		|		ПО ВТ_ТЗ.КодАкцизнойМарки = ОписаниеGTINИС.GTIN
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	ВТ2.ВидУпаковки КАК ВидУпаковки
		|ИЗ
		|	ВТ2 КАК ВТ2";
		ТЗ2=Запрос.Выполнить().Выгрузить();
		Если ТЗ2.Количество()>1 Тогда
			ЕстьОшибки=Истина;
			ТекстОшибки="В чеке присутствуют пачки и блоки сигарет"+символы.ПС+
			"количество кодов маркировки "+xmlстрока(КоличествоКМ)+символы.ПС+
			"не соответствует количеству товаров "++xmlстрока(КоличествоТоваров)+символы.ПС+
			"продажу блоков сигарет нужно оформлять отдельным чеком";
			Возврат;
		КонецЕсли;
		Для каждого стр из Объект.АкцизныеМарки Цикл
			МРЦ=МРЦ_КМ_Табак(""+стр.КодАкцизнойМарки);
			НомерСтрокиТовары=стр.КлючСвязи-1;
			Если НомерСтрокиТовары>Объект.Товары.Количество()-1 Тогда
				ЕстьОшибки=Истина;
				ТекстОшибки="Чек нужно очистить или аннулировать";
				Возврат;
			КонецЕсли;	
			стрТ=Объект.Товары[НомерСтрокиТовары];
			Если МРЦ<>стрТ.Цена Тогда
				ЕстьОшибки=Истина;
				ТекстОшибки="Строка "+стр.КлючСвязи+" "+стрТ.Номенклатура+Символы.ПС+
				" цена "+xmlстрока(стрТ.Цена)+" <> МРЦ "+xmlстрока(МРЦ)+Символы.ПС;
			КонецЕсли;
		КонецЦикла;	
	КонецЕсли;	
КонецПроцедуры

&НаСервереБезКонтекста
Функция МРЦ_КМ_Табак(ШК)
	
	Если Лев(ШК,1)="(" Тогда
		МРЦ=0;
		Попытка
			МРЦ=Число(Прав(ШК,6))/1000;
		Исключение
		КонецПопытки;
		Возврат МРЦ;
	КонецЕсли;	
    
	Если СтрДлина(ШК)=28 тогда //ШК с криптохвостом
		МРЦСтрокой=Сред(ШК,21,4);
	Иначе
		МРЦСтрокой=Прав(ШК,4);
	КонецЕсли;	
	РезультатПроверки = Новый Структура("ЭтоМРЦ, ЗначениеМРЦ", Ложь, 0);
	МРЦ        = 0;
	АлфавитМРЦ = ДопустимыеСимволыВКодеМаркировки().БуквыЦифрыЗнакиМРЦ;
	
	Для Индекс = 1 По СтрДлина(МРЦСтрокой) Цикл
		Символ = Сред(МРЦСтрокой, Индекс, 1);
		ИндексСимвола = СтрНайти(АлфавитМРЦ, Символ) - 1;
		МРЦ = МРЦ + Pow(80, 4 - Индекс) * ИндексСимвола;
	КонецЦикла;
	
	Возврат МРЦ/100;
	
КонецФункции

&НаСервереБезКонтекста
Функция ДопустимыеСимволыВКодеМаркировки()
	Алфавит = Новый Структура;
	Алфавит.Вставить("БуквыЦифры",         "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456­789");
	Алфавит.Вставить("БуквыЦифрыЗнаки",    "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456­789!”""%&’'()*+,-./_:;=<>?");
	Алфавит.Вставить("БуквыЦифрыЗнакиМРЦ", "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456­789!""%&'*+-./_,:;=<>?");
	Алфавит.Вставить("Цифры",              "0123456789");
	Возврат Алфавит;
КонецФункции