Получить остатки по всем счетам, у которых в субконто имеет тип "Склад" и "Номенклатура"

ВЫБРАТЬ
	ВидыСубконто.Ссылка КАК Ссылка
ПОМЕСТИТЬ Склады
ИЗ
	ПланСчетов.Хозрасчетный.ВидыСубконто КАК ВидыСубконто
ГДЕ
	ВидыСубконто.ВидСубконто = ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.Склады)

ИНДЕКСИРОВАТЬ ПО
	Ссылка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВидыСубконто.Ссылка КАК Ссылка
ПОМЕСТИТЬ Номенклатура
ИЗ
	ПланСчетов.Хозрасчетный.ВидыСубконто КАК ВидыСубконто
ГДЕ
	ВидыСубконто.ВидСубконто = ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура)

ИНДЕКСИРОВАТЬ ПО
	Ссылка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Склады.Ссылка КАК Ссылка
ПОМЕСТИТЬ Счета
ИЗ
	Склады КАК Склады
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Номенклатура КАК Номенклатура
		ПО Склады.Ссылка = Номенклатура.Ссылка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Рег.Счет КАК Счет,
	Рег.Субконто1 КАК Субконто1,
	Рег.Субконто2 КАК Субконто2,
	Рег.Субконто3 КАК Субконто3,
	Рег.СуммаОстаток КАК СуммаОстаток
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Остатки(
			,
			Счет В
				(ВЫБРАТЬ
					Счета.Ссылка
				ИЗ
					Счета),
			,
			) КАК Рег