Регламентированная отчетность: Расчет по страховым взносам. База ЗУП 3.1. Не заполняется плательщик.

Функция ПолучитьПоКодамСведенияОПредставителе(Организация, КодНО, КПП = Неопределено) Экспорт
	
	ТипПодписанта = "1";
	флПредставительЮрЛицо = Истина;
	НаименованиеОрганизацииПредставителя = "";
	ФИОПредставителя = "";
	ПредставительСсылка = Неопределено;
	ДокументПредставителя = "";
	               	
	Запрос = Новый Запрос;
	
	ТекстЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1
	               |	РегистрацииВНалоговомОргане.Представитель,
	               |	РегистрацииВНалоговомОргане.УполномоченноеЛицоПредставителя,
	               |	РегистрацииВНалоговомОргане.ДокументПредставителя
	               |ИЗ
	               |	Справочник.РегистрацииВНалоговомОргане КАК РегистрацииВНалоговомОргане
	               |ГДЕ
	               |	(РегистрацииВНалоговомОргане.Владелец = &Организация
				   |			ИЛИ РегистрацииВНалоговомОргане.Владелец = &ГоловнаяОрганизация)
				   |	И РегистрацииВНалоговомОргане.Код = &КодНО
				   |	И НЕ РегистрацииВНалоговомОргане.ПометкаУдаления";
				   
	Запрос.УстановитьПараметр("Организация", Организация);
	Запрос.УстановитьПараметр("КодНО", КодНО);
	Запрос.УстановитьПараметр("ГоловнаяОрганизация", РегламентированнаяОтчетность.ГоловнаяОрганизация(Организация));
		
	Если КПП <> Неопределено Тогда
		ТекстЗапроса = ТекстЗапроса + " И РегистрацииВНалоговомОргане.КПП = &КПП";
		Запрос.УстановитьПараметр("КПП", КПП);
	КонецЕсли;
	
	Запрос.Текст = ТекстЗапроса;
	
	Выборка = Запрос.Выполнить().Выбрать();
	Если Выборка.Следующий() И ЗначениеЗаполнено(Выборка.Представитель) Тогда
		ТипПодписанта = "2";
		ПредставительСсылка = Выборка.Представитель;
		ДокументПредставителя = Выборка.ДокументПредставителя;
		
		Если НЕ РегламентированнаяОтчетность.ПредставительЯвляетсяФизЛицом(Выборка.Представитель) Тогда
			
			флПредставительЮрЛицо = Истина;
			
			НаименованиеОрганизацииПредставителя = СокрЛП(ПредставительСсылка);
			
			Если ТипЗнч(ПредставительСсылка) = Тип("СправочникСсылка.Контрагенты")
			   И НЕ ПредставительСсылка.Метаданные().Реквизиты.Найти("НаименованиеПолное") = Неопределено
			   И ЗначениеЗаполнено(ПредставительСсылка.НаименованиеПолное) Тогда
			   
				НаименованиеОрганизацииПредставителя = СокрЛП(ПредставительСсылка.НаименованиеПолное);
					
			КонецЕсли;
						
			ФИОПредставителя = СокрЛП(Выборка.УполномоченноеЛицоПредставителя);
			
		Иначе
			
			флПредставительЮрЛицо = Ложь;
						
			ФИОПредставителя = СокрЛП(ПредставительСсылка);
			
			Если ТипЗнч(ПредставительСсылка) = Тип("СправочникСсылка.ФизическиеЛица")
			   И НЕ ПредставительСсылка.Метаданные().Реквизиты.Найти("ФИО") = Неопределено
			   И ЗначениеЗаполнено(ПредставительСсылка.ФИО) Тогда
			   
				ФИОПредставителя = СокрЛП(ПредставительСсылка.ФИО);
					
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЕсли;
	
	Результат = Новый Структура;
	Результат.Вставить("ТипПодписанта", ТипПодписанта);
	Результат.Вставить("флПредставительЮрЛицо", флПредставительЮрЛицо);
	Результат.Вставить("НаименованиеОрганизацииПредставителя", НаименованиеОрганизацииПредставителя);
	Результат.Вставить("ФИОПредставителя", ФИОПредставителя);
	Результат.Вставить("ПредставительСсылка", ПредставительСсылка);
	Результат.Вставить("ДокументПредставителя", ДокументПредставителя);
	
	Возврат Результат;						 
							 
КонецФункции