Сравнение с временной таблицей в запросе

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3

Внимание! Тема закрыта. Добавлять сообщения в закрытую тему запрещено.

1. evoo 8 20.11.13 10:40 Сейчас в теме

Нужно получить список спецодежды, которая положена сотруднику, но не передана ему.
Во временную таблицу я получаю список спецодежды, которая передана сотруднику и положена ему. Далее нужно получить список групп спецодежды, которая положена сотруднику, но не передана ему, сравнивая с полученной временной таблицей.
НО запрос ничего не выдает...
P.S. Если поменять условие на получения списка спецодежды, которая положена сотруднику и передана, то все работает.

Вот запрос:

ВЫБРАТЬ
	     ПередачаМатериаловВЭксплуатациюСпецодежда.ФизЛицо КАК ФизЛицо,
	     ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование КАК ГруппаСпецодежды
	     	ПОМЕСТИТЬ ПередачаСпецодежда
	ИЗ Документ.ПередачаМатериаловВЭксплуатацию.Спецодежда КАК ПередачаМатериаловВЭксплуатациюСпецодежда
	    	ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ЛичныеКарточки.НормыСотрудника КАК ЛичныеКарточкиНормыСотрудника
	     	ПО ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо = ПередачаМатериаловВЭксплуатациюСпецодежда.ФизЛицо 
	ГДЕ
	     ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Проведен = ИСТИНА
		 И ДОБАВИТЬКДАТЕ(ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Дата,Месяц,ПередачаМатериаловВЭксплуатациюСпецодежда.НазначениеИспользования.СрокПолезногоИспользования) < &ДатаКон 		
	 	 И ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование В(ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды)	
	;
	
	ВЫБРАТЬ
		ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо КАК ФизЛицо,
		ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды КАК ГруппаСпецодежды,
		ПередачаСпецодежда.ГруппаСпецодежды КАК ГруппаСпецодеждыДок	
	ИЗ Справочник.ЛичныеКарточки.НормыСотрудника КАК ЛичныеКарточкиНормыСотрудника
	    	ЛЕВОЕ СОЕДИНЕНИЕ ПередачаСпецодежда КАК ПередачаСпецодежда
	    	ПО ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо = ПередачаСпецодежда.ФизЛицо 
	       	И ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ПередачаСпецодежда.ГруппаСпецодежды   
	ГДЕ
		  ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = NULL

Показать

Помогите, пожалуйста, кого не затруднит :)

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. m-serg74 46 20.11.13 10:51 Сейчас в теме

(1) evoo,

ГДЕ
ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = NULL

лажа какая то, не вникая в суть происходящего может

    ГДЕ
          ПередачаСпецодежда.ГруппаСпецодежды IS NULL

3. evoo 8 20.11.13 10:58 Сейчас в теме

(2) m-serg74, это был последний из моих вариантов))

ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка) 
НЕ ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ПередачаСпецодежда.ГруппаСпецодежды

Выдает пусто...

А

ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ПередачаСпецодежда.ГруппаСпецодежды

прекрасно выдает список спецодежды, которая передана и положена, но мне нужно обратное..)

IS NULL, тоже не работает.

4. m-serg74 46 20.11.13 11:03 Сейчас в теме

(3) evoo,

    ВЫБРАТЬ
        ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо КАК ФизЛицо,
        ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды КАК ГруппаСпецодежды

а есть реквизит то вообще
ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды

5. m-serg74 46 20.11.13 11:04 Сейчас в теме

(4) m-serg74, и в первом запросе пакета
вместо

ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование КАК ГруппаСпецодежды

ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель КАК ГруппаСпецодежды

6. evoo 8 20.11.13 11:05 Сейчас в теме

(4) m-serg74, да, есть) Загвоздка только в отборе нужных записей

7. m-serg74 46 20.11.13 11:10 Сейчас в теме

(6) evoo, на (5) что скажем?

8. evoo 8 20.11.13 11:13 Сейчас в теме

(7) m-serg74, ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды - это строка, поэтому я меру Наименование. Без него условие

И ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ПередачаСпецодежда.ГруппаСпецодежды

не срабатывает

9. m-serg74 46 20.11.13 11:19 Сейчас в теме

(8) evoo, а это что такое?

И ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование В(ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды)

что из себя представляют реквизиты ваших справочников?
ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды - это ссылка, строка, списокзначений????

13. adva 45 20.11.13 11:23 Сейчас в теме

(9) Дававь еще к таблице типы значения ТипЗначения(ГруппаСпецодежды), чтобы посмотреть чего там

11. adva 45 20.11.13 11:22 Сейчас в теме

(8) А зачем тогда ГруппаСпецодежды сравниваешь с пустой ссылкой?

12. evoo 8 20.11.13 11:23 Сейчас в теме

(11) adva, как один из вариантов)

10. evoo 8 20.11.13 11:20 Сейчас в теме

(7) m-serg74, Если быз условий то получается вот эта табличка, Мне нужны строки, где ГруппаСпецодеждыДок равно пусто

Прикрепленные файлы:

15. m-serg74 46 20.11.13 11:25 Сейчас в теме

(10) evoo, боюсь спросить а чем отличаются обведенные красным друг от друга?

Прикрепленные файлы:

19. evoo 8 20.11.13 11:28 Сейчас в теме

(15) m-serg74, в первой строке ботинки не выданы, а в третей выданы (это для разных сотрудников, одному выданы, второму нет)

14. adva 45 20.11.13 11:24 Сейчас в теме

Интересует ТипЗначения(ГруппаСпецодеждыДок)

16. evoo 8 20.11.13 11:26 Сейчас в теме

(14) adva, это строка

17. m-serg74 46 20.11.13 11:26 Сейчас в теме

(14) adva, а что интересоваться - это Номенклатура.Родитель.Наименование, т.е. Строка

18. adva 45 20.11.13 11:27 Сейчас в теме

И пожалуй правильнее в первом запросе (ПередачаСпецодежды) делать внутреннее соединение

20. adva 45 20.11.13 11:28 Сейчас в теме

У тебя ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды никак не может быть NULL, т.к. соединение левое

21. adva 45 20.11.13 11:29 Сейчас в теме

тебе надо ПередачаСпецодежда.ГруппаСпецодежды проверять на NULL

22. adva 45 20.11.13 11:30 Сейчас в теме

ЕСТЬ NULL

23. adva 45 20.11.13 11:34 Сейчас в теме

Про первый запрос пожалуй соврал, внутреннего соединения не надо. Хотя как условие при Родитель.Наименование = NULL отрабатывает непонятно

24. evoo 8 20.11.13 11:35 Сейчас в теме

Ну конечно же

ПередачаСпецодежда.ГруппаСпецодежды IS NULL

Глаз замылился уже.. Спасибо, всё заработало! :)

25. m-serg74 46 20.11.13 11:38 Сейчас в теме

(24) evoo, а я в (2) что писал?
а еще надежнее попробуй вот так

ВЫБРАТЬ
	ПередачаМатериаловВЭксплуатациюСпецодежда.ФизЛицо КАК ФизЛицо,
	ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды КАК ГруппаСпецодежды
ПОМЕСТИТЬ ПередачаСпецодежда
ИЗ Документ.ПередачаМатериаловВЭксплуатацию.Спецодежда КАК ПередачаМатериаловВЭксплуатациюСпецодежда
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ЛичныеКарточки.НормыСотрудника КАК ЛичныеКарточкиНормыСотрудника
		ПО ПередачаМатериаловВЭксплуатациюСпецодежда.ФизЛицо = ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо 
		И ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование В(ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды)    
ГДЕ
	ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Проведен = ИСТИНА
	И ДОБАВИТЬКДАТЕ(ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Дата,Месяц,ПередачаМатериаловВЭксплуатациюСпецодежда.НазначениеИспользования.СрокПолезногоИспользования) < &ДатаКон         
;

ВЫБРАТЬ
    ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо КАК ФизЛицо,
    ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды КАК ГруппаСпецодежды,
    ПередачаСпецодежда.ГруппаСпецодежды КАК ГруппаСпецодеждыДок    
ИЗ Справочник.ЛичныеКарточки.НормыСотрудника КАК ЛичныеКарточкиНормыСотрудника
	ЛЕВОЕ СОЕДИНЕНИЕ ПередачаСпецодежда КАК ПередачаСпецодежда
		ПО ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо = ПередачаСпецодежда.ФизЛицо 
		И ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды = ПередачаСпецодежда.ГруппаСпецодежды   
ГДЕ
	ПередачаСпецодежда.ГруппаСпецодежды IS NULL

Показать

26. m-serg74 46 20.11.13 11:43 Сейчас в теме

(25) m-serg74, или можно ваще так:

ВЫБРАТЬ
    ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо КАК ФизЛицо,
    ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды КАК ГруппаСпецодежды,
ИЗ Справочник.ЛичныеКарточки.НормыСотрудника КАК ЛичныеКарточкиНормыСотрудника
	ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПередачаМатериаловВЭксплуатацию.Спецодежда КАК ПередачаМатериаловВЭксплуатациюСпецодежда
		ПО ПередачаМатериаловВЭксплуатациюСпецодежда.ФизЛицо = ЛичныеКарточкиНормыСотрудника.Ссылка.Сотрудник.ФизЛицо 
		И ПередачаМатериаловВЭксплуатациюСпецодежда.Номенклатура.Родитель.Наименование В(ЛичныеКарточкиНормыСотрудника.ГруппаСпецодежды)   
		И ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Проведен = ИСТИНА
		И ДОБАВИТЬКДАТЕ(ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка.Дата, Месяц, ПередачаМатериаловВЭксплуатациюСпецодежда.НазначениеИспользования.СрокПолезногоИспользования) < &ДатаКон         
ГДЕ
	ПередачаМатериаловВЭксплуатациюСпецодежда.Ссылка IS NULL

Показать

27. evoo 8 20.11.13 11:44 Сейчас в теме

(25) m-serg74, кто бы внимательнее посмотрел)
Попробовала, работает, а чем это надежнее?

28. m-serg74 46 20.11.13 11:44 Сейчас в теме

(27) evoo, (26) посмотри

29. evoo 8 20.11.13 11:46 Сейчас в теме

(28) m-serg74, в одном запросе, здорово! спасибо, работает

30. m-serg74 46 20.11.13 11:47 Сейчас в теме

(29) evoo, на здоровье:-)

Оставьте свое сообщение

E-mail: