molodoi1sneg
Иван Иванов

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS

rem  ----------------------------------------------------------------------------
rem Ring launcher
rem
rem Required environment variables:
rem JAVA_HOME - location of a Java installation directory.
rem Optional environment variables:
rem RING_OPTS - additional Java options
rem  ----------------------------------------------------------------------------

IF NOT DEFINED JAVA_HOME (
    echo.
    echo Error: JAVA_HOME environment variable is not set.
    echo Please set the JAVA_HOME environment variable to the location of your Java installation.
    echo.
    goto error
)

set "NEW_JAVA_HOME=%JAVA_HOME:"=%"

IF NOT EXIST "!NEW_JAVA_HOME!\bin\java.exe" (
    echo.
    echo Error: "!NEW_JAVA_HOME!\bin\java.exe" is not found.
    echo Please set the JAVA_HOME environment variable to the location of your Java installation.
    echo.
    goto error
)

IF ERRORLEVEL 1 (
    echo Unexpected error. Unable to enable extensions.
    goto error
)

set RING_JAVA="%NEW_JAVA_HOME%\bin\java.exe"
set RING_MAIN="com._1c.ring.cli.Ring"

set java_opts_adds=
rem Check whether we can use additional java options
IF DEFINED RING_OPTS (
    set java_opts_adds=%RING_OPTS%
    echo Using RING_OPTS from environment variable: %RING_OPTS%.
)

set CLASSPATH="%~dp0/lib/*"

%RING_JAVA% %java_opts_adds% -cp %CLASSPATH% %RING_MAIN% %*
set ERROR_CODE=%ERRORLEVEL%
goto end

:error
rem -- If error occurred - place a flag
set ERROR_CODE=1
goto end

rem Exit
:end
IF %ERRORLEVEL% NEQ 0 (
    if %ERROR_CODE% NEQ 0 (
        set ERROR_CODE=ERRORLEVEL
    )
)
cmd /C exit /B %ERROR_CODE%