как вычислить документы, которые проведены, но движений по ним нет

//1. поиск документов без движений (попросили НЕ показывать пустые проведенные ОРП)
	//2. поиск движений по непроведенным документам
	//3. поиск движений без регистратора, т.е. <объект не найден>
	//4. Поиск движений за указанный период, где:
	//			- Помещение не принадлежит указанному Складу;
	//			- Характеристика не принадлежит указанной Номенклатуре
	//			- Номенклатура помечена на удаление
	//			- Характеристика помечена на удаление
	ТекстЗапроса =
	"ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	ДокументыДляПроверки.Ссылка КАК Ссылка,
	|	ДокументыДляПроверки.Дата КАК Дата,
	|	""Проведенный документ без движений"" КАК ТипОшибки
	|ИЗ
	|	(ВЫБРАТЬ
	|		ЧекиККМ.Ссылка КАК Ссылка,
	|		ЧекиККМ.Дата КАК Дата
	|	ИЗ
	|		Документ.ЧекККМ КАК ЧекиККМ
	|	ГДЕ
	|		ЧекиККМ.Проведен
	|		И НЕ ЧекиККМ.Архивный
	|		И ЧекиККМ.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ЧекиККМ.Ссылка,
	|		ЧекиККМ.Дата
	|	ИЗ
	|		Документ.ЧекККМВозврат КАК ЧекиККМ
	|	ГДЕ
	|		ЧекиККМ.Проведен
	|		И НЕ ЧекиККМ.Архивный
	|		И ЧекиККМ.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ПоступлениеТоваровУслуг.Ссылка,
	|		ПоступлениеТоваровУслуг.Дата
	|	ИЗ
	|		Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг
	|	ГДЕ
	|		ПоступлениеТоваровУслуг.Проведен
	|		И ПоступлениеТоваровУслуг.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И ПоступлениеТоваровУслуг.УУ
	|		И НЕ ВЫБОР
	|					КОГДА ПоступлениеТоваровУслуг.Склад.ИспользоватьОрдернуюСхемуПриПоступлении
	|							И ПоступлениеТоваровУслуг.Дата >= ПоступлениеТоваровУслуг.Склад.ДатаНачалаОрдернойСхемыПриПоступлении
	|						ТОГДА ИСТИНА
	|					ИНАЧЕ ЛОЖЬ
	|				КОНЕЦ
	|		И (ПоступлениеТоваровУслуг.Товары.Номенклатура.ВидНоменклатуры.ТипНоменклатуры ЕСТЬ NULL 
	|				ИЛИ ПоступлениеТоваровУслуг.Товары.Номенклатура.ВидНоменклатуры.ТипНоменклатуры В (ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Товар), ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)))
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ОтчетОРозничныхПродажах.Ссылка,
	|		ОтчетОРозничныхПродажах.Дата
	|	ИЗ
	|		Документ.ОтчетОРозничныхПродажах КАК ОтчетОРозничныхПродажах
	|	ГДЕ
	|		ОтчетОРозничныхПродажах.Проведен
	|		И ОтчетОРозничныхПродажах.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И ОтчетОРозничныхПродажах.УУ
	|	
	|	СГРУППИРОВАТЬ ПО
	|		ОтчетОРозничныхПродажах.Ссылка,
	|		ОтчетОРозничныхПродажах.Дата
	|	
	|	ИМЕЮЩИЕ
	|		КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ОтчетОРозничныхПродажах.Ссылка.Товары.НомерСтроки) <> 0
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ОприходованиеТоваров.Ссылка,
	|		ОприходованиеТоваров.Дата
	|	ИЗ
	|		Документ.ОприходованиеИзлишковТоваров КАК ОприходованиеТоваров
	|	ГДЕ
	|		ОприходованиеТоваров.Проведен
	|		И ОприходованиеТоваров.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И ОприходованиеТоваров.УУ
	|		И НЕ ВЫБОР
	|					КОГДА ОприходованиеТоваров.Склад.ИспользоватьОрдернуюСхемуПриПоступлении
	|							И ОприходованиеТоваров.Дата >= ОприходованиеТоваров.Склад.ДатаНачалаОрдернойСхемыПриПоступлении
	|						ТОГДА ИСТИНА
	|					ИНАЧЕ ЛОЖЬ
	|				КОНЕЦ
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ПеремещениеТоваров.Ссылка,
	|		ПеремещениеТоваров.Дата
	|	ИЗ
	|		Документ.ПеремещениеТоваров КАК ПеремещениеТоваров
	|	ГДЕ
	|		ПеремещениеТоваров.Проведен
	|		И ПеремещениеТоваров.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И ПеремещениеТоваров.УУ
	|		И НЕ(ВЫБОР
	|						КОГДА ПеремещениеТоваров.СкладОтправитель.ИспользоватьОрдернуюСхемуПриОтгрузке
	|								И ПеремещениеТоваров.Дата >= ПеремещениеТоваров.СкладОтправитель.ДатаНачалаОрдернойСхемыПриОтгрузке
	|							ТОГДА ИСТИНА
	|						ИНАЧЕ ЛОЖЬ
	|					КОНЕЦ
	|					ИЛИ ВЫБОР
	|						КОГДА ПеремещениеТоваров.СкладПолучатель.ИспользоватьОрдернуюСхемуПриПоступлении
	|								И ПеремещениеТоваров.Дата >= ПеремещениеТоваров.СкладПолучатель.ДатаНачалаОрдернойСхемыПриПоступлении
	|							ТОГДА ИСТИНА
	|						ИНАЧЕ ЛОЖЬ
	|					КОНЕЦ)
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ПриходныйОрдерНаТовары.Ссылка,
	|		ПриходныйОрдерНаТовары.Дата
	|	ИЗ
	|		Документ.ПриходныйОрдерНаТовары КАК ПриходныйОрдерНаТовары
	|	ГДЕ
	|		ПриходныйОрдерНаТовары.Проведен
	|		И ПриходныйОрдерНаТовары.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		РасходныйОрдерНаТовары.Ссылка,
	|		РасходныйОрдерНаТовары.Дата
	|	ИЗ
	|		Документ.РасходныйОрдерНаТовары КАК РасходныйОрдерНаТовары
	|	ГДЕ
	|		РасходныйОрдерНаТовары.Проведен
	|		И РасходныйОрдерНаТовары.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		СписаниеТоваров.Ссылка,
	|		СписаниеТоваров.Дата
	|	ИЗ
	|		Документ.СписаниеНедостачТоваров КАК СписаниеТоваров
	|	ГДЕ
	|		СписаниеТоваров.Проведен
	|		И СписаниеТоваров.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И СписаниеТоваров.УУ
	|		И НЕ ВЫБОР
	|					КОГДА СписаниеТоваров.Склад.ИспользоватьОрдернуюСхемуПриОтгрузке
	|							И СписаниеТоваров.Дата >= СписаниеТоваров.Склад.ДатаНачалаОрдернойСхемыПриОтгрузке
	|						ТОГДА ИСТИНА
	|					ИНАЧЕ ЛОЖЬ
	|				КОНЕЦ
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		ПересортицаТоваров.Ссылка,
	|		ПересортицаТоваров.Дата
	|	ИЗ
	|		Документ.ПересортицаТоваров КАК ПересортицаТоваров
	|	ГДЕ
	|		ПересортицаТоваров.Проведен
	|		И ПересортицаТоваров.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И ПересортицаТоваров.УУ
	|		И (НЕ ВЫБОР
	|						КОГДА ПересортицаТоваров.Склад.ИспользоватьОрдернуюСхемуПриПоступлении
	|								И ПересортицаТоваров.Дата >= ПересортицаТоваров.Склад.ДатаНачалаОрдернойСхемыПриПоступлении
	|							ТОГДА ИСТИНА
	|						ИНАЧЕ ЛОЖЬ
	|					КОНЕЦ
	|				ИЛИ ПересортицаТоваров.ВидОперации В (ЗНАЧЕНИЕ(Перечисление.ВидыОперацийПересортицыТоваров.ОбменТовара), ЗНАЧЕНИЕ(Перечисление.ВидыОперацийПересортицыТоваров.ОприходованиеБрака)))
	|	
	|	ОБЪЕДИНИТЬ ВСЕ
	|	
	|	ВЫБРАТЬ
	|		РеализацияТоваровУслуг.Ссылка,
	|		РеализацияТоваровУслуг.Дата
	|	ИЗ
	|		Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
	|	ГДЕ
	|		РеализацияТоваровУслуг.Проведен
	|		И РеализацияТоваровУслуг.Дата МЕЖДУ &ДатаНач И &ДатаКон
	|		И РеализацияТоваровУслуг.УУ
	|		И НЕ ВЫБОР
	|					КОГДА РеализацияТоваровУслуг.Склад.ИспользоватьОрдернуюСхемуПриОтгрузке
	|							И РеализацияТоваровУслуг.Дата >= РеализацияТоваровУслуг.Склад.ДатаНачалаОрдернойСхемыПриОтгрузке
	|						ТОГДА ИСТИНА
	|					ИНАЧЕ ЛОЖЬ
	|				КОНЕЦ) КАК ДокументыДляПроверки
	|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
	|		ПО ДокументыДляПроверки.Ссылка = ТоварыНаСкладах.Регистратор
	|ГДЕ
	|	ТоварыНаСкладах.Регистратор ЕСТЬ NULL 
	|
	|УПОРЯДОЧИТЬ ПО
	|	Дата
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	ТоварыНаСкладах.Регистратор КАК Ссылка,
	|	ТоварыНаСкладах.Склад,
	|	ТоварыНаСкладах.Период КАК Период,
	|	ТоварыНаСкладах.Номенклатура,
	|	ТоварыНаСкладах.Характеристика,
	|	ТоварыНаСкладах.Помещение,
	|	ВЫБОР
	|		КОГДА НЕ ТоварыНаСкладах.Регистратор.Проведен
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК ДвиженияПоНепроведенномуДокументу,
	|	ВЫБОР
	|		КОГДА ТоварыНаСкладах.Регистратор.Проведен ЕСТЬ NULL 
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК РегистраторОбъектНеНайден,
	|	ВЫБОР
	|		КОГДА ТоварыНаСкладах.Помещение ССЫЛКА Справочник.СкладскиеПомещения
	|				И ТоварыНаСкладах.Помещение <> ЗНАЧЕНИЕ(Справочник.СкладскиеПомещения.ПустаяСсылка)
	|				И ТоварыНаСкладах.Помещение.Владелец <> ТоварыНаСкладах.Склад
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК ПомещениеЧужогоСклада,
	|	ВЫБОР
	|		КОГДА ТоварыНаСкладах.Характеристика ССЫЛКА Справочник.ХарактеристикиНоменклатуры
	|				И ТоварыНаСкладах.Характеристика <> ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)
	|				И ТоварыНаСкладах.Характеристика.Владелец <> ТоварыНаСкладах.Номенклатура
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК ХарактеристикаЧужойНоменклатуры,
	|	ВЫБОР
	|		КОГДА ТоварыНаСкладах.Номенклатура.ПометкаУдаления
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК НоменклатураПомеченаНаУдаление,
	|	ВЫБОР
	|		КОГДА ТоварыНаСкладах.Характеристика.ПометкаУдаления
	|			ТОГДА ИСТИНА
	|		ИНАЧЕ ЛОЖЬ
	|	КОНЕЦ КАК ХарактеристикаПомеченаНаУдаление
	|ПОМЕСТИТЬ АнализДвиженийТоваровНаСкладах
	|ИЗ
	|	РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
	|ГДЕ
	|	ТоварыНаСкладах.Период МЕЖДУ &ДатаНач И &ДатаКон
	|	И (ВЫБОР
	|				КОГДА НЕ ТоварыНаСкладах.Регистратор.Проведен
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ
	|			ИЛИ ВЫБОР
	|				КОГДА ТоварыНаСкладах.Регистратор.Проведен ЕСТЬ NULL 
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ
	|			ИЛИ ВЫБОР
	|				КОГДА ТоварыНаСкладах.Помещение ССЫЛКА Справочник.СкладскиеПомещения
	|						И ТоварыНаСкладах.Помещение <> ЗНАЧЕНИЕ(Справочник.СкладскиеПомещения.ПустаяСсылка)
	|						И ТоварыНаСкладах.Помещение.Владелец <> ТоварыНаСкладах.Склад
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ
	|			ИЛИ ВЫБОР
	|				КОГДА ТоварыНаСкладах.Характеристика ССЫЛКА Справочник.ХарактеристикиНоменклатуры
	|						И ТоварыНаСкладах.Характеристика <> ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)
	|						И ТоварыНаСкладах.Характеристика.Владелец <> ТоварыНаСкладах.Номенклатура
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ
	|			ИЛИ ВЫБОР
	|				КОГДА ТоварыНаСкладах.Номенклатура.ПометкаУдаления
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ
	|			ИЛИ ВЫБОР
	|				КОГДА ТоварыНаСкладах.Характеристика.ПометкаУдаления
	|					ТОГДА ИСТИНА
	|				ИНАЧЕ ЛОЖЬ
	|			КОНЕЦ)
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	ТоварыНаСкладах.Ссылка КАК Ссылка,
	|	ТоварыНаСкладах.Склад,
	|	""Движения по НЕ проведенному документу"" КАК ТипОшибки,
	|	ТоварыНаСкладах.Период
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК ТоварыНаСкладах
	|ГДЕ
	|	ТоварыНаСкладах.ДвиженияПоНепроведенномуДокументу
	|
	|УПОРЯДОЧИТЬ ПО
	|	ТоварыНаСкладах.Период
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	ТоварыНаСкладах.Ссылка КАК Ссылка,
	|	ТоварыНаСкладах.Склад,
	|	""Регистратор <Объект не найден>"" КАК ТипОшибки,
	|	ТоварыНаСкладах.Период КАК Период
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК ТоварыНаСкладах
	|ГДЕ
	|	ТоварыНаСкладах.РегистраторОбъектНеНайден
	|
	|УПОРЯДОЧИТЬ ПО
	|	Период
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	АнализДвиженийТоваровНаСкладах.Ссылка,
	|	АнализДвиженийТоваровНаСкладах.Склад,
	|	""Помещение не принадлежит указанному Складу"" КАК ТипОшибки,
	|	АнализДвиженийТоваровНаСкладах.Помещение,
	|	АнализДвиженийТоваровНаСкладах.Период КАК Период
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК АнализДвиженийТоваровНаСкладах
	|ГДЕ
	|	АнализДвиженийТоваровНаСкладах.ПомещениеЧужогоСклада
	|
	|УПОРЯДОЧИТЬ ПО
	|	Период
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	АнализДвиженийТоваровНаСкладах.Ссылка КАК Ссылка,
	|	АнализДвиженийТоваровНаСкладах.Склад,
	|	""Характеристика не принадлежит указанной Номенклатуре"" КАК ТипОшибки,
	|	АнализДвиженийТоваровНаСкладах.Период,
	|	АнализДвиженийТоваровНаСкладах.Номенклатура,
	|	АнализДвиженийТоваровНаСкладах.Характеристика
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК АнализДвиженийТоваровНаСкладах
	|ГДЕ
	|	АнализДвиженийТоваровНаСкладах.ХарактеристикаЧужойНоменклатуры
	|
	|УПОРЯДОЧИТЬ ПО
	|	АнализДвиженийТоваровНаСкладах.Период
	|ИТОГИ ПО
	|	Ссылка
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	АнализДвиженийТоваровНаСкладах.Ссылка КАК Ссылка,
	|	АнализДвиженийТоваровНаСкладах.Склад,
	|	""Используется номенклатура, помеченная на удаление"" КАК ТипОшибки,
	|	АнализДвиженийТоваровНаСкладах.Период КАК Период,
	|	АнализДвиженийТоваровНаСкладах.Номенклатура
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК АнализДвиженийТоваровНаСкладах
	|ГДЕ
	|	АнализДвиженийТоваровНаСкладах.НоменклатураПомеченаНаУдаление
	|
	|УПОРЯДОЧИТЬ ПО
	|	Период
	|ИТОГИ ПО
	|	Ссылка
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	АнализДвиженийТоваровНаСкладах.Ссылка КАК Ссылка,
	|	АнализДвиженийТоваровНаСкладах.Склад,
	|	""Используется характеристика, помеченная на удаление"" КАК ТипОшибки,
	|	АнализДвиженийТоваровНаСкладах.Период КАК Период,
	|	АнализДвиженийТоваровНаСкладах.Номенклатура,
	|	АнализДвиженийТоваровНаСкладах.Характеристика
	|ИЗ
	|	АнализДвиженийТоваровНаСкладах КАК АнализДвиженийТоваровНаСкладах
	|ГДЕ
	|	АнализДвиженийТоваровНаСкладах.ХарактеристикаПомеченаНаУдаление
	|
	|УПОРЯДОЧИТЬ ПО
	|	Период
	|ИТОГИ ПО
	|	Ссылка";
	
	Запрос = Новый Запрос;
	Запрос.Текст = ТекстЗапроса;
	Запрос.УстановитьПараметр("ДатаНач", ПараметрыВыполнения.ПериодОт);
	Запрос.УстановитьПараметр("ДатаКон", ПараметрыВыполнения.ПериодДо);