Windsor77

Процедура ОсновныеДействияФормыЭкспорт(Кнопка)
   Перем   ОбщаяКнига;
   
   Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
   Диалог.Заголовок = "Укажите имя файла для сохранения:";
   Диалог.ПредварительныйПросмотр = Ложь;
   Диалог.ПроверятьСуществованиеФайла = Истина;
   Диалог.Фильтр = "Файл Excel (*.xls)|*.xls";

   Если Не Диалог.Выбрать() Тогда Возврат; КонецЕсли;
   ИмяФайла = Диалог.ПолноеИмяФайла;
   П = ЭлементыФормы.ПанельРегистров;
   
   //////   Инициализация экселя
   Попытка
      Эксл = Новый COMОбъект("Excel.Application");
   Исключение
      СообщитьОбОшибке("Не удалось запустить MS Excel!");
      Возврат;
   КонецПопытки; 
   Эксл.DisplayAlerts = Ложь;
   ВрФайл = ПолучитьИмяВременногоФайла("xls");
   
   Для й = 1 По П.Страницы.Количество()-1 Цикл
      ТДок = ЭлементыФормы.Найти("Результат"+й);
      Если ТДок = Неопределено Тогда
         Эксл.Quit();
         ВызватьИсключение "Ошибка нумерации листов! Не найден ""Результат"+й+"""!";
      КонецЕсли; 
      
      ///////   Сохраняем страницу
      ТДок.Записать(ВрФайл, ТипФайлаТабличногоДокумента.XLS);

      Если ОбщаяКнига = Неопределено Тогда         /////   Создаём новую книгу, в которую будем сшивать страницы
          ОбщаяКнига = Эксл.WorkBooks.Add(ВрФайл);
         ОбщаяКнига.Windows(1).DisplayWorkbookTabs = Истина;
         ОбщаяКнига.Windows(1).TabRatio = 0.35;
      Иначе         ////   копируем в новую книгу:
         ТКнига = Эксл.WorkBooks.Add(ВрФайл);
         ТКнига.Sheets(1).Copy(, ОбщаяКнига.Sheets(ОбщаяКнига.Sheets.Count));
         ТКнига.Close();
      КонецЕсли; 
      
      ИмяЛиста = П.Страницы[й].Заголовок;
      ТЛист = ОбщаяКнига.Sheets(ОбщаяКнига.Sheets.Count);
      Попытка      // переименовать
         ТЛист.Name = ИмяЛиста;
      Исключение
         ТЛист.Name = "Регистр "+й;
      КонецПопытки; 
      ТЛист.PageSetup.LeftMargin      = 44.8;
      ТЛист.PageSetup.RightMargin      = 22.4;
      ТЛист.PageSetup.TopMargin      = 22.4;
      ТЛист.PageSetup.BottomMargin   = 22.4;
      ТЛист.PageSetup.Orientation = 1;
      ТЛист.PageSetup.FitToPagesWide = 1;
      ТЛист.PageSetup.FitToPagesTall = False;
      
      УдалитьФайлы(ВрФайл);
   КонецЦикла; 
   
   ОбщаяКнига.Sheets(1).Select();
   ОбщаяКнига.SaveAs(ИмяФайла);
   ОбщаяКнига.Close();
   Эксл.Quit();
   
   Предупреждение("Экспорт в файл " + ИмяФайла + " выполнен успешно!");
КонецПроцедуры