Таблица значений в XML файл и обратно (Управляемые формы)

&НаСервере
Функция ПолучитьДанныеТЗ()

 ДанныеТЗ = Новый ХранилищеЗначения(ТЗ.Выгрузить());
 Возврат XMLСтрока(ДанныеТЗ);

КонецФункции// ПолучитьДанныеТЗ()

&НаСервере
Процедура ЗагрузитьДанныеТЗ(Данные)

 ДанныеТЗ = XMLЗначение(Тип("ХранилищеЗначения"), Данные).Получить();
 Если ТипЗнч(ДанныеТЗ) = Тип("ТаблицаЗначений") Тогда
  ТЗ.Загрузить(ДанныеТЗ);
 КонецЕсли;

КонецПроцедуры // ЗагрузитьДанныеТЗ()

&НаКлиенте
Процедура СохранитьТЗ(Команда)
 
 ИмяФайла = ПолучитьИмяФайла(РежимДиалогаВыбораФайла.Сохранение);
 Если ПустаяСтрока(ИмяФайла) Тогда
  Возврат;
 КонецЕсли;
 
 ФайлТЗ = Новый ТекстовыйДокумент;
 ФайлТЗ.УстановитьТекст(ПолучитьДанныеТЗ());
 ФайлТЗ.Записать(ИмяФайла);
 
КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьТЗ(Команда)
 
 ИмяФайла = ПолучитьИмяФайла(РежимДиалогаВыбораФайла.Открытие);
 Если ПустаяСтрока(ИмяФайла) Тогда
  Возврат;
 КонецЕсли;
 
 ФайлТЗ = Новый ТекстовыйДокумент;
 ФайлТЗ.Прочитать(ИмяФайла);
 ЗагрузитьДанныеТЗ(ФайлТЗ.ПолучитьТекст());
 
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТЗСервер()
 
 Запрос = Новый Запрос;
 Запрос.Текст = 
  "ВЫБРАТЬ
  | ПоступлениеТоваровУслуг.Ссылка КАК Документ,
  | ПоступлениеТоваровУслуг.Контрагент,
  | ПоступлениеТоваровУслуг.Дата
  |ИЗ
  | Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг";

 ТЗ.Загрузить(Запрос.Выполнить().Выгрузить());

КонецПроцедуры // ЗаполнитьТЗСервер()

&НаКлиенте
Процедура ЗаполнитьТЗ(Команда)
 
 ЗаполнитьТЗСервер();
 
КонецПроцедуры

&НаКлиенте
Функция ПолучитьИмяФайла(Режим)
 
 ВыборФайла = Новый ДиалогВыбораФайла(Режим);
 ВыборФайла.ПолноеИмяФайла = "";
 Фильтр = "Таблица значений 1С(*.1ct)|*.1ct";
 ВыборФайла.Фильтр = Фильтр;
 ВыборФайла.МножественныйВыбор = Ложь;
 ВыборФайла.Выбрать();
 
 Возврат ВыборФайла.ПолноеИмяФайла;
 
КонецФункции

#Область Сериализация

//Функциии сериализации взяты отсюда: https://forum.infostart.ru/forum9/topic213044/
&НаСервере
Функция ПроизвестиЗаписьТаблицыВXMLСервер(ТЗ)
    
    ЗаписьXML = Новый ЗаписьXML;
    ЗаписьXML.УстановитьСтроку();
    ОбъектXDTO = СериализаторXDTO.ЗаписатьXDTO(ТЗ.Выгрузить());
    ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, ОбъектXDTO);
    Возврат ЗаписьXML.Закрыть();
    
КонецФункции

&НаСервере
Функция ПроизвестиЧтениеТаблицыИзXMLСервер(СтрокаXML)
    
    ЧтениеXML = Новый ЧтениеXML;
    ЧтениеXML.УстановитьСтроку(СтрокаXML);
    ТипОбъектаXDTO = ФабрикаXDTO.Тип("http://v8.1c.ru/8.1/data/core","ValueTable");
    ОбъектXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML,ТипОбъектаXDTO); 
    ОбъектXDTO.Проверить();
    
    ЧтениеXML.Закрыть();
    ТЗ = СериализаторXDTO.ПрочитатьXDTO(ОбъектXDTO);
	Возврат ТЗ;
    
КонецФункции
#КонецОбласти