Теория обмена, как правильно спроектировать механизм обмена?

&НаСервере
Процедура ОбменЧерезПланыНаСервере()
	
	Соединение = WSСсылки.ObmenPoPlanamWending.СоздатьWSПрокси("ObmenPoPlanamWending","ObmenPoPlanamWending","ObmenPoPlanamWendingSoap"); //ВсСыслка
	Операция   = Соединение.ТочкаПодключения.Интерфейс.Операции.Получить("Sync"); //ВебСервис 	
	
	ТекстХМЛ = СформироватьСообщениеСерверу();
	КодУзлаОтправителя = ПланыОбмена.WendingExchang.ЭтотУзел().Код;
	
	СтруктураПосылаемыхДанных = Новый Структура;
	СтруктураПосылаемыхДанных.Вставить("ТекстХМЛ",ТекстХМЛ);
	СтруктураПосылаемыхДанных.Вставить("КодУзлаОтправителя",КодУзлаОтправителя);
	
	Данные = Новый ХранилищеЗначения(СтруктураПосылаемыхДанных, Новый СжатиеДанных(9)); 
	Ответ = Соединение.Sync(Данные);
	ПринятьИзменениеПоПлану(Ответ.Получить());
	
КонецПроцедуры

&НаСервере
Функция СформироватьСообщениеСерверу()
	ЗаписьХМЛ = Новый ЗаписьXML; 
	ЗаписьХМЛ.УстановитьСтроку(); 
	ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
	Узел = ПланыОбмена.WendingExchang.НайтиПоКоду("ЦБ");
	ЗаписьСообщения.НачатьЗапись(ЗаписьХМЛ,Узел); 
	ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(Узел,ЗаписьСообщения.НомерСообщения); 
	Пока ВыборкаИзменений.Следующий() Цикл    
		ОбъектОбмена = ВыборкаИзменений.Получить(); 
		ЗаписатьXML(ЗаписьХМЛ,ОбъектОбмена);    
	КонецЦикла;      
	ЗаписьСообщения.ЗакончитьЗапись();  
    Возврат ЗаписьХМЛ.Закрыть();   
КонецФункции

&НаСервере
Процедура ПринятьИзменениеПоПлану(СтруктураПосылаемыхДанных) 	
	ТекстХМЛ = СтруктураПосылаемыхДанных.ТекстХМЛ;
	ТекстОшибки = СтруктураПосылаемыхДанных.ТекстОшибки;
	Если Не ТекстОшибки = "" тогда
		Сообщить("Произошла ошибка");
		Возврат;
	КонецЕсли;	
	ЧтениеХМЛ = Новый ЧтениеXML; 
	ЧтениеХМЛ.УстановитьСтроку(ТекстХМЛ); 
	ЧтениеСообщения = ПланыОбмена.СоздатьЧтениеСообщения();  
	ЧтениеСообщения.НачатьЧтение(ЧтениеХМЛ);      
	Пока ВозможностьЧтенияXML(ЧтениеХМЛ) Цикл      
		Данные = ПрочитатьXML(ЧтениеСообщения.ЧтениеXML); 
		//Данные = ПрочитатьXML(ЧтениеХМЛ);  
		Если Не Данные = Неопределено Тогда 
			Если Не ТипЗнч(Данные) = Тип("ДокументОбъект.ДанныеОтТП") Тогда 
				Данные.ОбменДанными.Отправитель = ЧтениеСообщения.Отправитель; 
				Данные.ОбменДанными.Загрузка = Истина;				
				Данные.Записать();  
			КонецЕсли;
		КонецЕсли; 
	КонецЦикла;  
	ЧтениеСообщения.ЗакончитьЧтение();
КонецПроцедуры

Функция Sync(DataStorage)
	ТекстОшибки = "";
	Попытка
		ТекстХМЛ = ЗарегистрироватьВыгрузку(DataStorage.Получить());
	Исключение
		ТекстОшибки = ОписаниеОшибки();
	КонецПопытки;
	
	СтруктураПосылаемыхДанных = Новый Структура;
	СтруктураПосылаемыхДанных.Вставить("ТекстХМЛ",ТекстХМЛ);
	СтруктураПосылаемыхДанных.Вставить("ТекстОшибки",ТекстОшибки);

	Возврат Новый ХранилищеЗначения(СтруктураПосылаемыхДанных, Новый СжатиеДанных(9)); 
КонецФункции

Функция ЗарегистрироватьВыгрузку(СтруктураПосылаемыхДанных)
	
	КодУзлаОтправителя = СтруктураПосылаемыхДанных.КодУзлаОтправителя;
	ТекстХМЛ = СтруктураПосылаемыхДанных.ТекстХМЛ;
	
	УзелПолучатель = ПланыОбмена.WendingExchang.НайтиПоКоду(КодУзлаОтправителя);
	
	Если Не ЗначениеЗаполнено(УзелПолучатель) Тогда 
		УзелПолучатель = ПланыОбмена.WendingExchang.СоздатьУзел();
		УзелПолучатель.Код = КодУзлаОтправителя;
		УзелПолучатель.Наименование = КодУзлаОтправителя;
		//УзелПолучатель.ПрефиксИБ = ПолучитьНомерИБ();
		УзелПолучатель.Записать();
		ПланыОбмена.ЗарегистрироватьИзменения(УзелПолучатель.Ссылка);		
	КонецЕсли;	
	
 	ЧтениеХМЛ = Новый ЧтениеXML; 
 	ЧтениеХМЛ.УстановитьСтроку(ТекстХМЛ); 	
	ЧтениеСообщения = ПланыОбмена.СоздатьЧтениеСообщения(); 
	ЧтениеСообщения.НачатьЧтение(ЧтениеХМЛ);  
	Узел = ЧтениеСообщения.Отправитель;	
	
	ПрефиксИБ = УзелПолучатель.ПрефиксИБ;
	ПользовательИБ = УзелПолучатель.Пользователь;
	Пока ВозможностьЧтенияXML(ЧтениеХМЛ) ИЛИ (ЧтениеХМЛ.ТипУзла = ТипУзлаXML.НачалоЭлемента И ЧтениеХМЛ.Имя = "info") Цикл         
		Если ЧтениеХМЛ.Имя = "info" Тогда
			// читаем дополнительную информацию
			ЧтениеХМЛ.Прочитать();
			// значением свойства ЧтениеXML.ТипУзла должно быть значение ТипУзлаXML.Текст
			// ЧтениеXML.Значение должна быть строка "дополнительная информация"
			ДопИнформация = ЧтениеХМЛ.Значение;            
			// читаем завершение дополнительной информации
			ЧтениеХМЛ.Прочитать();            
			// переходим к следующему элементу
			ЧтениеХМЛ.Прочитать();            
		Иначе            
			// Читаем элемент данных стандартным способом
			ЭлементДанных = ПрочитатьXML(ЧтениеХМЛ);
			Если ТипЗнч(ЭлементДанных) = Тип("ДокументОбъект.ДанныеОтТП") Тогда 
				ЭлементДанных.Номер = ПрефиксИБ + ЭлементДанных.Номер;
				ЭлементДанных.Ответственный = ПользовательИБ;
				ЭлементДанных.Записать();
			КонецЕсли;        
		КонецЕсли;         
	КонецЦикла;
	
	ПланыОбмена.УдалитьРегистрациюИзменений(ЧтениеСообщения.Отправитель,ЧтениеСообщения.НомерПринятого); 
	ЧтениеСообщения.ЗакончитьЧтение(); 
	
	ЗаписьХМЛ = Новый ЗаписьXML;  
	ЗаписьХМЛ.УстановитьСтроку(); 
	ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();	
	ЗаписьСообщения.НачатьЗапись(ЗаписьХМЛ,Узел); 
	
	ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(Узел,ЗаписьСообщения.НомерСообщения);  
	Пока ВыборкаИзменений.Следующий() Цикл    
		ОбъектОбмена = ВыборкаИзменений.Получить();  
		ЗаписатьXML(ЗаписьХМЛ,ОбъектОбмена);    
	КонецЦикла;     
	ЗаписьСообщения.ЗакончитьЗапись();  
	Возврат ЗаписьХМЛ.Закрыть();
КонецФункции