Поступление по ордеру

&НаСервере
Функция ПолучитьРезультатЗапросаПоПринятымТоварам(ДанныеОтбора,СкладПоступления = Неопределено,МассивЗаказов = Неопределено)
	
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("НакладнаяСсылка",         ДанныеОтбора.Ссылка);
	Запрос.УстановитьПараметр("ТекущаяДата",             ТекущаяДатаСеанса());
	Запрос.УстановитьПараметр("Соглашение",              ДанныеОтбора.Соглашение);
	Запрос.УстановитьПараметр("Договор",                 ДанныеОтбора.Договор);
	Запрос.УстановитьПараметр("СкладПоступления",        СкладПоступления);
	Запрос.УстановитьПараметр("МассивЗаказов",           МассивЗаказов);
	Запрос.УстановитьПараметр("ЗаполнитьПоПоступлениям", ИспользуетсяОперацияРаздельнойЗакупки);
	
	Запрос.Текст =
	"ВЫБРАТЬ
	|	ТаблицаОстатков.ДокументПоступления КАК ЗаказПоставщику,
	|	ТаблицаОстатков.Склад,
	|	ТаблицаОстатков.Номенклатура,
	|	ТаблицаОстатков.Номенклатура.ТипНоменклатуры КАК ТипНоменклатуры,
	|	ТаблицаОстатков.Характеристика,
	|	ТаблицаОстатков.Назначение,
	|	ТаблицаОстатков.Серия,
	|	ТаблицаОстатков.ОрдернаяСхемаПриПриемке,
	|	СУММА(ТаблицаОстатков.КОформлениюОстаток) КАК Количество
	|ИЗ
	|	(ВЫБРАТЬ
	|		ТоварыКОформлениюПоступленияОстатки.ДокументПоступления КАК ДокументПоступления,
	|		ТоварыКОформлениюПоступленияОстатки.Склад КАК Склад,
	|		ВЫБОР
	|			КОГДА ТоварыКОформлениюПоступленияОстатки.Склад.ИспользоватьОрдернуюСхемуПриПоступлении = ИСТИНА
	|					И ТоварыКОформлениюПоступленияОстатки.Склад.ДатаНачалаОрдернойСхемыПриПоступлении <= &ТекущаяДата
	|				ТОГДА ИСТИНА
	|			ИНАЧЕ ЛОЖЬ
	|		КОНЕЦ КАК ОрдернаяСхемаПриПриемке,
	|		ТоварыКОформлениюПоступленияОстатки.Номенклатура КАК Номенклатура,
	|		ТоварыКОформлениюПоступленияОстатки.Характеристика КАК Характеристика,
	|		ТоварыКОформлениюПоступленияОстатки.Назначение КАК Назначение,
	|		ТоварыКОформлениюПоступленияОстатки.Серия КАК Серия,
	|		ВЫБОР
	|			КОГДА &ЗаполнитьПоПоступлениям = ИСТИНА ТОГДА
	|				-ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоНакладнымОстаток
	|			ИНАЧЕ
	|				ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоОрдерамОстаток
	|		КОНЕЦ КАК КОформлениюОстаток
	|	ИЗ
	|		РегистрНакопления.ТоварыКПоступлению.Остатки(
	|				,
	|				ДокументПоступления В (&МассивЗаказов)
	|					ИЛИ ДокументПоступления = &Соглашение
	|					ИЛИ ДокументПоступления = &Договор
	|					ИЛИ ДокументПоступления = &НакладнаяСсылка) КАК ТоварыКОформлениюПоступленияОстатки
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ТоварыКОформлениюПоступления.ДокументПоступления,
	|		ТоварыКОформлениюПоступления.Склад,
	|		ВЫБОР
	|			КОГДА ТоварыКОформлениюПоступления.Склад.ИспользоватьОрдернуюСхемуПриПоступлении = ИСТИНА
	|					И ТоварыКОформлениюПоступления.Склад.ДатаНачалаОрдернойСхемыПриПоступлении <= &ТекущаяДата
	|				ТОГДА ИСТИНА
	|			ИНАЧЕ ЛОЖЬ
	|		КОНЕЦ КАК ОрдернаяСхемаПриПриемке,
	|		ТоварыКОформлениюПоступления.Номенклатура,
	|		ТоварыКОформлениюПоступления.Характеристика,
	|		ТоварыКОформлениюПоступления.Назначение,
	|		ТоварыКОформлениюПоступления.Серия,
	|		ВЫБОР
	|			КОГДА &ЗаполнитьПоПоступлениям = ИСТИНА ТОГДА
	|				ТоварыКОформлениюПоступления.КОформлениюПоступленийПоНакладным
	|			ИНАЧЕ
	|				ТоварыКОформлениюПоступления.КОформлениюПоступленийПоОрдерам
	|		КОНЕЦ КАК Количество
	|	ИЗ
	|		РегистрНакопления.ТоварыКПоступлению КАК ТоварыКОформлениюПоступления
	|	ГДЕ
	|		ТоварыКОформлениюПоступления.Регистратор = &НакладнаяСсылка
	|		И ТоварыКОформлениюПоступления.Активность) КАК ТаблицаОстатков
	|
	|СГРУППИРОВАТЬ ПО
	|	ТаблицаОстатков.ДокументПоступления,
	|	ТаблицаОстатков.Склад,
	|	ТаблицаОстатков.ОрдернаяСхемаПриПриемке,
	|	ТаблицаОстатков.Номенклатура,
	|	ТаблицаОстатков.Характеристика,
	|	ТаблицаОстатков.Назначение,
	|	ТаблицаОстатков.Серия
	|
	|ИМЕЮЩИЕ
	|	СУММА(ТаблицаОстатков.КОформлениюОстаток) > 0";
	
	УстановитьПривилегированныйРежим(Истина);
	
	Возврат Запрос.Выполнить();
	
КонецФункции