Добавление команд печати в свои документы в Бухгалтерии 3.0

25.09.16

Разработка - Работа с интерфейсом

Данная публикация может быть вам полезна, если вы хотите сделать своим нетиповым документам в Бухгалтерии 3.0 универсализированную печать (не затрагивая типовые объекты). Эта статья подойдет для любой конфигурации на основе БСП, так как использует возможности ее подсистемы "Печать"

В Бухгалтерии 2.0 была очень удобная типовая процедура

УниверсальныеМеханизмы.НапечататьДокумент(ТабДокумент, КоличествоЭкземпляров, НаПринтер,
					  Заголовок, НепосредственнаяПечать, Ссылка, ИмяМакета) 

Она помогала вывести ваш печатный документ в универсальное окно печати, где вы выбирали количество копий, вариант сохранения и тому подобное

Сейчас, переходя с 2.0 на 3.0, я стал искать аналог этой процедуры и не нашел. Но это к лучшему, потому что я нашел еще более универсальный механизм. Он опирается на механизмы подсистемы "Печать" БСП (БСП - это основа всех современных конфигураций фирмы 1С). Нужно добавить несколько функций в два модуля: Модуль менеджера и Модуль формы. Пусть у нас есть нетиповой документ Приказ, и у него есть два макета и две формы. 

Для каждого из двух макетов у нас подготовлены функции СформироватьАкт(Ссылка) и СформироватьПриказ(Ссылка), возвращающие табличные документы, которые нам нужно будет красиво выводить на печать. Хочется, не прилагая больших усилий, добиться следующего результата: чтобы в каждой из двух форм этого документа в командной панели была кнопка-подменю Печать, в которой был бы список из наших печатных форм.

     

Откроем форму ФормаДокумента, и создадим обработчик ПриСозданииНаСервере. Скопируем в модуль формы следующий код:

&НаСервере 
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
		
	УправлениеПечатью.ПриСозданииНаСервере(ЭтаФорма)	
	
КонецПроцедуры 

&НаКлиенте 
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
	
	УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Объект)
	
КонецПроцедуры  

 

Теперь откроем Модуль менеджера и скопируем туда следующий код:

Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт 

	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Акт";
	КомандаПечати.Представление = "Дополнительный акт";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента";
	
	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Приказ";
	КомандаПечати.Представление = "Приказ";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента";
	
КонецПроцедуры 

Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт 	
	
	ПараметрыВывода.ДоступнаПечатьПоКомплектно = Истина;
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Акт") Тогда
 		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "Акт", "Акт", 
			СформироватьНесколькоАктов(МассивОбъектов),"Документ.Приказ.Акт");
	КонецЕсли;
	
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Приказ") Тогда
 		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "Приказ", "Приказ", 
			СформироватьНесколькоПриказов(МассивОбъектов),"Документ.Приказ.Приказ");
	КонецЕсли;
	
КонецПроцедуры 

Функция   СформироватьНесколькоАктов(МассивОбъектов)
	
	ТабДокумент = Новый ТабличныйДокумент;
	Для каждого Ссылка из МассивОбъектов Цикл
		ТабДокументОбъекта = СформироватьАкт(Ссылка); 
		Если ТабДокумент.ВысотаТаблицы > 0 И ТабДокументОбъекта.ВысотаТаблицы > 0 Тогда 
			ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц()
		КонецЕсли;
		ТабДокумент.Вывести(ТабДокументОбъекта)
	КонецЦикла;

	Возврат ТабДокумент

КонецФункции 

Функция   СформироватьНесколькоПриказов(МассивОбъектов)
	
	ТабДокумент = Новый ТабличныйДокумент;
	Для каждого Ссылка из МассивОбъектов Цикл
		ТабДокументОбъекта = СформироватьПриказ(Ссылка); 
		Если ТабДокумент.ВысотаТаблицы > 0 И ТабДокументОбъекта.ВысотаТаблицы > 0 Тогда 
			ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц()
		КонецЕсли;
		ТабДокумент.Вывести(ТабДокументОбъекта)
	КонецЦикла;

	Возврат ТабДокумент

КонецФункции 

Функция  СформироватьАкт(Ссылка)

	ТабДокумент = Новый ТабличныйДокумент; 
	// подготовка ТабДокумента
	Возврат ТабДокумент 

КонецФункции 

Функция   СформироватьПриказ(Ссылка)
	
    ТабДокумент = Новый ТабличныйДокумент;
    // подготовка ТабДокумента 
    Возврат ТабДокумент 

КонецФункции 

Все готово, в форме документа у нас теперь программно будут добавляться кнопки печати. Чтобы они появились и в форме списка, проделайте с ней тоже самое (создайте обработчик ПриСозданииНаСервере и скопируйте код в Модуль формы ФормаСписка, в Модуле менеджера уже ничего менять не надо). Единственное отличие в третьем параметре функции ВыполнитьПодключаемуюКомандуПечати: вместо Объект нужно написать Элементы.Список. Также у этого списка обязательно должна быть колонка Ссылка, пусть даже невидимая. 

Результат всего этого выглядит так:

 

Форма документа

 

Форма списка

 

Универсальное окно печати в Бухгалтерии 3.0

 

P.S. Если при открытии информационной базы появится такое окно, то просто выполните то, что там написано, это нормально

подробнее о подсистеме "Печать" на ИТС:  https://its.1c.ru/db/bspdoc#content:219:hdoc

См. также

Табличная часть в доп. реквизитах и формирование таблиц в шаблоне docx для 1С:ДО 3.0

Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Платные (руб)

Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.

29400 руб.

29.06.2023    4446    9    4    

18

Расширение для 1С:УНФ. Автоматическое снятие резервов в Заказах покупателей

Логистика, склад и ТМЦ Адаптация типовых решений Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Мы доработали УНФ, чтобы она автоматически отменяла старые резервы и не мешала эффективно продавать.

7200 руб.

02.08.2023    2950    4    0    

19

Богатый редактор картинок, хранимых в базе, с возможностью РИСОВАНИЯ. Редактор внешних файлов картинок. Объект, расширяющий возможности работы с картинками из встроенного языка (Три в одном) + Обработка «Стандартизация картинок»

Работа с интерфейсом Рабочее место Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Обработка предназначена для редактирования картинок в режиме «Предприятие», с возможностью РИСОВАТЬ на них. Поддерживается работа как в обычных формах (толстый клиент) так и на управляемых формах (тонкий клиент). Обработка позволяет редактировать как картинки, хранимые в базе, так и графические файлы с диска на файловой системе. Помимо базовых функций (изменение размеров, преобразование формата, обрезание картинки, повороты и т.п.) – редактор имеет богатый набор инструментов для рисования. Доступна функция вставки изображения из буфера обмена. Также обработка может быть использована из встроенного языка как объект для редактирования картинок. Объект может быть использован: на стороне клиента, на стороне сервера, из внешнего соединения. Данная обработка будет особенно полезна тем, кто вносит картинки в базу (изображения номенклатуры, фотографии физических лиц и т.п.). Функционал реализуется с использованием JavaScript и бесплатного ПО ImageMagick (без использования внешних компонент).

6000 руб.

16.01.2015    61791    43    59    

80

[Расширения] Динамическое управление видимостью и доступностью элементов форм (УФ) (8.3.6+)

Работа с интерфейсом Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Механизм «Динамическое управление доступом к элементам форм объектов 1С8» предназначен для обеспечения возможности оперативного управления видимостью и доступностью элементов форм документов и справочников продуктов фирмы «1С» «1С:Предприятие 8». Решение универсальное, встраивается в любую конфигурацию с минимальными доработками, что позволяет без проблем обновлять типовые решения.

5000 руб.

14.01.2016    54394    16    21    

42

Управление дашбордами

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Обработка предназначена для создания и управления дашбордами.

2400 руб.

29.06.2020    16694    21    4    

35
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. paybaseme 14 02.12.13 13:09 Сейчас в теме
Самое интересное в предлагаемой Вами методике, осталось за кадром: если в форме списка выделить НЕСКОЛЬКО элементов (в вашем случае, приказов), то как же тогда будут напечатаны все Ваши документы, ежели Вы пишите:

Ссылка = МассивОбъектов[0];


Для одного объекта и будет напечатано.

Полагаю, Вам нужно заглянуть в БСП.
2. nick-max 249 02.12.13 16:26 Сейчас в теме
(1) paybaseme,

Понятно, что где-то реализованы целые блоки и фреймворки для управления печатью. Эта статья только для Бухгалтерии 3.0, она полностью опирается на функционал этой конфигурации.

Да, из кода понятно, что если выделить шифтом несколько строк с документами, то можно напечатать их пакетно. Но для меня это ненужная функция. Однако, спасибо, что обратили на это внимание, может кому-то будет полезно)
3. paybaseme 14 02.12.13 17:47 Сейчас в теме
(2)

Понятно, что где-то реализованы целые блоки и фреймворки для управления печатью. Эта статья только для Бухгалтерии 3.0, она полностью опирается на функционал этой конфигурации.


Я ключевую неточность у Вас подчеркнул. В БП 3.0 портирована подсистема "Печать". Механизм печати, в части касающейся Вашей статьи, одинаков для конфигураций, где данная подсистема уже внедрена. Т.е. "фреймворк" печати (в вашей терминологии), уже встроен в БП 3.0. И говорить, что Ваша статья "опирается на функционал этой конфигурации." видимо, не совсем, точно. Ваша статья опирается на использование типовой подсистемы "Печать" из БСП.

Все выше сказанное, не в критику, а в уточнение :)
ivnik; keln; ccapt; swimdog; borzyj; jobkostya1c_ERP; Bukaska; Makushimo; +8 Ответить
4. nick-max 249 03.12.13 11:00 Сейчас в теме
(3) paybaseme,

Спасибо за уточнение
Значит эта статья кросс-конфигурационная)
20. Bukaska 140 19.12.13 14:35 Сейчас в теме
(2) Вот теперь спасибо! Правда вперед ИТС под рукой был)))) есть другой вопрос, по части внешних печатных форм для самодельных документов. Эти все дела по вашей публикации я сделала, потом отлаживаю сейчас родной макет самодельного документа.. но вот Внешнюю печатную форму не зарегить, выскакивает ошибка: Тип не определен.ДокументСсылка.ИмяДокумента.. В Общую команду составного типа добавила свой док, но все равно видать что-то где-то не хватает... Благо что хоть родной макет отлаживается))))
23. mie24 2 09.01.14 09:26 Сейчас в теме
(20) Bukaska, Чтобы к новому документу иметь возможность подключить ВПФ необходимо этот документ указать в списке Типов параметров Общей команды "ДополнительныеОтчетыИОбработкиПечатныеФормы", а лучше подстраховаться и указать новый(ые) документ(ы) и в других Общих командах "ДополнительныеОтчетыИОбработкиОтчеты", "ДополнительныеОтчетыИОбработкиЗаполнениеОбъекта", "ДополнительныеОтчетыИОбработкиСозданиеСвязанныхОбъектов".
Далее необходимо в Модуле формы (Документа и Списка) нового документа необходимо создать процедуру ПриСозданииНаСервере:
&
НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
		// СтандартныеПодсистемы.Печать
	УправлениеПечатью.ПриСозданииНаСервере(ЭтаФорма);
	// Конец СтандартныеПодсистемы.Печать
	
	// ДополнительныеОтчетыИОбработки
	ДополнительныеОтчетыИОбработки.ПриСозданииНаСервере(ЭтаФорма);
	// Конец ДополнительныеОтчетыИОбработки
	
	Если Параметры.Ключ.Пустая() Тогда
		ПодготовитьФормуНаСервере();
	КонецЕсли;

КонецПроцедуры
Показать

Кажется этого должно быть достаточно.

Только нужно еще проверить на форме на панели (Вид - ГруппаКнопок и Источник - Форма) появилась ли кнопка Печать с выпадающим меню "ДополнительныеПечатныеФормы"
freeek; insurgut; BiTwaR; Sherdrada; +4 Ответить
10. Bukaska 140 10.12.13 17:25 Сейчас в теме
(1) paybaseme, Я думаю множественная печать и Без БСП реализуется, если глянуть в типовую..
Для этого даже с самодельными печатными формами вместо ссылки на объект, делаем
Запрос.УстановитьПараметр("МассивОбъектов", МассивОбъектов)
А в самом запросе:
...
ГДЕ
НужноеПоле.Ссылка В(&МассивОбъектов)


И переменную результата запроса Шапка прокрутить в цикле и усе.. и все будет ОК))))
Это как раз если внешнюю печатную форму встраивать через доп.Отчеты и обработки))))
11. paybaseme 14 10.12.13 20:45 Сейчас в теме
(10) Bukaska,
Я думаю множественная печать и Без БСП реализуется, если глянуть в типовую..


Все таки, по внимательнее перечитайте (3). Если Вы гляните в типовую БП 3.0, то все о чем Вы написали, НЕ ИМЕЕТ СМЫСЛА без внедренной подсистемы "Печать". Поэтому, Ваши думы о том, что множественная печать реализуется БЕЗ БСП, могут существовать в контексте Ваших исключительных рассуждений и дум :) А если глубже копнуть, то выяснится, что ваш алгоритм - это типовая методика, которую можно было увидеть в БСП версии 1.0.7.5 от 05.08.2010, в то время как БП 3.0 зарелизилась с версии 3.0.9.4 от 28.04.2012. Т.е., тот алгоритм, который Вы описали, опирается на обвяз, который уже был представлен в демо БСП практически за 2 года, до первого релиза БП 3.0

Это как раз если внешнюю печатную форму встраивать через доп.Отчеты и обработки


А это, в свою очередь, еще одна подсистема БСП под названием "Дополнительные отчеты и обработки", которая также портирована в БП 3.0

Итоги моего поста какие? :)
12. Bukaska 140 10.12.13 21:45 Сейчас в теме
(11) paybaseme, Я сказала именно про множественную печать, что не нужно так глубоко копать для привязки ВПФ к документу)))
Вопрос в том, как по вашей методике согласно публикации сделать так, чтобы работала множественная печать.А то нулевой индекс строки правильно ребята подметили, - это печать одного документа, как будто из бух 2.0 печатаем)
13. paybaseme 14 10.12.13 22:53 Сейчас в теме
(12) Bukaska,
не нужно так глубоко копать для привязки ВПФ к документу


Как раз таки нужно, ибо если не копать, тогда сложится мнение как у вас и у вашего коллеги: что оно якобы как-то само там живет, в типовой, своей жизнью.

Надо за правило взять, если что-то по печати, доп.отчетам и обработкам, ролям и прочему не понятно - то первое что надо делать, это не пытаться раскуривать самому, а скачать демо БСП, той редакции, которая сейчас в типовой, и посмотреть примеры.

Пожалуйста! Всегда Ваш, Кэп.

:)
14. Bukaska 140 10.12.13 23:19 Сейчас в теме
(13) paybaseme, БСП недоступна ни по учетке учебной версии, ни по комплекту разраба вроде как.. Это только франям..)))
Если бы оно везде на ресурсах валялось.. другой бы разговор)))
Лучше подскажите как в типовой найти версию БСП, и где посмотреть справку о функционале БСП.
15. paybaseme 14 11.12.13 09:35 Сейчас в теме
(14) Bukaska,
Прикрепленные файлы:
16. Bukaska 140 11.12.13 09:57 Сейчас в теме
(15) paybaseme, Спасибо! А как в типовой бух 3.0 выйти на эту справку?
17. paybaseme 14 11.12.13 10:17 Сейчас в теме
(16) Bukaska,
А как в типовой бух 3.0 выйти на эту справку?

1. Версия подсистем - РС
2. Справка по подсистемам БСП - никак. Только на ИТС.
18. Bukaska 140 11.12.13 10:19 Сейчас в теме
(17) paybaseme, ну вот.. опять двадцать пять((( жаль.. Ладно.. может меня когда-нить и допустят до ИТС)))
19. paybaseme 14 11.12.13 11:25 Сейчас в теме
(18) Bukaska,

может меня когда-нить и допустят до ИТС


Если у Вас ваше скромное чувство собственного "я" позволит себя допустить до ИТС, то для этого нужно сделать всего лишь четыре шага:

1. Зарегать новый e-mail
2. Открыть http://its.1c.ru/test-drive/
3. Получить доступ к ИТС по е-mail из п.1 на 7 дней
4. Через 7 дней, выполнить в п.1

Пожалуйста! Всегда Ваш, Кэп.
Suslik_Johns; SunShinne; +2 Ответить
5. Saifa 32 08.12.13 19:03 Сейчас в теме
Статья мне пригодилась, спасибо!
6. nixel 1403 08.12.13 19:32 Сейчас в теме
В БП 3.0 помимо подсистемы "Печать" встроена подсистема "Дополнительные отчеты и обработки", которая позволяет вообще без внесения изменений в конфигурацию добавлять произвольные команды печати и обработок в документы. Единственное требование от конфигурации - наличие документа/справочника в определенной подписке. Если этого нет, то контроллировать изменение одной/двух подписок намного проще, чем модулей объекта и менеджера. Сама же печать располагается во внешней обработке, которая имеет в своем модуле информацию для подключения к какому-либо документу, и все это дело настраивается в пользовательском режиме.
Как уже писалось выше, почитайте документацию по новой БСП, там правда много интересного :)
jobkostya1c_ERP; +1 Ответить
7. AleksSF 222 10.12.13 09:44 Сейчас в теме
А через команды документа и конструкторы не пробовали. Там все автоматом размещается и на форму документа и на форму списка. В БП 3.0 как и во всех управляемых приложениях ко многим вещам другой подход. И лучше как следует изучить новую конфигурацию, а затем переносить свои изменения. Иначе получиться изобретение велосипеда.
8. nick-max 249 10.12.13 10:19 Сейчас в теме
(7) AleksSF,

Пробовал, конечно, с этого и начал. Но такая печать просто формирует и открывает табличный документ, а мне требовалось, чтобы он открывался в форме с кнопкой "Печать", количеством экземпляров, возможностью сохранить
9. AleksSF 222 10.12.13 15:55 Сейчас в теме
(8)
В принципе Ваш способ имеет право жить, если в конфигурацию добавляешь свои Документы. Но для стандартных документов все же лучше использовать Дополнительные внешние печатные формы. Они добавляются с таким-же функционалом. Но при обновлениях ничего не будет пропадать и для последователей более прозрачно. Поэтому +.
21. oleg212 03.01.14 11:16 Сейчас в теме
22. SoulCast 33 04.01.14 00:15 Сейчас в теме
Спасибо, сделал по этой схеме несколько печатных форм в новых документах. Как раз в процессе переход на БП 3.0 )) А есть идеи как передать в процедуру печати дополнительные параметры?
24. nick-max 249 09.01.14 12:38 Сейчас в теме
(22) SoulCast,

а для чего это может быть нужно? то есть, какой например может быть доп. параметр, и почему его нельзя получить уже внутри процедуры типа СформироватьАкт?
25. SoulCast 33 09.01.14 19:21 Сейчас в теме
(24) например получить текущую строку табличной части. У меня были печатные формы, которые получали данные по выбранной строке.
26. Dima69 53 07.03.14 10:05 Сейчас в теме
Спасибо очень помогло
27. Dima69 53 07.03.14 10:09 Сейчас в теме
Да чуть не забыл, а не подскажите какие стандартные процедуры
ставят значок Дб-Кр (при ручной корректировки операции) в списке документов
28. nick-max 249 07.03.14 10:30 Сейчас в теме
(27) Dima69,

для выведения на форму кнопки ДтКт нужно добавить свой документ в общую команду ПоказатьДвиженияДокумента.
Но с точки зрения доработки типовой конфигурации с минимальными изменениями в типовых объектах лучше всего скопировать эту общую команду, назвать ПоказатьДвиженияМоегоДокумента и указывать в ней только свои документы. Тогда при обновлении кнопка ДтКт точно не слетит
29. Dima69 53 19.03.14 20:49 Сейчас в теме
Спасибо за ответ, но я имел в виду не кнопку ДтКт,
а значок ДтКт левее документа, операция которого отредактированна вручную, рядом
с зеленой галкой проведенного документа
30. sudmorsh 57 02.08.14 19:51 Сейчас в теме
Спасибо за статью очень пригодилась
31. jobkostya1c_ERP 100 20.08.14 08:03 Сейчас в теме
Интересная статья про печать в БП 3.0 с использованием стандартных механизмов. Но, может быть, даже для новых нетиповых документов использовать внешние печатные формы если нужно оперативно (не выгоняя пользователей) исправить ошибку при печати?
Печатную форму сделать проще чем копаться в механизмах печати новых релизов? Постоянно ведь корректировать конфигурацию будет затруднительно? Особенно если новых документов много.
32. Astafan 11.11.14 08:15 Сейчас в теме
Спасибо за статью, очень пригодилась.
Но есть один вопрос: Создал в типовой конфигурации новый документ. Чтобы использовать механизм подключаемых печатных форм нужно редактировать команду "ДополнительныеОтчетыИОбработкиПечатныеФормы". НО при обновлении изменения слетят. Как правильно поступить в данном случае?
33. ekaterinaeon 18 28.11.14 08:53 Сейчас в теме
Нашла эту статью как раз в тот момент, когда больше всего была нужна) и помогло! спасибо!
34. helox 04.12.14 15:23 Сейчас в теме
В процедуре Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт 

	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Акт";
	КомандаПечати.Представление = "Дополнительный акт";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента"; 

в списке форм должны быть наименования форм используемых при печати, добавил форму "ФормаДокументаУФ" - и долго гадал почему не появилась кнопочка печати!!
solary; DarkUser; +2 Ответить
35. ronhard 29.01.15 17:52 Сейчас в теме
Также у этого списка обязательно должна быть колонка Ссылка, пусть даже невидимая
В конфигураторе на форме у колонки "Ссылка" должна стоять галочка "Использовать всегда", иначе невидимая колонка работать не будет, а только если она видимая.
A.Kurilov; bird21; PoZiTiFFF; cleaner_it; +4 Ответить
50. den_vrn 12 19.06.19 11:12 Сейчас в теме
(35)
"Использовать всегда"


не могу найти где эта галочка блин ....
36. ui69 41 11.02.15 13:50 Сейчас в теме
Спасибо, помогла данная статья. Создавал новый документ в БП 3.0 с двумя печатными формами.
37. Baser 5 12.02.16 09:07 Сейчас в теме
А можете ссылку дать, как это более правильно делать? Я уже который день пытаюсь понять, как свою печать через БСП пустить, а не по старинке, через команды; везде методики для использования во внешних печатных формах

Ну, вот почему так... как вопрос задал, так сразу и нашел... спасибо всем :)
http://its.1c.ru/db/bspdoc#content:219:1:issogl2_%D1%80%D0%B0%D0%B7%D1%80%D0%B0%D0%B1%D0%BE%D1%82%D0%­BA%D0%B0_%D0%BF%D1%80%D0%BE%D1%86%D0%B5%D0%B4%D1%83%D1%80%D1­%8B_%D0%BF%D0%B5%D1%87%D0%B0%D1%82%D1%8C
38. user590836_zhan_chick 08.07.16 14:24 Сейчас в теме
Теперь у меня программно добавились 2 лишние кнопки печати, которые мне не нужны. Помимо тех что созданы на форме вручную. Вопрос: как мне их убрать?
39. zmx 25.07.16 00:29 Сейчас в теме
В форме списка документа в процедуре ВыполнитьПодключаемуюКомандуПечати нужно поставить условие выполнения печати только, если документ проведен. Почему здесь не виден реквизит проведения документа?

Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)

Объект=Элементы.Список.ТекущаяСтрока;
Если Объект.Проведен = Ложь Тогда
Сообщить("Документ не проведен !!! Печать не возможна");
Возврат;
КонецЕсли;

УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Элементы.Список);
КонецПроцедуры

Спасибо заранее!
40. nick-max 249 25.09.16 03:24 Сейчас в теме
(39) zmx,

думаю, тут лучше использовать Элементы.Список.ТекущиеДанные.Ссылка.Проведен, при условии, что в список выведена колонка Ссылка. Но я бы такие проверки перенес внутрь функций типа СформироватьПриказ
41. Perk0n 13 31.07.17 11:12 Сейчас в теме
Be aware.. в новой БСП поменяли принцип подключения своих команд. Статью бы немного дополнить, так как в данном виде она утратила свою актуальность.

Вместо методов из "СтандартныеПодсистемы.Печать"

&НаКлиенте 
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)	
	УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Объект)	
КонецПроцедуры  


Следует использовать методы из "СтандартныеПодсистемы.ПодключаемыеКоманды"
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры
42. slauter77 20 06.10.17 10:17 Сейчас в теме
Спасибо за предупреждение! (41)
От себя добавлю, что например в Бух КОРП 3.0.52.39 нужно в модуле: "ОбщийМодуль.УправлениеПечатьюПереопределяемый"

в процедуру:
 Процедура ПриОпределенииОбъектовСКомандамиПечати(СписокОбъектов) Экспорт 


добавить строку типа:
СписокОбъектов.Добавить(Документы.ИмяВашегоДокумента)


тогда, с учетом изменений описанных Вами, печать заработает!

(просто сам долго копался с этим)
mlv84; rmarkovych; insurgut; EMelihoff; lina_00; k0pai; ye_s; 777Ferz777; +8 Ответить
43. 777Ferz777 8 17.10.17 08:59 Сейчас в теме
С новыми обновами, новые веянья
Вызовы вида:
// СтандартныеПодсистемы.Печать
&НаКлиенте
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.Печать


следует заменить вызовами:

// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, <ОбъектИлиТаблицаФормы>);
КонецПроцедуры
 
&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, <ОбъектИлиТаблицаФормы>, Результат);
КонецПроцедуры
 
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
Показать


более подробно читайте здесь http://downloads.v8.1c.ru/content/SSL/2_4_3_84/change.htm
44. nadjushka 19 28.03.18 10:10 Сейчас в теме
Добавление команд печати в Бухгалтерии 3.0 после релиза 3.0.52.35

http://1c-soft.it-terminal.ru/public/674880/
45. bds22 20 07.04.18 18:17 Сейчас в теме
в бухгалтерии корп 3.0 мне для того, чтобы появилась возможность печати в моем документе, пришлось в общем модуле "Управление печатью переопределяемый"
в эту процедуру добавить свой документ
Процедура ПриОпределенииОбъектовСКомандамиПечати(СписокОбъектов) Экспорт

там такие строки
СписокОбъектов.Добавить(Документы.ПоступлениеТоваровУслуг);
	СписокОбъектов.Добавить(Документы.ПринятиеКУчетуНМА);
	СписокОбъектов.Добавить(Документы.ПринятиеКУчетуОС);
	СписокОбъектов.Добавить(Документы.ПриходныйКассовыйОрдер);
	СписокОбъектов.Добавить(Документы.РаспределениеНДС);
	СписокОбъектов.Добавить(Документы.РасходныйКассовыйОрдер);

и так далее - все документы
rmarkovych; Артём74; CatZero; +3 Ответить
46. CatZero 12.04.18 06:57 Сейчас в теме
49. vis_tmp 32 18.04.19 19:47 Сейчас в теме
(45) А в самом документе что нужно добавить?
47. liric 26.09.18 17:28 Сейчас в теме
А если я хочу просто напечатать документ в своей самописанной конфе где нет никаких БСП и конструкторы печати теперь не работают. Что делать?
48. newvideo 27.01.19 13:52 Сейчас в теме
УНФ 1.6.5. БСП 2.3.1.53
в модуле УправлениеПечатьюСлужебныйКлиент
в процедуре ВыполнитьПодключаемуюКомандуПечатиПодготовкаОбъектовПечати
вываливается:

{ОбщийМодуль.УправлениеПечатьюСлужебныйКлиент.Модуль(125)}: Ошибка компиляции при вычислении выражения или выполнении фрагмента кода Результат = Вычислить(Обработчик);
по причине:
{(1,1)}: Переменная не определена (УправлениеПечатьюБПКлиент)
<<?>>УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати(ОписаниеКоманды)

Менял в Модуле Менеджера Документа
УправлениеПечатьюБПКлиент на УправлениеПечатьюКлиент и также на
Подключаемый_ВыполнитьКомандуПечати
всёравно ошибки, куда же копать?
51. XelOla 17 06.09.19 15:49 Сейчас в теме
(48) вы разобрались?
ТОже не могу для УНФ вывести
52. newvideo 06.09.19 21:00 Сейчас в теме
(51) давно это было, помню только что разобрался, а что именно сделал к сожалению уже не вспомню) Но конфигурация под рукой, могу сказать что где есть)
53. insurgut 207 08.04.20 16:13 Сейчас в теме
54. Djo82 6 15.05.20 10:19 Сейчас в теме
Если это КА 1.1 например, то печать можно вывести через свойства команды
Прикрепленные файлы:
55. Denic_01 46 02.06.20 18:08 Сейчас в теме
Добавьте в статью прям жирным шрифтом
что если не прописать объект в методе

Процедура ПриОпределенииОбъектовСКомандамиПечати(СписокОбъектов) Экспорт 


модуля УправлениеПечатьюПереопределяемый

ничего работать не будет !!!
criptid; delsoft; SanchoD; Rusel; 111c; ulen; +6 Ответить
Оставьте свое сообщение