Работа с управляемыми блокировками в примерах. Новая схема проведения документов 1с 8.2.

24.07.12

Разработка - Подготовка к аттестации

Много информации есть на тему работы с управляемыми блокировками в 1С 8.2. Но так, как я не нашел статьи, написанной в простых и понятных примерах, то решил написать свою статью. Она будет полезна тем, кто все еще не до конца понимает принципы работы управляемых блокировок и то, чем отличаются блокировки новой схемы проведения от старой.

Будем рассматривать принципы работы управляемых блокировок на некоторой тестовой конфигурации. Учет ведется в разрезе номенклатуры и свойств номенклатуры. Приходная накладная (ПН) ничего не блокирует, но пишет данные в регистр накопления "Остаток товара". На примере документа Расходная накладная (РН) изучим, как работают управляемые блокировки, а затем посмотрим на новую схему проведения документов. В ПН и РН есть одинаковые по структуре табличные части (ТЧ) СписокНоменклатуры, в которых содержится список Номенклатуры, Свойств, Количество, Сумма, Цена:


В Регистре накопления есть соответсвующие измерения: Номенклатура, Свойство и два ресурса - Сумма и Количество. 

Предварительно для работы с управляемыми блокировками установим управляемый режим блокировок для конфигурации в целом и управляемывй режим блокировок отдельно для Приходной накладной, Расходной накладной и для всех регистров, движения по которым эти документы делают. В наших примерах - это один регистр накопления Остаток товара.

Обратим внимание, что в файловой версии можно устанавливать блокировки только на таблицы целиком (см. таблицу ниже), построчные (в разрезе выбранных движений из регистра накопления, например) блокировки в файловом режиме не работают. Примеры тестировались на 1С 8.2 + MS SQL 2008 R2 Express.

Детальнее про поддерживаемые режимы блокировок тут: http://v8.1c.ru/overview/Term_000000642.htm

Примеры рассматриваются на следующих РН и ПН:

ПН - 01

ПН - 02

РН - 01

 

Пример 1. Блокировка по конкретно известной номенклатурной позиции.

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

Движения.ОстаткиНоменклатуры.Записывать = Истина;

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.УстановитьЗначение("Номенклатура",Справочники.Номенклатура.НайтиПоНаименованию("Ботинки")); //поиск по наименованию в целях примера
Блокировка.Заблокировать(); //установили блокировку по номенклатуре с наименованием "Ботинки"

//Далее идет заполнение движений

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по измерению "Номенклатура" с наименованием "Ботинки" и ПН - 02 будет ожидать завершения блокировки регистра накопления по измерению "Номенклатура" с наименованием "Ботинки".

 

Пример 2. Блокировка по конкретно известной паре номенклатурная позиция - свойство.

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

Движения.ОстаткиНоменклатуры.Записывать = Истина;

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.УстановитьЗначение("Номенклатура", Справочники.Номенклатура.НайтиПоНаименованию("Ботинки")); //поиск по наименованию в целях примера
ЭлементБлокировки.УстановитьЗначение("Свойство", Справочники.Свойства.НайтиПоНаименованию("черные 42 размера")); //поиск по наименованию в целях примера
Блокировка.Заблокировать();

//Далее идет заполнение движений
 

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по паре измерений "Номенклатура" (с наименованием "Ботинки") -"Свойство" (с наименованием "черные 42 размера"), а ПН - 02 проведется без ожидания, так как в ее ТЧ СписокНоменклатуры нет пары  "Номенклатура"-"Свойство", которая будет образовывать соответвствующее движение.

 

Пример 3. Блокировка на всю таблицу регистра накопления.

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
Блокировка.Заблокировать();

//Далее идет заполнение движений

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки таблицы регистра накопления и ПН - 02 будет ожидать завершения блокировки таблицы регистра накопления.

 

Пример 4. Блокировка по одному полю из источника данных для блокировки (это, например, список движений или список номенклатуры по которой будут движения).

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
Блокировка.Заблокировать();

//Далее идет заполнение движений

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по измерению "Номенклатура" и значением "Ботинки" из источника СписокНоменклатуры и ПН - 02 будет ожидать завершения блокировки регистра накопления по измерению "Номенклатура" и значением "Ботинки" из источника СписокНоменклатуры (так как именно такое значение реквизита "Номенклатура" в переданной как источник ТЧ).

 

Пример 5. Блокировка по комбинации полей из источника данных для блокировки (это, например, список движений или список номенклатуры со свойствами по которой будут движения).

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

Блокировка = Новый БлокировкаДанных;

ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;

ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Свойство", "Свойство");
Блокировка.Заблокировать();
 

//Далее идет заполнение движений

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по паре измерений "Номенклатура" значение "Ботинки" из переданного источника - "Свойство" значение "черные 42 размера" из переданного источника, а ПН - 02 проведется без ожидания, так как в ее ТЧ СписокНоменклатуры нет пары  "Номенклатура"-"Свойство", которая будет образовывать соответвствующее значениям полей источника блокировки движение.

 

Пример 6. Блокировка по двум полям из источника данных для блокировки.

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

//условие "И" - будут заблокированы и записи для номенклатуры из ТЧ СписокНоменклатуры

// с любыми свойствами и записи для любой номенклатуры со свойствами из ТЧ СписокНоменклатуры
Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;

ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Свойство", "Свойство");
Блокировка.Заблокировать();

//Далее идет заполнение движений

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по измерению "Номенклатура" значение "Ботинки" с любыми свойствами и отдельно по "Свойству" со значением "черные 42 размера" для любой номенклатуры, в ПН - 01 есть и номенклатура "Ботинки" и номенклатура со свойствами "черные 42 размера". Аналогично ПН - 02 будет ожидать завершения блокировки, так как в ПН - 02 есть номенклатура "Ботинки". 

 

Пример 7. Новая схема проведения (чем же отличается БлокироватьДляИзменеия = Истина от блокировок при помощи объекта БлокировкаДанных).

Код процедуры ОбработкаПроведения(Отказ, Режим) модуля объекта документа РасходнаяНакладная:

//Новая схема (без механизма контроля остатков)

//Разбор БлокироватьДляИзменения = Истина
Движения.ОстаткиНоменклатуры.БлокироватьДляИзменения = Истина;
Движения.ОстаткиНоменклатуры.Записать(); //Набор пустой, нет значений полей пространства блокировки. нечего блокировать.


//очень упрощенный пример создания движений расходной
Для Каждого СтрокаН Из СписокНоменклатуры Цикл
Движение = Движения.ОстаткиНоменклатуры.ДобавитьРасход();
Движение.Период = Дата;
Движение.Номенклатура = СтрокаН.Номенклатура;

Движение.Количество = СтрокаН.Количество;
Движение.Сумма = СтрокаН.Сумма;

Движение.Свойство = СтрокаН.Свойство;
КонецЦикла;

//1
Движения.ОстаткиНоменклатуры.БлокироватьДляИзменения = Истина;
Движения.ОстаткиНоменклатуры.Записать(); //Набор не пустой будет выполнена блокировка, источник - ТЧ СписокТоваров


//Далее должен идти механизм контроля остатков

Как это работает:

Если в процессе проведение РН - 01, сделать попытку провести ПН - 01, то она будет ожидать завершения блокировки регистра накопления по паре измерений "Номенклатура" значение "Ботинки" из переданного источника - "Свойство" значение "черные 42 размера" из переданного источника, а ПН - 02 проведется без ожидания, так как в ее ТЧ СписокНоменклатуры нет пары  "Номенклатура"-"Свойство", которая будет образовывать соответвствующее значениям полей источника блокировки движение.

При использовании команды БлокироватьДляИзменения = Истина на регистр накопления по значениям измерений движений установится исключительная блокировка. Никаких конструкций с использованием объекта БлокировкаДанных для этого писать не нужно.

Код под комментарием //1 выше аналогичен следующему коду:

//Работает аналогично, как и 1
Движения.ОстаткиНоменклатуры.Записать();
Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить();
ЭлементБлокировки.Область = "РегистрНакопления.ОстаткиНоменклатуры";
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = Движения.ОстаткиНоменклатуры.Выгрузить();
Для Каждого Измерение Из Метаданные.РегистрыНакопления.ОстаткиНоменклатуры.Измерения Цикл
    ЭлементБлокировки.ИспользоватьИзИсточникаДанных(Измерение.Имя, Измерение.Имя);
КонецЦикла;
Блокировка.Заблокировать();


//Далее должен идти механизм контроля остатков

 

P.S. Отличие исключительных блокировок от разделяемых в изложенных выше примерах в том, что при разделяемом режиме блокировок возможны разделяемые блокировки при параллельном проведении других документов по тем же полям источников данных, что и в заблокированных в данном документе данных. 

См. также

Запросы 1С OnLine. Интерактивная обучающая программа.

Подготовка к аттестации Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Интерактивное изучение языка запросов с самого начала: - 50 практических заданий с различным уровнем сложности; - Методические материалы по практике написания запросов; - Описание назначения таблиц и индексов 1С Предприятие 8; - Методика решения реальных задач запросом 1С; - Автоматическая система проверки решений с указанием ошибок; - Инструкции по решению задач с разъяснениями; - Техническая поддержка пользователей. Подходит для начинающих и действующих разработчиков 1С

1800 руб.

11.02.2014    73832    677    13    

165

Оптимизация запросов 1С - от теории к практике

Подготовка к аттестации Запросы Конфигурации 1cv8 Платные (руб)

Желаете повысить свой уровень разработки? Не знаете, как оптимизировать работу тяжелых запросов 1С? Или знаете методы оптимизации, но на практике не получаете результат? Тогда эта интерактивная обучающая программа для Вас! Оптимизация запросов прямо в программе 1С:Предприятие 8. Несколько десятков практических заданий, рассматривающих методы оптимизации на практике. От Вас требуются реальные решения - оптимизация представленных запросов. Автоматизированная система оценит Ваш запрос и представит результат проверки.

1800 руб.

06.07.2015    70795    118    9    

128

Программист 1С: как начать с нуля с минимальными затратами

Подготовка к аттестации Платформа 1С v8.3 Россия Бесплатно (free)

Информация будет полезна многим начинающим программистам 1C и тем, кто хочет что-то изменить в своей жизни, испытывая жизненные трудности, с минимальными затратами.

18.03.2024    1017    AlOkt    4    

6

Как я готовилась к экзамену на Специалиста по платформе 1С

Подготовка к аттестации Платформа 1С v8.3 Россия Бесплатно (free)

Готовилась три месяца, сдала с первого раза. Делюсь опытом, лайфхаками и ресурсами, по которым учила материал.

14.03.2024    9335    PROSTO-1C    45    

77

Как я стал Экспертом по технологическим вопросам за 3 месяца. Часть 2 (обновлена)

Подготовка к аттестации Бесплатно (free)

Мой опыт подготовки и сдачи к экзамену 1С: Эксперт по технологическим вопросам. Часть 2.

04.02.2024    5613    shuhratsj    16    

71

Как я стал Экспертом по технологическим вопросам за 3 месяца

Подготовка к аттестации Бесплатно (free)

Мой опыт подготовки и сдачи к экзамену 1С: Эксперт по технологическим вопросам за 3 месяца. Часть 1.

29.01.2024    12982    shuhratsj    102    

153

1С: Специалист-консультант ЗУП 8. Решения из сборника задач для подготовки к экзамену «1С:Специалист-консультант» по внедрению прикладного решения „1С:Зарплата и управление персоналом 8“, редакция сентябрь 2023. Часть 6

Подготовка к аттестации Зарплата Кадровый учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Часть шестая. Делюсь сквозным решением 15-ти задач из сборника задач для подготовки к экзамену «1С:Специалист-консультант» по внедрению прикладного решения „1С:Зарплата и управление персоналом 8“, редакция сентябрь 2023.

5 стартмани

01.12.2023    1312    16    Ocherkcons    0    

6

1С: Специалист-консультант ЗУП 8. С чего начать решение билета на экзамене? Актуальность: ноябрь 2023 года

Подготовка к аттестации Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бесплатно (free)

Делюсь наработками из опыта подготовки к экзамену на получение сертификата 1С:Специалист-консультант по внедрению прикладного решения „1С:Зарплата и управление персоналом 8“. Первые минуты на экзамене.

17.11.2023    2344    Ocherkcons    0    

6
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Hany 24.07.12 12:42 Сейчас в теме
Движения.ОстаткиНоменклатуры.БлокироватьДляИзменения = Истина;
Движения.ОстаткиНоменклатуры.Записать(); //Набор пустой, нет значений полей пространства блокировки. нечего блокировать.

Вы забыли уточнить, зачем мы блокируем "пустой" набор. Когда пишется "пустой" набор, то:

1) блокируются данные по "очищаемым" записям (т.е. тем, по которым были движения до перепроведения документа, ведь их тоже надо блокировать, чтобы в случае отмены транзакции гарантировать откат (отказ от проведения и возврат к предыдущим проводкам));
2) все записи очищаются



А также хочу добавить, что "БлокироватьДляИзменения" выставлять в значение "Истина" нужно, если у вас в регистре установлено "Разделение итогов", чтобы "временно отключить" это разделение.
SagittariusA; Snakesa; portwein; Alex_Nash; sergo89; unduty; Hagaro; Divanoff; user712426; Winstoncuk; rendalina; КДЕ; kolya_tlt; yuraer; lllayka; Intel_Man; vitunchik; it@contlog.ru; ZPGS; Ekovichev; SadrArt; JesteR; AlexBloim; Elvisnya; Spacer; tormozit; mikhailovaew; awk; Invaa; +29 Ответить
24. mihan 117 11.05.13 17:39 Сейчас в теме
(1) Hany,
блокировать старые записи имхо перестраховка, другой документ итоги вроде не должен поменять по нормальному, он же будет считывать остаток чтобы в минус не уйти, а считать не сможет, так как одна из строк таблицы итогов эксклюзивно заблокирована первым документом
42. kuzyara 1900 04.07.17 04:14 Сейчас в теме
(1)
1) блокируются данные по "очищаемым" записям (т.е. тем, по которым были движения до перепроведения документа, ведь их тоже надо блокировать, чтобы в случае отмены транзакции гарантировать * (отказ от проведения и возврат к предыдущим проводкам));

боже, какой бред...
43. nytlenc 19.07.17 14:37 Сейчас в теме
(42) Согласен.... Оптимизм у автора комментария явно страдает.
44. sokir 2 24.07.17 17:45 Сейчас в теме
(42) в чем же бред? Как бы все верно.
(43) тоесть если написано без оптимизма - значит не верно? Странная логика.
45. nytlenc 25.07.17 09:07 Сейчас в теме
(44) оптимизм тут не причем. Читайте про оптимистические блокировки
2. Fruit83 28 26.07.12 22:57 Сейчас в теме
Отличие исключительных блокировок от разделяемых в изложенных выше примерах в том, что при разделяемом режиме блокировок возможны разделяемые блокировки при параллельном проведении других документов по тем же полям источников данных, что и в заблокированных в данном документе данных.


Я читал более простое объяснение. При исключительных блокировках записывать ничего нельзя и читать данные тоже нельзя. При разделяемых читать данные можно.
SagittariusA; POWone; KBNIKKB; +3 Ответить
3. kilokilo 18 27.07.12 01:25 Сейчас в теме
Хотя работа в блокировками мне знакома - большое спасибо, что разместили статью не в скачиваемом файле.
4. erina_valentina 88 27.07.12 04:57 Сейчас в теме
Спасибо! Очень полезная и интересная статья!
5. khaoos 239 27.07.12 10:11 Сейчас в теме
Автор молодец. Хорошо пишешь. Неплохо было бы и первый комментарий от Hany изящно как-нибудь воткнуть в статью :) и добавить к нему, что при записи управляемые блокировки накладываются всегда (конечно, при соответствующем режиме) и БлокироватьДляИзменения нужно, чтобы в блокировках не учитывалось это самое измерение-разделитель. Ну в PS после статьи как-то мысль хитро завернута в слова, что на месте человека впервые разбирающегося с блокировками я бы не понял этой мысли :)
11. mikhailovaew 127 31.07.12 10:54 Сейчас в теме
Спасибо за статью!
Присоединюсь к (5): не все читают комментарии, а замечание из (1) ценное, лучше его разместить в самой статье, хотя бы в комментариях в коде
12. Invaa 409 31.07.12 11:22 Сейчас в теме
(11) mikhailovaew,

добавлю ценные замечания в статью обязательно и спасибо за них :) руки пока не дошли еще...
6. sockor 58 27.07.12 11:04 Сейчас в теме
вот спасибо, никак время не находил это изучить.
7. Altair777 644 27.07.12 11:46 Сейчас в теме
К концу статьи начинает коробить от тавтологий. Копипаст рулит :)
8. tolyan_ekb 104 27.07.12 14:55 Сейчас в теме
спасибо. Полезная статья с примерами и комментариями. Надеюсь, скоро попробую с блокировками поработать.
9. DenisCh 27.07.12 15:08 Сейчас в теме
Спасибо, полезная статья.
10. пользователь 30.07.12 07:44
Сообщение было скрыто модератором.
...
13. briz 71 01.08.12 10:33 Сейчас в теме
Вопрос , а как поведет в примере 5 ПН 2, если в РН будет еще такая запись : Ботинки,Со шпильками 37 размера. ?
15. Invaa 409 01.08.12 16:20 Сейчас в теме
(13) briz,

При блокировках РН, устанавливаемых в примере 5, и наличии в РН записи "Ботинки,Со шпильками 37", ПН 2 проведется, так как в этой приходной нет записей соотвествующих блокировкам. Есть записи отдельно по товару "Ботинки", отдельно по свойству "Со шпильками 37", но не с парой "Ботинки"-"Со шпильками 37".
16. briz 71 01.08.12 16:40 Сейчас в теме
(15)есть подозрение что блокируется все комбинации товаров и свойств, поэтому, имхо, ПН 2 будет ждать
17. Invaa 409 01.08.12 17:15 Сейчас в теме
(16) briz,

такая блокировка накладывается в примере 6
14. пользователь 01.08.12 13:03
Сообщение было скрыто модератором.
...
18. hogik 443 01.08.12 23:47 Сейчас в теме
(0)
Вызывает сомнение утверждение в первом примере, что приходные накладные будут ожидать завершение проведения расходной накладной, если код управляемых блокировок будет внесен только в расходную накладную.

"Следует помнить, что чтение данных другими транзакциями будет невозможно только в том случае, если в других транзакциях устанавливаются несовместимые управляемые блокировки. Если управляемые блокировки в других транзакциях не устанавливаются, то чтение будет возможно."(с)

http://www.lavelin.ru/index.php/articles/1s/18-razrabotka/93-blokirovki-dannyh-v-1spredpriyatii-8

Или я ошибаюсь?
19. rozer 306 20.10.12 10:52 Сейчас в теме
согласен с (18), только если в ПН прописать блокировки тогда утверждения в статье верны.
21. USER--1C 60 30.12.12 21:37 Сейчас в теме
(18) hogik, Посмотрите дату статьи (2007 г.): http://www.lavelin.ru/index.php/articles/1s/18-razrabotka/93-blokirovki-dannyh-v-1spredpriyatii-8
В конце указано: "Автор: © Белоусов Павел (Альтер Лого, Москва). Данная статья является фрагментом книги П.С.Белоусов, А.В.Островерх "1С:Предприятие: от 8.0 к 8.1". Дата выхода книги: ноябрь 2007.
(Информация с ресурса http://1cexpo.ru)"

На ИТС есть более свежие статьи по блокировкам, в том числе для 8.2. Например: от 18.08.2010 "Анализ и устранение взаимоблокировок" (для имеющих доступ на ИТС: http://www.its.1c.ru/db/metod81#content:4051:1)
22. hogik 443 30.12.12 21:54 Сейчас в теме
(21)
"Посмотрите дату статьи (2007 г.)"(с)
Информация устарела?
Т.е. в (18) сообщении я ошибаюсь? ;-)
39. Sanya2049 39 26.10.15 22:10 Сейчас в теме
Пытаю воспроизвести нечего не выходит
Блокировка = Новый БлокировкаДанных;
	ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.ОстаткиНоменклатуры");
	ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
	ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
	ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
	Блокировка.Заблокировать(); 

Ошибка при выполнении обработчика - 'ОбработкаПроведения'
по причине:
{Документ.РасходнаяНакладная.МодульОбъекта(18)}: Ошибка при вызове метода контекста (Заблокировать)
Блокировка.Заблокировать();
по причине:
Использование блокировки допустимо только внутри транзакции в режиме управляемых блокировок!
40. azhilichev 213 29.12.15 06:28 Сейчас в теме
(39) Sanya2049, Проверьте, что у вас документ находится в режиме управляемых блокировок:
Прикрепленные файлы:
20. chemezov 47 29.11.12 12:08 Сейчас в теме
мне очень не хватало этой информации для понимания блокировок. огромное спасибо, +1.
23. rеd80 26.03.13 11:31 Сейчас в теме
Отличие исключительных блокировок от разделяемых в изложенных выше примерах в том, что при разделяемом режиме блокировок возможны разделяемые блокировки при параллельном проведении других документов по тем же полям источников данных, что и в заблокированных в данном документе данных.

Не понял о чем это. Для меня понятна следующая разница:
В режиме разделяемых блокировок блокированные записи остаются доступны для чтения другим пользователям и недоступны для записи.
В режиме исключительных блокировок блокированные записи недоступны для чтения другим пользователям и недоступны для записи.
kako1toxren; marsohod; RailMen; ankorobov; vitunchik; it@contlog.ru; memfree; +7 Ответить
25. zigomodo 26.08.13 11:26 Сейчас в теме
Столкнулся с данной проблемой, статья очень кстати.
26. ZLENKO 398 27.08.13 13:25 Сейчас в теме
В настоящее время подходы, изложенные в статье, потеряли актуальность. Появились более прогрессивные подходы по использованию управляемых блокировок при проведении документов. Вот это больше соответствует современным реалиям http://infostart.ru/public/195591/
27. mr.Kot 10.01.14 15:55 Сейчас в теме
Хорошо структурирован и подан текст, всё становится понятно. Жаль, что первый комментарий в статье так и не учли. А я как знал, что в коментах обязательно что-нибудь дельное промелькнёт.
28. tiniji 164 03.02.14 17:22 Сейчас в теме
Правильно ли я понимаю?
Если включить управляемые блокировки в УТ 10.3 для всей конфигурации (т.е. будут все объекты с упр. блокировками), то необходимо добавить блокировки на регистр ВзаиморасчетыСКонтрагентами (при контроле долга). На регистры товаров (НТТ, Розница, опт, организаций) при контроле остатков. И Регистры "Партии товаров", т.к. списание происходит по ФИФО. Регистры НДС не беру, т.к. ими не пользуемся.
Нужно ли кроме этого управлять блокировками других объектов? Журналы, последовательность и др.
Спрашиваю заранее, что бы не набивать шишки при переходе.
34. ZLENKO 398 29.04.15 12:09 Сейчас в теме
(28) tiniji, "Спрашиваю заранее, что бы не набивать шишки при переходе."

Чтобы не набить "шишки" Вам необходимо досконально разобраться в вопросах, связанных с управляемыми блокировками. Вам необходимо понимать что у Вас есть сейчас и что Вы хотите получить в результате. Данная статья просто описывает механизмы платформы. К практике использования управляемых блокировок в реальных конфигурациях она отношения не имеет. Поймите что нет "серебряной пули" для борьбы с избыточными блокировками.
29. Alex123456 09.09.14 17:18 Сейчас в теме
Спасибо за статью. Как раз надо решить проблему с блокировками.
30. monstruz 10.09.14 14:30 Сейчас в теме
31. Nigelist 24.09.14 16:14 Сейчас в теме
Подскажите в в каких регистрах можно использовать управляемые блокировки? В регистрах накопления, сведений, бухгалтерии? Периодических и прочих регистрах?
32. nvv1970 28.04.15 22:27 Сейчас в теме
Различные тесты показали, что управляемые блокировки в 8.2 - это полная неадекватность. В 8.3 поведение вполне адекватное, за исключением некоторых особенностей.
33. ZLENKO 398 29.04.15 12:03 Сейчас в теме
(32) nvv1970, "Различные тесты показали, что управляемые блокировки в 8.2 - это полная неадекватность."

Думаю Вы просто не до конца разобрались в вопросе. В последних релизах 8.2 вполне адекватно работают.
С чем именно у Вас возникли сложности ? Просто "полного счастья" с управляемыми блокировками при использовании MS SQL Server можно добиться только при переводе базы в режим версионирования (а не блокировщика), а для 8.2 это не "штатный" режим, хотя все отлично работает.
35. ZLENKO 398 29.04.15 12:12 Сейчас в теме
Цитата из кода статьи: "Движения.ОстаткиНоменклатуры.Записать(); "

Никогда так не поступайте - это прямой путь к взаимоблокировкам !
47. YaroslavS 23.10.21 12:59 Сейчас в теме
(35)
"Цитата из кода статьи: "Движения.ОстаткиНоменклатуры.Записать(); "

Никогда так не поступайте - это прямой путь к взаимоблокировкам !"

Прошу прощения за некро пост, но думаю это вы неправы, тут явная ошибка в применении "новой" схемы контроля остатков, но никак не путь к взаимоблокировкам в версии 8.2 + mssql. Что в коде не так - излишняя очистка регистра перед записью новых движений. Почему не ведет к взаимоблокировке? Потому что использован признак БлокироватьДляИзменения, который в случае, если наш регистр (накопления или бухгалтерии) использует разделение данных, при помещении набора записей в базу накладывается неявная блокировка БЕЗ ИСПОЛЬЗОВАНИЯ разделителя в таблице итогов до конца транзакции. Что в итоге приведет к корректному поведению документов при параллельном проведении. Не будет возможности двум документам провести одновременную запись в регистр (нам это не даст сделать отсутствия разделителя в неявных блокировках на таблицу итогов-остатков) и затем встать в дедлок, когда они будут по "новой" схеме контролировать отрицательный остаток запросом, который никак не учитывает разделитель. (каждый пытается прочитать запись в итогах заблокированную другим документом - дедлок). Хотя вероятно вы и сами все знаете.
49. YaroslavS 23.10.21 14:24 Сейчас в теме
(35) (35) Дошло что имеется в виду, дедлоки из за несовпадения в разных документах порядка записи в регистры. Документ 1 записал в регистр 1 готовиться писать в регистр 2, одновременно с ним документ 2 записал в регистр 2 готовиться писать в регистр 1. Если по блокировкам на записи одних и тех же регистров есть пересечения в обоих случаях вторых по порядку записей с первыми конкурирующего документа, то оба документа встанут в дедлок. Да действительно такая проблема есть, но отказаться от явной записи в регистры мы не сможем, пока у нас есть контроль остатков, что по старому методу, что по новому, и не важно как мы это сделаем: с помощью Движения.ОстаткиТоваров.Записать() или Движения.ОстаткиТоваров.Записывать = Истина; Движения.Записать(); Тут уже нужно придерживаться порядка в записи в регистры, если у нас есть контроль остатков в разных документах по нескольким регистрам. А лишние Движения.ИмяРегистра.Записать(); действительно не нужны.
36. alex44ru 17.06.15 16:08 Сейчас в теме
Спасибо за статью, все понятно написано.

Меня смутил ответ Максим Радченко, 1С на форуме http://devtrainingforum.v8.1c.ru/forum/thread.jsp?id=572655&threadtype=0, а именно:
....................

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.ТоварыНаСкладах");
ЭлементБлокировки.УстановитьЗначение("Качество", Справочники.Качество.НайтиПоКоду("1"));
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = ДокументОбъект.ВозвратнаяТара;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Склад", "Склад");
Блокировка.Заблокировать();

....................
Блокировка будет наложена на те записи, в которых:
- есть номенклатура из табличной части ВозвратнаяТара и Качество равно указанному значению,
или
- есть склад из табличной части ВозвратнаяТара и Качество равно указанному значению.
Если нужно блокировать только по сочетанию значений Номенклатура - Склад, которые есть в табличной части, нужно использовать один оператор ИспользоватьИзИсточникаДанных, указывая в нем два поля через запятую.

из его ответа следует что у Вас в пятом примере будет блокировка на номенклатуру или на свойство, помогите разобраться кто прав ?
Ксакеп; +1 Ответить
41. fzt 29.12.15 06:41 Сейчас в теме
(36) alex44ru, возьми да проверь)
37. Firefox27 17.06.15 16:35 Сейчас в теме
Чтоб избавмтса от блокировок чаще используйте запроси для получения данных. И как можна менше получайте реквизиты объектов через точку.
38. ZLENKO 398 18.06.15 12:00 Сейчас в теме
(37) Firefox27, "И как можна менше получайте реквизиты объектов через точку."

Чем быстрее (меньше длительность транзакции) проводятся документы, тем меньше вероятность возникновения блокировки.
46. Xershi 1474 21.10.19 13:20 Сейчас в теме
В справочнике характеристик завели доп. реквизит порядковый номер. Он должен быть уникальный, генерируется вычислением максимального значения этого реквизита с добавлением +1.
Чтобы исключить его дублирование при программном создании элементов написал такую блокировку:
Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить("Справочник.ХарактеристикиНоменклатуры");
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
Блокировка.Заблокировать();

Если есть решение лучше, то было бы хорошо это озвучить и добавить в статью!
В конфигурации режим управления блокировками управляемый стоит. И данный код должен быть в транзакции, иначе у меня в ошибку выбивало на
Блокировка.Заблокировать()
48. YaroslavS 23.10.21 14:23 Сейчас в теме
50. 3soft 8 23.01.23 12:57 Сейчас в теме
Движения.ОстаткиНоменклатуры.Записать(); //Набор не пустой будет выполнена блокировка, источник - ТЧ СписокТоваров

Вероятно, правильнее было бы: источник - набор движений Движения.ОстаткиНоменклатуры, который в свою очередь, был заполнен из ТЧ СписокТоваров
51. TVA_11 04.08.23 15:04 Сейчас в теме

Пока истина Цикл

   Попытка
         Блокировка.Заблокировать();
         ...
         Движения.ОстаткиНоменклатуры.Записать();
         прервать;
   Исключение
   КонецПопытки;

КонецЦикла;
         Блокировка.Разблокировать();
Показать


Вопрос, можно ли таким способом немного подождать?
Оставьте свое сообщение