1С ЗУП Программно Статистика персонала (Численность и текучесть кадров)

Результат = Новый ТаблицаЗначений;
	
	НашОтчет = Отчеты.СтатистикаПерсонала.Создать();
	
	СхемаОтчета = Отчеты.СтатистикаПерсонала.ПолучитьМакет("СхемаКомпоновкиДанныхКадры");
	АдресСхемы = ПоместитьВоВременноеХранилище(СхемаОтчета);
		
	Отчеты.СтатистикаПерсонала.ПередЗаполнениемОбщихИсточниковДанныхОтчета(
		СхемаОтчета.НаборыДанных);
	СтруктураОбъект = Новый Структура("СхемаКомпоновкиДанных", СхемаОтчета);
	ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбщиеИсточникиДанныхОтчета(СтруктураОбъект);
	
	Настройки = НашОтчет.КомпоновщикНастроек.ПолучитьНастройки();	
	
	//++доп свойства
	ОтчетыСервер.ЗаполнитьДополнительныеСвойства(НашОтчет, Настройки, "ЧисленностьИТекучесть", "ЧисленностьИТекучесть", "", Неопределено);
	ДопСвойства = НашОтчет.КомпоновщикНастроек.Настройки.ДополнительныеСвойства;
	ДопСвойства.Вставить("ВариантНаименование", "Численность и текучесть кадров");
	ДопСвойства.Вставить("КлючВарианта", "ЧисленностьИТекучесть");
	ДопСвойства.Вставить("КлючПредопределенногоВарианта", "ЧисленностьИТекучесть");
	ДопСвойства.Вставить("Контекст", "");
	ДопСвойства.Вставить("АдресСхемы", АдресСхемы);
	//--доп свойства
	
	//++подключение схемы
	ВариантОтчета = Справочники.ВариантыОтчетов.НайтиПоНаименованию("Численность и текучесть кадров");
	ОтчетыСервер.ИнициализироватьКомпоновщикНастроек(НашОтчет.КомпоновщикНастроек, АдресСхемы, НашОтчет, ВариантОтчета);
	//--подключение схемы
	
	ПараметрПериод = Настройки.ПараметрыДанных.Элементы.Найти("ПериодОтчета");
	СтПериод = Новый СтандартныйПериод;
	СтПериод.Вариант = ВариантСтандартногоПериода.ПрошлыйГод;
	ПараметрПериод.Значение = СтПериод;
	
	ЗначениеПараметра = Настройки.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ИспользоватьШтатноеРасписание"));
	Если ЗначениеПараметра <> Неопределено Тогда
		ЗначениеПараметра.Значение = ПолучитьФункциональнуюОпцию("ИспользоватьШтатноеРасписание");
	КонецЕсли;

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаОтчета, Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ПроцессорВывода.УстановитьОбъект(Результат);

	ПроцессорВывода.Вывести(ПроцессорКомпоновки);