Требование накладная субконто 3

Форум Программирование Общие вопросы программирования (Dev)

1. user916115 31.10.18 13:24 Сейчас в теме

Всем привет, кого не видела!:)
Бух 8.3 документ «ТребованиеНакладная»
В тч «Материалы» я добавила реквизит «Продукция» тип «СправочникСсылка.Номенклатура», этот реквизит появляется, когда «СчетаУчетаЗатратВТаблице = Истина».
Суть вопроса такова :
При проведении документа реквизит «Продукция» должен вставать в субконто3, начала разбираться совсем вся запуталась, может кто сталкивался

Прикрепленные файлы:

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

4. neuro88 31.10.18 15:04 Сейчас в теме

(1) на 20.01 открыто субконто Продукция? (ну в смысле третье субконто с типом «СправочникСсылка.Номенклатура»)

Чтобы Продукция вставала в субконто3, нужно соответствующим образом подготовить данные для формирования движений.

На примере БП3.0:

Открываете модуль объекта документа ТребованиеНакладная, далее процедуру ОбработкаПроведения. там смотрите строчку

ПараметрыПроведения = Документы.ТребованиеНакладная.ПодготовитьПараметрыПроведения(Ссылка, Отказ);

проанализировав код, понимаем, что нужный нам кусок запроса формируется в функции ТекстЗапросаСписаниеМатериалов, а именно в строках:

	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА НЕОПРЕДЕЛЕНО
	|		ИНАЧЕ Реквизиты.Субконто3
	|	КОНЕЦ КАК КорСубконто3,

таким образом, нам необходимо НЕОПРЕДЕЛЕНО заменить на ТаблицаМатериалы.Продукция
Аналогично подправить ВидКорСубконто3 в том же запросе (с НЕОПРЕДЕЛЕНО на ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура)).

5. user916115 31.10.18 16:52 Сейчас в теме

(4) спасибо, большое за помощь, я вроде все правильно сделала, но вылезла ошибка:(

Функция ТекстЗапросаСписаниеМатериалов(НомераТаблиц, ПараметрыПроведения, Реквизиты)
	
	Если НЕ Реквизиты.ЕстьМатериалы Тогда
		ПараметрыПроведения.Вставить("МатериалыРеквизиты", Неопределено);
		ПараметрыПроведения.Вставить("ТаблицаМатериалы",   Неопределено);
		Возврат "";
	КонецЕсли;
	
	НомераТаблиц.Вставить("МатериалыРеквизиты", НомераТаблиц.Количество());
	НомераТаблиц.Вставить("ТаблицаМатериалы",   НомераТаблиц.Количество());
	
	ТекстЗапроса =
	"ВЫБРАТЬ
	|	Реквизиты.Ссылка КАК Регистратор,
	|	Реквизиты.Дата КАК Период,
	|	""Списание"" КАК ТипСписания,
	|	Реквизиты.Ссылка КАК ДокументРеализации,
	|	""ТребованиеНакладная"" КАК ВидОперации,
	|	Реквизиты.Организация КАК Организация,
	|	Реквизиты.Склад.ТипСклада КАК ТипСклада,
	|	ЛОЖЬ КАК ДеятельностьНаПатенте,
	|	НЕОПРЕДЕЛЕНО КАК Контрагент,
	|	Реквизиты.ПодразделениеОрганизации КАК Подразделение,
	|	ВЫБОР
	|		КОГДА НЕ Реквизиты.СчетаУчетаЗатратВТаблице
	|				И Реквизиты.СчетЗатрат В (&Субсчета44)
	|			ТОГДА &СодержаниеСписаниеМатериаловНаИздержки
	|		КОГДА НЕ Реквизиты.СчетаУчетаЗатратВТаблице
	|				И Реквизиты.СчетЗатрат В (&Субсчета91)
	|			ТОГДА &СодержаниеСписаниеМатериаловНаПрочиеРасходы
	|		ИНАЧЕ &СодержаниеСписаниеМатериаловВПроизводство
	|	КОНЕЦ КАК Содержание
	|ИЗ
	|	Реквизиты КАК Реквизиты
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	""Материалы"" КАК ИмяСписка,
	|	&СинонимМатериалы КАК СинонимСписка,
	|	Реквизиты.Дата КАК Период,
	|	ТаблицаМатериалы.НомерСтроки КАК НомерСтроки,
	|	ТаблицаМатериалы.Счет КАК СчетУчета,
	|	ТаблицаМатериалы.Номенклатура КАК Номенклатура,
	|	Реквизиты.Склад КАК Склад,
	|	ТаблицаМатериалы.ДокументОприходования КАК ДокументОприходования,
	|	ТаблицаМатериалы.Себестоимость КАК Себестоимость,
	|	ТаблицаМатериалы.Количество КАК Количество,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.ПодразделениеЗатрат
	|		ИНАЧЕ Реквизиты.ПодразделениеЗатрат
	|	КОНЕЦ КАК КорПодразделение,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.СпособУчетаНДС
	|		ИНАЧЕ Реквизиты.СпособУчетаНДС
	|	КОНЕЦ КАК СпособУчетаНДС,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.СчетЗатрат
	|		ИНАЧЕ Реквизиты.СчетЗатрат
	|	КОНЕЦ КАК КорСчетСписания,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.НоменклатурнаяГруппа
	|		ИНАЧЕ Реквизиты.Субконто1
	|	КОНЕЦ КАК КорСубконто1,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.СтатьяЗатрат
	|		ИНАЧЕ Реквизиты.Субконто2
	|	КОНЕЦ КАК КорСубконто2,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.Продукция
	|		ИНАЧЕ Реквизиты.Субконто3
	|	КОНЕЦ КАК КорСубконто3,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы)
	|		ИНАЧЕ 1
	|	КОНЕЦ КАК ВидКорСубконто1,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.СтатьиЗатрат)
	|		ИНАЧЕ 2
	|	КОНЕЦ КАК ВидКорСубконто2,
	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА НЕОПРЕДЕЛЕНО
	|		ИНАЧЕ 3
	|	КОНЕЦ КАК ВидКорСубконто3,
	|	НЕОПРЕДЕЛЕНО КАК Комитент,
	|	НЕОПРЕДЕЛЕНО КАК ДоговорКомиссии,
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетАвансовСКомитентом,
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетРасчетовСКомитентом,
	|	НЕОПРЕДЕЛЕНО КАК ВалютаРасчетовСКомитентом,
	|	0 КАК СуммаРасчетовСКомитентом,
	|	ТаблицаМатериалы.НомерСтроки КАК НомерСтроки1,
	|	ТаблицаМатериалы.Счет КАК Счет,
	|	ТаблицаМатериалы.Номенклатура КАК Номенклатура1,
	|	ТаблицаМатериалы.ДокументОприходования КАК ДокументОприходования1,
	|	ТаблицаМатериалы.Себестоимость КАК Себестоимость1,
	|	ТаблицаМатериалы.Количество КАК Количество1,
	|	ТаблицаМатериалы.ПодразделениеЗатрат КАК ПодразделениеЗатрат,
	|	ТаблицаМатериалы.СпособУчетаНДС КАК СпособУчетаНДС1,
	|	ТаблицаМатериалы.СчетЗатрат КАК СчетЗатрат,
	|	ТаблицаМатериалы.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	|	ТаблицаМатериалы.СтатьяЗатрат КАК СтатьяЗатрат,
	|	ТаблицаМатериалы.НомерСтроки КАК НомерСтроки2,
	|	ТаблицаМатериалы.Счет КАК Счет1,
	|	ТаблицаМатериалы.Номенклатура КАК Номенклатура2,
	|	ТаблицаМатериалы.ДокументОприходования КАК ДокументОприходования2,
	|	ТаблицаМатериалы.Себестоимость КАК Себестоимость2,
	|	ТаблицаМатериалы.Количество КАК Количество2,
	|	ТаблицаМатериалы.ПодразделениеЗатрат КАК ПодразделениеЗатрат1,
	|	ТаблицаМатериалы.СпособУчетаНДС КАК СпособУчетаНДС2,
	|	ТаблицаМатериалы.СчетЗатрат КАК СчетЗатрат1,
	|	ТаблицаМатериалы.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа1,
	|	ТаблицаМатериалы.СтатьяЗатрат КАК СтатьяЗатрат1,
	|	ТаблицаМатериалы.Продукция КАК Продукция
	|ИЗ
	|	ТаблицаМатериалы КАК ТаблицаМатериалы
	|		ЛЕВОЕ СОЕДИНЕНИЕ Реквизиты КАК Реквизиты
	|		ПО (ИСТИНА)
	|
	|УПОРЯДОЧИТЬ ПО
	|	НомерСтроки";
	
	Возврат ТекстЗапроса + ОбщегоНазначенияБПВызовСервера.ТекстРазделителяЗапросовПакета();
	
КонецФункции

Показать

а вот текст ошибки

{Документ.ТребованиеНакладная.МодульМенеджера(204)}: Ошибка при вызове метода контекста (ВыполнитьПакет)
	Результат = Запрос.ВыполнитьПакет();
по причине:
{(88, 27)}: Поле не найдено "ТаблицаМатериалы.Продукция"
ТОГДА ТаблицаМатериалы.<<?>>Продукция

по причине:
{(88, 27)}: Поле не найдено "ТаблицаМатериалы.Продукция"
ТОГДА ТаблицаМатериалы.<<?>>Продукция

Показать

7. neuro88 31.10.18 18:11 Сейчас в теме

(5) моя вина.
ТаблицаМатериалы - это временная таблица.
Для устранения ошибки необходимо в функции ТекстЗапросаТаблицыДокумента добавить соответствующий реквизит ТЧ.

10. user916115 01.11.18 08:48 Сейчас в теме

(7) извините уточню) я правильно добавила же?

Функция ТекстЗапросаТаблицыДокумента(НомераТаблиц, ПараметрыПроведения, Реквизиты)
	
	ТекстЗапроса = "";
	Если Реквизиты.ЕстьМатериалы Тогда
		НомераТаблиц.Вставить("ВременнаяТаблицаМатериалы", НомераТаблиц.Количество());
		ТекстЗапроса = ТекстЗапроса +
		"ВЫБРАТЬ
		|	ТаблицаМатериалы.Ссылка КАК Ссылка,
		|	ТаблицаМатериалы.НомерСтроки КАК НомерСтроки,
		|	ТаблицаМатериалы.Номенклатура КАК Номенклатура,
		|	ТаблицаМатериалы.Количество КАК Количество,
		|	ТаблицаМатериалы.НомерГТД КАК НомерГТД,
		|	ТаблицаМатериалы.СтранаПроисхождения КАК СтранаПроисхождения,
		|	ТаблицаМатериалы.Счет КАК Счет,
		|	ЕСТЬNULL(ТаблицаМатериалы.Счет.Забалансовый, ЛОЖЬ) КАК СчетУчетаЗабалансовый,
		|	ТаблицаМатериалы.СчетЗатрат КАК СчетЗатрат,
		|	ТаблицаМатериалы.ПодразделениеЗатрат КАК ПодразделениеЗатрат,
		|	ТаблицаМатериалы.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
		|	ТаблицаМатериалы.СтатьяЗатрат КАК СтатьяЗатрат,
		|	ТаблицаМатериалы.СпособУчетаНДС КАК СпособУчетаНДС,
		|	ТаблицаМатериалы.ДокументОприходования КАК ДокументОприходования,
		|	ТаблицаМатериалы.Себестоимость КАК Себестоимость,
		|	ТаблицаМатериалы.Продукция КАК Продукция
		|ПОМЕСТИТЬ ТаблицаМатериалы
		|ИЗ
		|	Документ.ТребованиеНакладная.Материалы КАК ТаблицаМатериалы
		|ГДЕ
		|	ТаблицаМатериалы.Ссылка = &Ссылка"
		+ ОбщегоНазначенияБПВызовСервера.ТекстРазделителяЗапросовПакета();
	КонецЕсли;
	Если Реквизиты.ЕстьМатериалыЗаказчика Тогда
		НомераТаблиц.Вставить("ВременнаяТаблицаМатериалыЗаказчика", НомераТаблиц.Количество());
		ТекстЗапроса = ТекстЗапроса +
		"ВЫБРАТЬ
		|	ТаблицаМатериалыЗаказчика.Ссылка КАК Ссылка,
		|	ТаблицаМатериалыЗаказчика.НомерСтроки КАК НомерСтроки,
		|	ТаблицаМатериалыЗаказчика.Номенклатура КАК Номенклатура,
		|	ТаблицаМатериалыЗаказчика.Количество КАК Количество,
		|	ТаблицаМатериалыЗаказчика.Счет КАК Счет,
		|	ТаблицаМатериалыЗаказчика.СчетПередачи КАК СчетПередачи
		|ПОМЕСТИТЬ ТаблицаМатериалыЗаказчика
		|ИЗ
		|	Документ.ТребованиеНакладная.МатериалыЗаказчика КАК ТаблицаМатериалыЗаказчика
		|ГДЕ
		|	ТаблицаМатериалыЗаказчика.Ссылка = &Ссылка"
		+ ОбщегоНазначенияБПВызовСервера.ТекстРазделителяЗапросовПакета();
	КонецЕсли;
	
	Возврат ТекстЗапроса;
	
КонецФункции

Показать

если правильно, то у меня проблемы:( так и не встало субконто 3:(

Прикрепленные файлы:

15. neuro88 01.11.18 11:42 Сейчас в теме

(10) ничего не забыли? если судить по предыдущим сообщениям, то ВидКорСубконто3=НЕОПРЕДЕЛЕНО

Открыл типовую БП3.0 Корп.
Последовательность действий:
1) Добавляем третье субконто на счет 20.01 - номенклатура;
2) Добавляем в ТЧ Материалы реквизит Продукция и выводим его на форму;
3) изменяем текст запросов:
3.1) функция ТекстЗапросаТаблицыДокумента добавляем во временную таблицу продукцию:

|	ТаблицаМатериалы.Себестоимость,
		|	ТаблицаМатериалы.Продукция

3.2) функция ТекстЗапросаСписаниеМатериалов меняем в 2-х местах - КорСубконто3 и ВидКорСубконто3

	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ТаблицаМатериалы.Продукция
	|		ИНАЧЕ Реквизиты.Субконто3
	|	КОНЕЦ КАК КорСубконто3,

	|	ВЫБОР
	|		КОГДА Реквизиты.СчетаУчетаЗатратВТаблице
	|			ТОГДА ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура)
	|		ИНАЧЕ 3
	|	КОНЕЦ КАК ВидКорСубконто3,

4) проводим документ - третье субконто заполнено в соответствии с данными табличной части

Это естественно решение конкретной задачи, как верно заметили в (8) в реальности могут понадобиться более сложные условия для КорСубконто3 и ВидКорСубконто3. Хотя если выбрать счет без 3-го субконто - проведение не приведет к возникновению ошибок, однако делать так не рекомендую)

8. ben19791010 01.11.18 04:50 Сейчас в теме

(1)

При проведении документа реквизит «Продукция» должен вставать в субконто3

а вот интересно если будет счет, где нет 3-го субконто?
26 например
91.02 и т.д.

11. user916115 01.11.18 08:53 Сейчас в теме

(8)
воу воу погодите, до этого я еще не дошла, мне бы сейчас разобраться с этой кучей запросов, чтобы хотя бы вставало оно....:)
а кстати, я делала для этого документа подбор номенклатуры, где в условии счетРодитель 10, поэтому в этот документ и не должны др счета попадать... нуууу я так думаю... не смейтесь только если бред сказала..)

17. nomad_irk 76 05.06.20 09:27 Сейчас в теме

(1)Поздравляю, вы поставили с ног на уши производственный учет :)
То, что вы пытаетесь сделать, реализуется документом выпуска продукции, указывая в нем, какие материалы были израсходованы на выпуск продукции.
Материалы в НЗП списываются котловым методом.

2. user1078842 31.10.18 14:20 Сейчас в теме

У вас в ПС "Хозрасчетный" само это субконто есть? (по умолчанию)?

3. user916115 31.10.18 14:35 Сейчас в теме

(2)да

6. user633533_encantado 11 31.10.18 16:59 Сейчас в теме

(3) Вы табличной части документа добавили колонку "продукция", или просто на форме элемент добавили ?

"ТаблицаМатериалы" это временная таблица в запросе, где вы ее формируете ?

9. ben19791010 01.11.18 04:51 Сейчас в теме

явно же 20 счет в условие придется добавить ;)

12. acanta 01.11.18 08:53 Сейчас в теме

Официальная рекомендация заводить на каждый вид продукции отдельный элемент номенклатурой группы. Что у вас в справочнике номенклатура и что в номенклатурных группах?
Если требуется какая то укрупненная аналитика, то есть группы номенклатуры и группы номенклатурных групп, отчеты в режиме только иерархия.

13. user916115 01.11.18 09:01 Сейчас в теме

(12) не совсем поняла вопроса :) но вот:

Прикрепленные файлы:

16. user1314134 05.06.20 09:08 Сейчас в теме

(13)Добрый день. Скажите, получилось в итоге решить эту проблему?

14. acanta 01.11.18 09:16 Сейчас в теме

А что в карточке продукции?

Оставьте свое сообщение

E-mail: