Неудачный обмен данными УТ 8 ред.11 и БП 8.2

Запрос = Новый Запрос;
Для Каждого СвойствоПоиска Из СвойстваПоиска Цикл
	Запрос.УстановитьПараметр(СвойствоПоиска.Ключ, СвойствоПоиска.Значение);
КонецЦикла;

Если НЕ СвойстваПоиска.Получить("ИспользуетсяПриОбменеДанными") = Неопределено Тогда
	
	// Осуществляем поиск по реквизитам
	Запрос.Текст = "ВЫБРАТЬ
	               |	ДоговорыКонтрагентов.Ссылка
	               |ИЗ
	               |	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
	               |ГДЕ
	               |	ДоговорыКонтрагентов.ВидДоговора = &ВидДоговора
	               |	И ДоговорыКонтрагентов.Организация = &Организация
	               |	И ДоговорыКонтрагентов.Владелец = &Владелец
	               |	И ДоговорыКонтрагентов.ВалютаВзаиморасчетов = &ВалютаВзаиморасчетов
	               |	И ДоговорыКонтрагентов.ИспользуетсяПриОбменеДанными = &ИспользуетсяПриОбменеДанными
	               |	И ДоговорыКонтрагентов.РасчетыВУсловныхЕдиницах = &РасчетыВУсловныхЕдиницах";
	
	ВыборкаДоговоров = Запрос.Выполнить().Выбрать();
	Если ВыборкаДоговоров.Следующий() Тогда
		СсылкаНаОбъект = ВыборкаДоговоров.Ссылка;
	КонецЕсли;
	
Иначе
	
	// Осуществляем поиск договора не только по реквизитам, но и по свойствам
	Запрос.Текст = "ВЫБРАТЬ
	               |	ЗначенияЗагруженныхСвойств.СвойствоНаименование КАК СвойствоНаименование,
	               |	ЗначенияЗагруженныхСвойств.СвойствоЗначение
	               |ПОМЕСТИТЬ ЗначенияЗагруженныхСвойств
	               |ИЗ
	               |	&ЗначенияЗагруженныхСвойств КАК ЗначенияЗагруженныхСвойств
	               |
	               |ИНДЕКСИРОВАТЬ ПО
	               |	СвойствоНаименование
	               |;
	               |
	               |////////////////////////////////////////////////////////////­////////////////////
	               |ВЫБРАТЬ
	               |	ДоговорыКонтрагентов.Ссылка КАК Ссылка,
	               |	ЗначенияЗагруженныхСвойств.СвойствоНаименование
	               |ПОМЕСТИТЬ ОтборПоРеквизитам
	               |ИЗ
	               |	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов,
	               |	ЗначенияЗагруженныхСвойств КАК ЗначенияЗагруженныхСвойств
	               |ГДЕ
	               |	ДоговорыКонтрагентов.ВидДоговора = &ВидДоговора
	               |	И ДоговорыКонтрагентов.Организация = &Организация
	               |	И ДоговорыКонтрагентов.Владелец = &Владелец
	               |	И ДоговорыКонтрагентов.ВалютаВзаиморасчетов = &ВалютаВзаиморасчетов
	               |	И ДоговорыКонтрагентов.РасчетыВУсловныхЕдиницах = &РасчетыВУсловныхЕдиницах
	               |
	               |ИНДЕКСИРОВАТЬ ПО
	               |	Ссылка
	               |;
	               |
	               |////////////////////////////////////////////////////////////­////////////////////
	               |ВЫБРАТЬ
	               |	ОтборПоРеквизитам.Ссылка,
	               |	ЗначенияСвойствОбъектов.Свойство.Наименование КАК СвойствоНаименование,
	               |	ЗначенияСвойствОбъектов.Значение КАК СвойствоЗначение
	               |ПОМЕСТИТЬ ЗначенияСвойствВБазе
	               |ИЗ
	               |	ОтборПоРеквизитам КАК ОтборПоРеквизитам
	               |		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
	               |		ПО ОтборПоРеквизитам.Ссылка = ЗначенияСвойствОбъектов.Объект
	               |			И ОтборПоРеквизитам.СвойствоНаименование = ЗначенияСвойствОбъектов.Свойство.Наименование
	               |
	               |ИНДЕКСИРОВАТЬ ПО
	               |	СвойствоНаименование
	               |;
	               |
	               |////////////////////////////////////////////////////////////­////////////////////
	               |ВЫБРАТЬ
	               |	РезультатАнализаДоговоров.Ссылка
	               |ИЗ
	               |	(ВЫБРАТЬ
	               |		ЗначенияСвойствВБазе.Ссылка КАК Ссылка,
	               |		МИНИМУМ(ВЫБОР
	               |				КОГДА ЗначенияЗагруженныхСвойств.СвойствоЗначение = ЗначенияСвойствВБазе.СвойствоЗначение
	               |							И (НЕ ЗначенияЗагруженныхСвойств.СвойствоЗначение ЕСТЬ NULL )
	               |							И (НЕ ЗначенияСвойствВБазе.СвойствоЗначение ЕСТЬ NULL )
	               |						ИЛИ ЗначенияЗагруженныхСвойств.СвойствоЗначение = НЕОПРЕДЕЛЕНО
	               |							И (ЗначенияСвойствВБазе.СвойствоЗначение ЕСТЬ NULL 
	               |								ИЛИ ЗначенияСвойствВБазе.СвойствоЗначение = НЕОПРЕДЕЛЕНО
	               |								ИЛИ ЗначенияСвойствВБазе.СвойствоЗначение = ЗНАЧЕНИЕ(Справочник.ЗначенияСвойствОбъектов.ПустаяСсылка))
	               |					ТОГДА ИСТИНА
	               |				ИНАЧЕ ЛОЖЬ
	               |			КОНЕЦ) КАК Результат
	               |	ИЗ
	               |		ЗначенияСвойствВБазе КАК ЗначенияСвойствВБазе
	               |			ПОЛНОЕ СОЕДИНЕНИЕ ЗначенияЗагруженныхСвойств КАК ЗначенияЗагруженныхСвойств
	               |			ПО ЗначенияСвойствВБазе.СвойствоНаименование = ЗначенияЗагруженныхСвойств.СвойствоНаименование
	               |	
	               |	СГРУППИРОВАТЬ ПО
	               |		ЗначенияСвойствВБазе.Ссылка) КАК РезультатАнализаДоговоров
	               |ГДЕ
	               |	РезультатАнализаДоговоров.Результат";
	
	ЗначенияЗагруженныхСвойств = Новый ТаблицаЗначений;
	ЗначенияЗагруженныхСвойств.Колонки.Добавить("СвойствоНаименование", Новый ОписаниеТипов("Строка",, Новый КвалификаторыСтроки(50)));
	ЗначенияЗагруженныхСвойств.Колонки.Добавить("СвойствоЗначение", Новый ОписаниеТипов("СправочникСсылка.ЗначенияСвойствОбъектов"));
	
	Для Каждого ПараметрОбъекта Из ПараметрыОбъекта Цикл
		
		Ключ = ПараметрОбъекта.Ключ;
		Если Ключ = "ЗначениеСвойстваПартнерУТ11" Тогда
			НазваниеСвойства = "Партнер УТ11";
		ИначеЕсли Ключ = "ЗначениеСвойстваСоглашениеСКлиентомУТ11" Тогда
			НазваниеСвойства = "Соглашение с клиентом УТ11";
		ИначеЕсли Ключ = "ЗначениеСвойстваСоглашениеСПоставщикомУТ11" Тогда
			НазваниеСвойства = "Соглашение с поставщиком УТ11";
		ИначеЕсли Ключ = "ЗначениеСвойстваСделкаСКлиентомУТ11" Тогда
			НазваниеСвойства = "Сделка с клиентом УТ11";
		ИначеЕсли Ключ = "ЗначениеСвойстваЗаказКлиентаУТ11" Тогда
			НазваниеСвойства = "Заказ клиента УТ11";
		ИначеЕсли Ключ = "ЗначениеСвойстваЗаказПоставщикуУТ11" Тогда
			НазваниеСвойства = "Заказ поставщику УТ11";
		КонецЕсли;
		
		НоваяСтрока = ЗначенияЗагруженныхСвойств.Добавить();
		НоваяСтрока.СвойствоНаименование = НазваниеСвойства;
		НоваяСтрока.СвойствоЗначение	 = ?(ЗначениеЗаполнено(ПараметрОбъекта.Значение), ПараметрОбъекта.Значение, Неопределено);
		
	КонецЦикла;
	
	Запрос.УстановитьПараметр("ЗначенияЗагруженныхСвойств", ЗначенияЗагруженныхСвойств);
	
	РезультатЗапроса = Запрос.ВыполнитьПакет()[3];
	ВыборкаДоговоров = РезультатЗапроса.Выбрать();
	Если ВыборкаДоговоров.Следующий() Тогда
		СсылкаНаОбъект = ВыборкаДоговоров.Ссылка;
	КонецЕсли;
	
КонецЕсли;