Отключение колонки отчета при отсутствии данных в строках

Question

Как программно отключить поле(Колонку) при отсутствии данных по ней в строках.
То есть имеется отчет в нем есть группировка детальных записей:
"Контрагент" | "Номенклатура" | "Размер" | "Количество"

Так вот в большинстве случаев во всех строках колонки "Размер" отсутствуют данные.

Необходимо при отсутствии данных по этой колонке отключать ее использование.
[1C-CODE]Поле.Использование = Ложь;
Иначе Поле.Использование = Истина;[/1C-CODE]

Пытался в запросе создать параметр типа булево с подсчетом количества но не могу понять как этот параметр установить из запроса.
[1C-CODE]ВЫБОР
		КОГДА КОЛИЧЕСТВО(ВТ_ВсеОбъекты.Размер) > 0
			ТОГДА &ДаНет = ИСТИНА
		ИНАЧЕ &ДаНет = Истина
	КОНЕЦ КАК ДаНет[/1C-CODE]
Отчет на СКД.
Просьба условное оформление по группировке не предлагать тк не умеет СКД нулевую ширину устанавливать.
Может у кого была такая задача, тема живая и нужная давайте погутарим!

Accepted Answer

(1) параметры нельзя устанавливать из запроса. Они работают наоборот. На момент запроса параметры должны быть установлены (вместо них подставляются их значения).
Первое, что пришло в голову, это получать программно в ТЗ. Анализировать полученный ТЗ. И уже по итогу, если необходимо, скрывать колонку отчета и формировать отчет уже в табличный документ. Из минусов: двойное выполнение отчета.
Пример:
[CODE]
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
    Настройки = КомпоновщикНастроек.ПолучитьНастройки();
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	
	// 1
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки,,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);
    
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ТЗ = Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(ТЗ);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	Если ТЗ.Итог("ПолеКотороеНужноСкрыть") = 0 Тогда
		ОтключаемаяКолонка = Новый ПолеКомпоновкиДанных("ПолеКотороеНужноСкрыть");
		Для Каждого Колонка Из Настройки.Выбор.Элементы Цикл
			Если Колонка.Поле = ОтключаемаяКолонка Тогда
				Колонка.Использование = Ложь;
				Прервать;
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,, ДанныеРасшифровки);
    
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);

КонецПроцедуры[/CODE]