Проблемы с разработкой мобильного приложения

&НаКлиенте
Процедура ПредыдущаяСтраница(Команда)
	
	ТекущаяСтраница = ТекущаяСтраница - 1;
	ОбновитьЭлементыФормы(ТекущаяОриентацияЭкрана());
	ЭтаФорма.ОбновитьОтображениеДанных();
	
КонецПроцедуры

&НаКлиенте
Процедура СледующаяСтраница(Команда)
	
	ТекущаяСтраница = ТекущаяСтраница + 1;
	ОбновитьЭлементыФормы(ТекущаяОриентацияЭкрана());
	ЭтаФорма.ОбновитьОтображениеДанных();
	
КонецПроцедуры

&НаСервере
Процедура ОбновитьЭлементыФормы(Ориентация)
	
	//Удалим старые Элементы формы
	Для каждого Стр из ТЧ_ДобавляемыеЭлементы Цикл  
		Группа = Элементы.Найти(Стр.ИмяГруппы);
		Если Не Группа = Неопределено Тогда 
			Элементы.Удалить(Группа);	
		КонецЕсли;
		
		Элемент = Элементы.Найти(Стр.ИмяЭлемента);
		Если Не Элемент = Неопределено Тогда 
			Элементы.Удалить(Элемент);	
		КонецЕсли;
	КонецЦикла;
	ТЧ_ДобавляемыеЭлементы.Очистить();
		
	РПТовары = ТЧ_Товары.НайтиСтроки(Новый Структура("ПолоВозрастнаяГруппа, НомерСтраницы", ПолоВозрастнаяГруппа, ТекущаяСтраница));	
	Для каждого Стр из РПТовары Цикл  
		пп  = Стр.НомерСтроки;
		
		ИмяГруппы 	= "Группа"+пп;
		Стр.Цена	= ?(ТипЗнч(Стр.Цена) = Тип("Число"), СокрЛП(Стр.Цена) + " сум.", Стр.Цена);
		
		Группа 						= Элементы.Добавить(ИмяГруппы, Тип("ГруппаФормы"), ЭтаФорма);
		Группа.Вид					= ВидГруппыФормы.ОбычнаяГруппа;
		Группа.ОтображатьЗаголовок 	= Ложь;
		Группа.Отображение 			= ОтображениеОбычнойГруппы.Нет;
		Группа.Группировка 			= ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;
		
		ДвоичныеДанные = Стр.Фото.ДанныеФайлаМиниатюры.Получить();
		Если ДвоичныеДанные = Неопределено Тогда 
			Стр.НавигационнаяСсылка = ПутьКПустойКартинке;
		Иначе 
			Стр.НавигационнаяСсылка = ПолучитьНавигационнуюСсылку(Стр.Фото, "ДанныеФайлаМиниатюры");
		КонецЕсли;
		
		Элемент 						 = Элементы.Добавить("ПолеФото"+пп, Тип("ПолеФормы"), Элементы[ИмяГруппы]);
		Элемент.ПутьКДанным 			 = "ТЧ_Товары["+(пп-1)+"].НавигационнаяСсылка";
		Элемент.Вид						 = ВидПоляФормы.ПолеКартинки;
		Элемент.Подсказка				 = пп-1;
		Элемент.ПоложениеЗаголовка 		 = ПоложениеЗаголовкаЭлементаФормы.Нет;
		Элемент.РазмерКартинки			 = РазмерКартинки.Пропорционально;
		Элемент.ГоризонтальноеПоложение  = ГоризонтальноеПоложениеЭлемента.Лево;
		Элемент.РастягиватьПоГоризонтали = Ложь;
		Элемент.Гиперссылка				 = Истина;
		Элемент.УстановитьДействие("Нажатие", "ОбработкаНажатия");
		
		НоваяСтрока 				= ТЧ_ДобавляемыеЭлементы.Добавить();
		НоваяСтрока.ИмяГруппы 		= ИмяГруппы;
		НоваяСтрока.ИмяЭлемента 	= Элемент.Имя;
		
		ПодГруппа_1 					= Элементы.Добавить("ПодГруппа"+пп, Тип("ГруппаФормы"), Группа);
		ПодГруппа_1.Вид					= ВидГруппыФормы.ОбычнаяГруппа;
		ПодГруппа_1.ОтображатьЗаголовок	= Ложь;
		ПодГруппа_1.Отображение 		= ОтображениеОбычнойГруппы.Нет;
		ПодГруппа_1.Группировка 		= ГруппировкаПодчиненныхЭлементовФормы.Вертикальная;
		
		Элемент 					= Элементы.Добавить("ПолеТовар"+пп, Тип("ДекорацияФормы"), Элементы["ПодГруппа"+пп]);
		Элемент.Заголовок 			= ТЧ_Товары[(пп-1)].Товар;
		Элемент.Подсказка			= пп-1;
		Элемент.Гиперссылка			= Истина;
		Если Ориентация = ОриентацияСтраницы.Портрет Тогда
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,7,Истина);	
		Иначе 
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,8,Истина);	
		КонецЕсли;
		Элемент.УстановитьДействие("Нажатие", "ОбработкаНажатия");
		
		НоваяСтрока 			= ТЧ_ДобавляемыеЭлементы.Добавить();
		НоваяСтрока.ИмяГруппы 	= ИмяГруппы;
		НоваяСтрока.ИмяЭлемента = Элемент.Имя;
		
		Элемент 					= Элементы.Добавить("ПолеЦена"+пп, Тип("ПолеФормы"), Элементы["ПодГруппа"+пп]);
		Элемент.ПутьКДанным 		= "ТЧ_Товары["+(пп-1)+"].Цена";
		Элемент.Вид					= ВидПоляФормы.ПолеНадписи;
		Элемент.Подсказка			= пп-1;
		Элемент.ПоложениеЗаголовка  = ПоложениеЗаголовкаЭлементаФормы.Нет;
		Элемент.Гиперссылка			= Истина;
		Если Ориентация = ОриентацияСтраницы.Портрет Тогда
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,8,Истина);	
		Иначе 
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,9,Истина);	
		КонецЕсли;
		Элемент.УстановитьДействие("Нажатие", "ОбработкаНажатия");
		
		НоваяСтрока 			= ТЧ_ДобавляемыеЭлементы.Добавить();
		НоваяСтрока.ИмяГруппы 	= ИмяГруппы;
		НоваяСтрока.ИмяЭлемента = Элемент.Имя;
		
		
		ПодГруппа_2 						 = Элементы.Добавить("ПодПодГруппа"+пп, Тип("ГруппаФормы"), Элементы["ПодГруппа"+пп]);
		ПодГруппа_2.Вид						 = ВидГруппыФормы.ОбычнаяГруппа;
		ПодГруппа_2.ОтображатьЗаголовок		 = Ложь;
		ПодГруппа_2.Отображение 			 = ОтображениеОбычнойГруппы.Нет;
		ПодГруппа_2.Группировка 			 = ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;
		ПодГруппа_2.РастягиватьПоГоризонтали = Ложь;
		
		Элемент 					= Элементы.Добавить("ПолеКоличество"+пп, Тип("ПолеФормы"), Элементы["ПодПодГруппа"+пп]);
		Элемент.ПутьКДанным 		= "ТЧ_Товары["+(пп-1)+"].Количество";
		Элемент.Вид					= ВидПоляФормы.ПолеВвода;
		Элемент.Подсказка			= пп-1;
		Элемент.ПоложениеЗаголовка  = ПоложениеЗаголовкаЭлементаФормы.Нет;
		Элемент.КнопкаРегулирования	= Истина;
		Элемент.МинимальноеЗначение = 0;
		Если Ориентация = ОриентацияСтраницы.Портрет Тогда
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,8,Истина);	
		Иначе 
			Элемент.Шрифт			= Новый Шрифт(Элемент.Шрифт,,9,Истина);	
		КонецЕсли;
		
		НоваяСтрока 			= ТЧ_ДобавляемыеЭлементы.Добавить();
		НоваяСтрока.ИмяГруппы 	= ИмяГруппы;
		НоваяСтрока.ИмяЭлемента = Элемент.Имя;
		
		Команда 			= Команды.Найти("Купить"+пп);
		Если Команда = Неопределено Тогда 
			Команда	 		= Команды.Добавить("Купить"+пп); 
		КонецЕсли;
		Команда.Заголовок 	= "Купить";
		Команда.Подсказка	= пп-1;
		Команда.Картинка 	= БиблиотекаКартинок.Корзина;
		Команда.Действие	= "Купить";
		
		Элемент 			= Элементы.Добавить("ФормаКупить"+пп, Тип("КнопкаФормы"), Элементы["ПодПодГруппа"+пп]);
		Элемент.Вид			= ВидКнопкиФормы.ОбычнаяКнопка;
		Элемент.ИмяКоманды	= Команда.Имя;
		//Элемент.Ширина		= 7;
		Элемент.Высота		= 1;
		Если Ориентация = ОриентацияСтраницы.Портрет Тогда
			Элемент.Шрифт		= Новый Шрифт(Элемент.Шрифт,,6,Истина);	
			Элемент.Отображение = ОтображениеКнопки.Картинка;
		Иначе 
			Элемент.Шрифт		= Новый Шрифт(Элемент.Шрифт,,7,Истина);	
			Элемент.Отображение = ОтображениеКнопки.КартинкаИТекст;
		КонецЕсли;
		
		НоваяСтрока 			= ТЧ_ДобавляемыеЭлементы.Добавить();
		НоваяСтрока.ИмяГруппы 	= ИмяГруппы;
		НоваяСтрока.ИмяЭлемента = Элемент.Имя;
	КонецЦикла;
	
	Элементы.Переместить(Элементы.ГруппаПереключениеСтраниц, ЭтаФорма);
	
	РПТовары_2 = ТЧ_Товары.НайтиСтроки(Новый Структура("ПолоВозрастнаяГруппа", ПолоВозрастнаяГруппа));
	Если РПТовары.Количество() = РПТовары_2.Количество() Тогда 
		Элементы.ГруппаПереключениеСтраниц.Видимость = Ложь;	
	Иначе 
		Элементы.ГруппаПереключениеСтраниц.Видимость = Истина;	
		
		Если ТекущаяСтраница = 1 Тогда 
			Элементы.ПредыдущаяСтраница.Доступность = Ложь;
			Элементы.СледующаяСтраница.Доступность  = Истина;
		ИначеЕсли ТекущаяСтраница = РПТовары_2[РПТовары_2.ВГраница()].НомерСтраницы Тогда 
			Элементы.ПредыдущаяСтраница.Доступность = Истина;
			Элементы.СледующаяСтраница.Доступность  = Ложь;
		Иначе 
			Элементы.ПредыдущаяСтраница.Доступность = Истина;
			Элементы.СледующаяСтраница.Доступность  = Истина;
		КонецЕсли;
	КонецЕсли;
	
	Если РПТовары.Количество() > 0 Тогда 
		ЭтаФорма.ТекущийЭлемент = Элементы["ПолеФото"+РПТовары[0].НомерСтроки];
	КонецЕсли;
	
КонецПроцедуры

Функция ТекущаяОриентацияЭкрана() Экспорт
	
	ПараметраЭкрана = ПолучитьИнформациюЭкрановКлиента();
	Если ПараметраЭкрана.Количество() > 0 Тогда 
		ИнфаЭкрана = ПараметраЭкрана[0];    
		
		Если ИнфаЭкрана.Высота > ИнфаЭкрана.Ширина Тогда 
			Возврат ОриентацияСтраницы.Портрет;	
		Иначе 
			Возврат ОриентацияСтраницы.Ландшафт;	
		КонецЕсли;
	КонецЕсли;

КонецФункции