Покажите простой пример прямого запроса, например, по остаткам на складе

    Запрос                     = СоздатьОбъект("Запрос");
    ТекстЗапроса             = "//{{ЗАПРОС(Сформировать)
    |Период с ВыбДокумент по ДатаКонцаАнализа;
    |Заявка         =    Регистр.Заявки.      ЗаявкаПокупателя,
    |                  Регистр.ЗаказыЗаявки.ЗаявкаПокупателя,
    |                  Регистр.РезервыТМЦ.  ЗаявкаПокупателя;
    |ТекДок         = Регистр.Заявки.ТекущийДокумент;
   |Фирма           = Регистр.РезервыТМЦ.Фирма,
   |                 Регистр.ОстаткиТМЦ.Фирма,
   |                 Регистр.Заявки.    Фирма,
   |                 Регистр.ЗаказыЗаявки.ЗаявкаПокупателя.Фирма;
    |КолЗаявки       = Регистр.Заявки.      КоличествоРасход;
    |КолЗаказа       = Регистр.ЗаказыЗаявки.Количество;
    |КолРезерва      = Регистр.РезервыТМЦ.  Количество;
    |КолОстатка      = Регистр.ОстаткиТМЦ.  Количество;
    |Номенклатура    = Регистр.Заявки.      Номенклатура,
    |               Регистр.ЗаказыЗаявки.Номенклатура,
    |               Регистр.РезервыТМЦ.  Номенклатура,
    |               Регистр.ОстаткиТМЦ.  Номенклатура;
    |Функция ВыписанаЗаявка        = Приход(КолЗаявки)  Когда (Заявка в ВыбДокумент);
    |Функция ОстатокНаСкладах   = КонОст(КолОстатка);
    |Функция ЧужиеРезервы       = КонОст(КолРезерва) Когда (Заявка <> ВыбДокумент);
    |Функция Зарезервировано    = КонОст(КолРезерва) Когда (Заявка в ВыбДокумент);
    |Функция СнятаЗаявка         = Расход(КолЗаявки)  Когда((Заявка в ВыбДокумент) и ((ТекДок.Вид() = ""ЗаявкаПокупателя"") или (ТекДок.Вид() = ""ОтменаЗаявок"")));
    |Функция ОстатокЗаявки      = КонОст(КолЗаявки)  Когда (Заявка в ВыбДокумент);
    |Функция ЗаказаноПоставщику = КонОст(КолЗаказа)  Когда (Заявка в ВыбДокумент);
    |Функция Отпущено            = Расход(КолЗаявки)  Когда((Заявка в ВыбДокумент) и (ТекДок.Вид() <> ""ЗаявкаПокупателя"") и (ТекДок.Вид() <> ""ОтменаЗаявок""));
    |Группировка Номенклатура Без Групп;
    |Условие (Номенклатура в СписокНоменклатура);
   |Условие (Фирма в ФирмаЗаявки);";
    
    // Если ошибка в запросе, то выход из процедуры
    Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда Возврат; КонецЕсли;

Запрос=СоздатьОбъект("ODBCRecordSet");
Запрос.УложитьСписокОбъектов(СписокНоменклатура, "#ВремТовары", "Номенклатура");
Запрос.УстановитьТекстовыйПараметр("ФирмаЗаявки", ФирмаЗаявки);
Запрос.УстановитьТекстовыйПараметр("ВыбДокумент", ВыбДокумент);
Запрос.УстановитьТекстовыйПараметр("ДатаКонцаАнализа", ДатаКонцаАнализа);

тз=Запрос.ВыполнитьИнструкцию(
"select
|   Рез.Номенклатура         [Номенклатура $Справочник.Номенклатура],
|   sum(Рез.ОстатокЗаявки)      [ОстатокЗаявки],
|   sum(Рез.ВыписанаЗаявка)    [ВыписанаЗаявка],
|   sum(Рез.СнятаЗаявка)      [СнятаЗаявка],
|   sum(Рез.Отпущено)         [Отпущено],
|   sum(Рез.ОстатокНаСкладах)   [ОстатокНаСкладах],
|   sum(Рез.ЧужиеРезервы)      [ЧужиеРезервы],
|   sum(Рез.Зарезервировано)   [Зарезервировано],
|   sum(Рез.ЗаказаноПоставщику)   [ЗаказаноПоставщику]
|from(
|   select -- ОстатокЗаявки = КонОст(КолЗаявки)  Когда (Заявка в ВыбДокумент)
|      РегЗаявка_О.Номенклатура [Номенклатура],
|      РегЗаявка_О.КоличествоРасходОстаток [ОстатокЗаявки],
|      0 [ВыписанаЗаявка],
|      0 [СнятаЗаявка],
|      0 [Отпущено],
|      0 [ОстатокНаСкладах],
|      0 [ЧужиеРезервы],
|      0 [Зарезервировано],
|      0 [ЗаказаноПоставщику]
|      from $РегистрОстатки.Заявки(:ДатаКонцаАнализа~,
|         inner join #ВремТовары ON Номенклатура=#ВремТовары.val,
|         ЗаявкаПокупателя=:ВыбДокумент and Фирма=:ФирмаЗаявки,
|         Номенклатура, КоличествоРасход) as РегЗаявка_О
|   union all
|   select -- ВыписанаЗаявка, СнятаЗаявка, Отпущено
|      $РегЗаявка_Д.Номенклатура,
|      0,
|      sum(case РегЗаявка_Д.debkred when 0 then $РегЗаявка_Д.КоличествоРасход else 0 end),
|      sum(case РегЗаявка_Д.debkred when 0 then 0 else
|            case when Журн.iddocdef=$ВидДокумента.ЗаявкаПокупателя or Журн.iddocdef=$ВидДокумента.ОтменаЗаявок then $РегЗаявка_Д.КоличествоРасход
|            else 0
|            end
|      end),
|      sum(case РегЗаявка_Д.debkred when 0 then 0 else
|            case when Журн.iddocdef=$ВидДокумента.ЗаявкаПокупателя or Журн.iddocdef=$ВидДокумента.ОтменаЗаявок then 0
|            else $РегЗаявка_Д.КоличествоРасход
|            end
|      end),
|      0,
|      0,
|      0,
|      0
|      from $Регистр.Заявки РегЗаявка_Д inner join _1sjourn Журн on РегЗаявка_Д.iddoc=Журн.iddoc
|         inner join #ВремТовары on $РегЗаявка_Д.Номенклатура=#ВремТовары.val
|      where Журн.date_time_iddoc >= :ВыбДокумент~~~~ and Журн.date_time_iddoc <= :ДатаКонцаАнализа
|         and $РегЗаявка_Д.ЗаявкаПокупателя=:ВыбДокумент and $РегЗаявка_Д.Фирма = :ФирмаЗаявки
|      group by $РегЗаявка_Д.Номенклатура
|      having
|         sum(case РегЗаявка_Д.debkred when 0 then $РегЗаявка_Д.КоличествоРасход else 0 end)<>0 or
   |      sum(case РегЗаявка_Д.debkred when 0 then 0 else
|            case when Журн.iddocdef=$ВидДокумента.ЗаявкаПокупателя or Журн.iddocdef=$ВидДокумента.ОтменаЗаявок then $РегЗаявка_Д.КоличествоРасход
|            else 0
|            end
|         end) <> 0 or
|         sum(case РегЗаявка_Д.debkred when 0 then 0 else
|            case when Журн.iddocdef=$ВидДокумента.ЗаявкаПокупателя or Журн.iddocdef=$ВидДокумента.ОтменаЗаявок then 0
|            else $РегЗаявка_Д.КоличествоРасход
|            end
|         end)<>0
|   union all
|   select -- ОстатокНаСкладах   = КонОст(КолОстатка)
|      РегОстТМЦ.Номенклатура,
|      0,
|      0,
|      0,
|      0,
|      РегОстТМЦ.КоличествоОстаток,
|      0,
|      0,
|      0
|      from $РегистрОстатки.ОстаткиТМЦ(:ДатаКонцаАнализа~,
|         inner join #ВремТовары ON Номенклатура=#ВремТовары.val,
|         Фирма=:ФирмаЗаявки,
|         Номенклатура, Количество) as РегОстТМЦ
|   union all
|   select -- ЗаказаноПоставщику = КонОст(КолЗаказа)  Когда (Заявка в ВыбДокумент)
|      РегЗаказыЗаявки.Номенклатура,
|      0,
|      0,
|      0,
|      0,
|      0,
|      0,
|      0,
|      РегЗаказыЗаявки.КоличествоОстаток
|      from $РегистрОстатки.ЗаказыЗаявки(:ДатаКонцаАнализа~,
|         inner join #ВремТовары ON Номенклатура=#ВремТовары.val,
|         ЗаявкаПокупателя=:ВыбДокумент and Фирма=:ФирмаЗаявки,
|         Номенклатура, Количество) as РегЗаказыЗаявки
|   union all
|   select -- ЧужиеРезервы = КонОст(КолРезерва) Когда (Заявка <> ВыбДокумент)
|      РегРезервы1.Номенклатура,
|      0,
|      0,
|      0,
|      0,
|      0,
|      РегРезервы1.КоличествоОстаток,
|      0,
|      0
|      from $РегистрОстатки.РезервыТМЦ(:ДатаКонцаАнализа~,
|         inner join #ВремТовары ON Номенклатура=#ВремТовары.val,
|         ЗаявкаПокупателя<>:ВыбДокумент and Фирма=:ФирмаЗаявки,
|         Номенклатура, КоличествоРасход) as РегРезервы1
|   union all
|   select -- Зарезервировано = КонОст(КолРезерва) Когда (Заявка в ВыбДокумент)
|      РегРезервы2.Номенклатура,
|      0,
|      0,
|      0,
|      0,
|      0,
|      0,
|      РегРезервы2.КоличествоОстаток,
|      0
|      from $РегистрОстатки.РезервыТМЦ(:ДатаКонцаАнализа~,
|         inner join #ВремТовары ON Номенклатура=#ВремТовары.val,
|         ЗаявкаПокупателя=:ВыбДокумент and Фирма=:ФирмаЗаявки,
|         Номенклатура, КоличествоРасход) as РегРезервы2
|) as Рез
|group by Рез.Номенклатура");
тз.ВыбратьСтроку();