1С, не могу добавить данные из запроса на внешнюю печатную форму (внешняя обработка)

Question

Здравствуйте, 2 день бьюсь с внешней обработкой, суть в чем. Макет, на нем нужны данные из Справочника Организации и Справочника Контрагенты, в 3-е поле успешно выводятся данные из док-та к которому подвязана внешняя обработка. Возможно не правильно построил запрос или типо того, отладчиком не умею пользоваться. Выводит пустые строки, скриншоты и код прикреплю.

[1C-CODE]Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

	УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
									КоллекцияПечатныхФорм,
									"ТестоваяПечатьДок",
									"Тестовая печать док",
									СформироватьПечатнуюФорму(МассивОбъектов[0], ОбъектыПечати));

КонецПроцедуры


// вся суть здесь
Функция СформироватьПечатнуюФорму(СсылкаНаОбъект, ОбъектыПечати)

	ТабличныйДокумент = Новый ТабличныйДокумент;
	МакетОбработки = ПолучитьМакет("МакетВнешнейОбработки_ТестПечатьДок");

	ОбластьШапки = МакетОбработки.ПолучитьОбласть("Шапка");
	ТабличныйДокумент.Вывести(ОбластьШапки);
	
	
	//СтрокаТЧ1
	ОбластьСтроки1 = МакетОбработки.ПолучитьОбласть("ШапкаТЧ1");
	ТабличныйДокумент.Вывести(ОбластьСтроки1);

	ОбластьСтроки1 = МакетОбработки.ПолучитьОбласть("ТелоТЧ1");
 	
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	               |	Организации.Наименование КАК Наименование,
	               |	Организации.ИНН КАК ИНН,
	               |	Организации.КПП КАК КПП,
	               |	Организации.КонтактнаяИнформация.(
	               |		НомерТелефона КАК НомерТелефона,
	               |		АдресЭП КАК АдресЭП
	               |	) КАК КонтактнаяИнформация
	               |ИЗ
	               |	Справочник.Организации КАК Организации
	               |ГДЕ
	               |	Организации.Ссылка В (&Ссылка)";
	
	Запрос.УстановитьПараметр("Ссылка",СсылкаНаОбъект);
	РезультатЗапроса = Запрос.Выполнить(); 
	Выборка = РезультатЗапроса.Выбрать();  
	
	ОбластьСтроки1.Параметры.Заполнить(Выборка);
	ТабличныйДокумент.Вывести(ОбластьСтроки1); 

Это первый вариант первого поля. Ниже второй
//Пока Выборка.Следующий() Цикл 
	//	
	//	ОбластьСтроки1.Параметры.Организация = Выборка.Наименование; 
	//	ОбластьСтроки1.Параметры.ИНН = Выборка.ИНН;
	//	ОбластьСтроки1.Параметры.КПП = Выборка.КПП;
	//	//ОбластьСтроки1.Параметры.ЮрАдрес = Выборка.Сумма;
	//	//ОбластьСтроки1.Параметры.ФактАдрес = Выборка.СуммаНДС;
	//	ОбластьСтроки1.Параметры.КТ = Выборка.НомерТелефона;
	//	ОбластьСтроки1.Параметры.ЭП = Выборка.АдресЭП; 
	//	//ОбластьСтроки1.Параметры.КЛК = Выборка.Цена; 
	//	
	//ТабличныйДокумент.Вывести(ОбластьСтроки1);
	//КонецЦикла;

//Ничего не работает в интернете все заумно пишут, я не понимаю, только универ закончил, прошерстил 
//все что можно, ответ никто не выкладывает, все говорят, что исправили и тема закрыта, а как решить другим не ясно.
//второй пункт макета сделан так же поэтому на всякий закину 3, он работает с самого начала, проблем не было.

//СтрокаТЧ3   
	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ШапкаТЧ3");
	ТабличныйДокумент.Вывести(ОбластьСтроки);

	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ТелоТЧ3");

	Для Каждого ТекущаяСтрока Из СсылкаНаОбъект.Товары Цикл
			
		ОбластьСтроки.Параметры.Номенклатура = ТекущаяСтрока.Номенклатура; 
		ОбластьСтроки.Параметры.Цена = ТекущаяСтрока.Цена;
		ОбластьСтроки.Параметры.Количество = ТекущаяСтрока.Количество;
		ОбластьСтроки.Параметры.Сумма = ТекущаяСтрока.Сумма;
		ОбластьСтроки.Параметры.НДС = ТекущаяСтрока.СуммаНДС;
		
	ТабличныйДокумент.Вывести(ОбластьСтроки);
	КонецЦикла;[/1C-CODE]

Accepted Answer

Итак, решение без вывода контактного лица контрагента вот:

[CODE]//СтрокаТЧ1
	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ШапкаТЧ1");
	ТабличныйДокумент.Вывести(ОбластьСтроки);

	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ТелоТЧ1");
	
	Запрос = Новый Запрос;
	Запрос.Текст = "
        |ВЫБРАТЬ
        |    Организации.Наименование КАК Организация,
        |    Организации.ИНН КАК ИНН,
        |    Организации.КПП КАК КПП,
        |    ОрганизацииКонтактнаяИнформацияЮрАдрес.Представление КАК ЮрАдрес,
        |    ОрганизацииКонтактнаяИнформацияФактАдрес.Представление КАК ФактАдрес,
        |    ОрганизацииКонтактнаяИнформацияТелефон.Представление КАК КТ,
        |    ОрганизацииКонтактнаяИнформацияEmail.Представление КАК ЭП
        |ИЗ
        |    Справочник.Организации КАК Организации
        |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации.КонтактнаяИнформация КАК ОрганизацииКонтактнаяИнформацияФактАдрес
        |        ПО (ОрганизацииКонтактнаяИнформацияФактАдрес.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресОрганизации)
        |                И Организации.Ссылка = ОрганизацииКонтактнаяИнформацияФактАдрес.Ссылка)
        |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации.КонтактнаяИнформация КАК ОрганизацииКонтактнаяИнформацияЮрАдрес
        |        ПО (ОрганизацииКонтактнаяИнформацияЮрАдрес.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресОрганизации)
        |                И Организации.Ссылка = ОрганизацииКонтактнаяИнформацияЮрАдрес.Ссылка)
        |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации.КонтактнаяИнформация КАК ОрганизацииКонтактнаяИнформацияТелефон
        |        ПО (ОрганизацииКонтактнаяИнформацияТелефон.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонОрганизации)
        |                И Организации.Ссылка = ОрганизацииКонтактнаяИнформацияТелефон.Ссылка)
        |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации.КонтактнаяИнформация КАК ОрганизацииКонтактнаяИнформацияEmail
        |        ПО (ОрганизацииКонтактнаяИнформацияEmail.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.EmailОрганизации)
        |                И Организации.Ссылка = ОрганизацииКонтактнаяИнформацияEmail.Ссылка)
        |ГДЕ
        |    Организации.Ссылка = &Ссылка";


	Запрос.УстановитьПараметр("Ссылка",СсылкаНаОбъект.Организация);
	РезультатЗапроса = Запрос.Выполнить(); 
	Выборка = РезультатЗапроса.Выбрать();  
	Если Выборка.Следующий() Тогда
	    ОбластьСтроки.Параметры.Заполнить(Выборка);
	    ТабличныйДокумент.Вывести(ОбластьСтроки);
	КонецЕсли;    
	
	
	
//СтрокаТЧ2
	ОбластьСтроки1 = МакетОбработки.ПолучитьОбласть("ШапкаТЧ2");
	ТабличныйДокумент.Вывести(ОбластьСтроки1);

	ОбластьСтроки1 = МакетОбработки.ПолучитьОбласть("ТелоТЧ2");
	
	Запрос1 = Новый Запрос;
	Запрос1.Текст = "ВЫБРАТЬ
	                |	Контрагенты.Наименование КАК Контрагент,
	                |	Контрагенты.ИНН КАК ИНН1,
	                |	Контрагенты.КПП КАК КПП1,
	                |	КонтрагентыКонтактнаяИнформацияЮрАдрес.Представление КАК ЮрАдрес1,
	                |	КонтрагентыКонтактнаяИнформацияФактАдрес.Представление КАК ФактАдрес1,
	                |	КонтрагентыКонтактнаяИнформацияТелефон.Представление КАК КТ1,
					//| 	КонтрагентыКонтактнаяИнформацияКонтактноеЛицоКонтрагента.Представление КАК КЛК,
					|	КонтрагентыКонтактнаяИнформацияEmail.Представление КАК ЭП1
	                |ИЗ
	                |	Справочник.Контрагенты КАК Контрагенты
	                |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформацияФактАдрес
	                |		ПО (КонтрагентыКонтактнаяИнформацияФактАдрес.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресКонтрагента))
	                |			И Контрагенты.Ссылка = КонтрагентыКонтактнаяИнформацияФактАдрес.Ссылка
					//
	                |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформацияЮрАдрес
	                |		ПО (КонтрагентыКонтактнаяИнформацияЮрАдрес.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресКонтрагента))
	                |			И Контрагенты.Ссылка = КонтрагентыКонтактнаяИнформацияЮрАдрес.Ссылка
					//
	                |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформацияТелефон
	                |		ПО (КонтрагентыКонтактнаяИнформацияТелефон.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента))
	                |			И Контрагенты.Ссылка = КонтрагентыКонтактнаяИнформацияТелефон.Ссылка
					//
					//|		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформацияКонтактноеЛицо	               
					//|		ПО (КонтрагентыКонтактнаяИнформацияКонтактноеЛицо.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.КонтактноеЛицо))
	                //|			И Контрагенты.Ссылка = КонтрагентыКонтактнаяИнформацияКонтактноеЛицо.Ссылка
                    //								
	                |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформацияEmail
	                |		ПО (КонтрагентыКонтактнаяИнформацияEmail.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.EmailКонтрагента))
	                |			И Контрагенты.Ссылка = КонтрагентыКонтактнаяИнформацияEmail.Ссылка
	                |ГДЕ
	                |	Контрагенты.Ссылка = &Ссылка";
	
	Запрос1.УстановитьПараметр("Ссылка",СсылкаНаОбъект.Контрагент);
	РезультатЗапроса = Запрос1.Выполнить(); 
	Выборка1 = РезультатЗапроса.Выбрать();  
	Если Выборка1.Следующий() Тогда
	    ОбластьСтроки1.Параметры.Заполнить(Выборка1);
	    ТабличныйДокумент.Вывести(ОбластьСтроки1);
	КонецЕсли;    		
	
	
	
//СтрокаТЧ3   
	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ШапкаТЧ3");
	ТабличныйДокумент.Вывести(ОбластьСтроки);

	ОбластьСтроки = МакетОбработки.ПолучитьОбласть("ТелоТЧ3");

	Для Каждого ТекущаяСтрока Из СсылкаНаОбъект.Товары Цикл
			
		ОбластьСтроки.Параметры.Номенклатура = ТекущаяСтрока.Номенклатура; 
		ОбластьСтроки.Параметры.Цена = ТекущаяСтрока.Цена;
		ОбластьСтроки.Параметры.Количество = ТекущаяСтрока.Количество;
		ОбластьСтроки.Параметры.Сумма = ТекущаяСтрока.Сумма;
		ОбластьСтроки.Параметры.НДС = ТекущаяСтрока.СуммаНДС;
		
	ТабличныйДокумент.Вывести(ОбластьСтроки);
	КонецЦикла;
	
       
	ТабличныйДокумент.АвтоМасштаб = Истина;

	Возврат ТабличныйДокумент;[/CODE]