Прохождение аудита внешнего отчета для базы во Фреше

Форум Программирование Библиотека стандартных подсистем (БСП)

1. Glagoleva 18.03.18 14:13 Сейчас в теме

Создал внешний отчет, но он не проходит аудит по причиние:
1. Не используется программный интерфейс подсистемы "Дополнительные отчеты и обработки" БСП
- Разверните демо БСП, опубликованной на https://releases.1c.ru/project/SSL23
- В конфигураторе выгрузите в файл Пример.epf общий макет _ДемоПечатьСчетовНаОплатуПокупателю, или другой общий макет с префиксом _Демо
- Оформите модуль Вашей обработки так, как это сделано в примере

Я не понимаю что от меня хотят, отчет подключается как внешний в Бухгалтерию предпрития имеет модуль

Функция СведенияОВнешнейОбработке() Экспорт
    
    РегистрационныеДанные = Новый Структура;
    РегистрационныеДанные.Вставить("Наименование", "РВП: материальный отчет MX-20");
    РегистрационныеДанные.Вставить("БезопасныйРежим", Истина);
    РегистрационныеДанные.Вставить("Версия", "1.0.0");
   
    РегистрационныеДанные.Вставить("Вид", "ДополнительныйОтчет");
   
    РегистрационныеДанные.Вставить("Информация", "РВП: материальный отчет MX-20");
   
    тзКоманд = Новый ТаблицаЗначений;
    тзКоманд.Колонки.Добавить("Идентификатор");
    тзКоманд.Колонки.Добавить("Представление");
    тзКоманд.Колонки.Добавить("Модификатор");
    тзКоманд.Колонки.Добавить("ПоказыватьОповещение");
    тзКоманд.Колонки.Добавить("Использование");
   
    строкаКоманды = тзКоманд.Добавить();
    строкаКоманды.Идентификатор = "РВП_МатериальныйОтчетМХ20";
    строкаКоманды.Представление = "РВП: материальный отчет MX-20";
    строкаКоманды.ПоказыватьОповещение = Истина;
    строкаКоманды.Модификатор = "";
    строкаКоманды.Использование = "ОткрытиеФормы";
   
    РегистрационныеДанные.Вставить("Команды", тзКоманд);
   
   
    Возврат РегистрационныеДанные;
               
КонецФункции

Показать

Есть какое-нить видео, где показано как создать отчет который проходит аудит? или на пальцах можете объяснить чего надо 1С?

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. pun4er 18.03.18 16:01 Сейчас в теме

А вы делали то, что они сказали?

3. Glagoleva 18.03.18 18:03 Сейчас в теме

А что они сказали?

4. pun4er 18.03.18 21:57 Сейчас в теме

(3)

- Разверните демо БСП, опубликованной на https://releases.1c.ru/project/SSL23
- В конфигураторе выгрузите в файл Пример.epf общий макет _ДемоПечатьСчетовНаОплатуПокупателю, или другой общий макет с префиксом _Демо
- Оформите модуль Вашей обработки так, как это сделано в примере

5. user705522_constantin_h 35 19.03.18 11:12 Сейчас в теме

(3)Попробуйте заменить

РегистрационныеДанные.Вставить("Вид", "ДополнительныйОтчет");

на

РегистрационныеДанные.Вставить("Вид", ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет());

строкаКоманды.Использование = "ОткрытиеФормы";

на

строкаКоманды.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();

6. MaxS 2855 28.03.18 18:19 Сейчас в теме

Что-то вы не то насоветовали.
Нельзя так:
РегистрационныеДанные = Новый Структура;
РегистрационныеДанные.Вставить("

Вот пример.

Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.3.3.77");
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет();
	ПараметрыРегистрации.Версия = "1.1.0";  
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Прайс лист с изображениями и характеристиками'");
	НоваяКоманда.Идентификатор = "ПрайсЛистКартинкиХарактеристики";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

Показать

Оставьте свое сообщение

E-mail: