1С 8.2 УПП Регистр ПродажиСебестоимость

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3

1. mdmdvd 51 03.10.11 17:38 Сейчас в теме

Нужен совет знатоков. Имеется код запроса
ВЫБРАТЬ
ПродажиСебестоимость.Номенклатура КАК Номенклатура,
ПродажиСебестоимость.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
ПродажиСебестоимость.ЗаказПокупателя КАК ЗаказПокупателя,
ВЫБОР
КОГДА ПродажиСебестоимость.ДокументДвижения <> НЕОПРЕДЕЛЕНО
ТОГДА ПродажиСебестоимость.ДокументДвижения
ИНАЧЕ ПродажиСебестоимость.Регистратор
КОНЕЦ КАК Регистратор,
ПродажиСебестоимость.Стоимость КАК СтоимостьОборот
ИЗ
РегистрНакопления.ПродажиСебестоимость КАК ПродажиСебестоимость
Каким образом можно присоединить к нему следующий кусок кода:
ВЫБРАТЬ
ЦеныНоменклатурыСрезПоследних.Номенклатура,
ЦеныНоменклатурыСрезПоследних.ТипЦен,
ЦеныНоменклатурыСрезПоследних.Цена
ИЗ
РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&НаДату, ) КАК ЦеныНоменклатурыСрезПоследних
ГДЕ
ЦеныНоменклатурыСрезПоследних.ТипЦен = &ТипЦен
С таким условием чтобы параметр НаДату принимал значение Регистратор.Дата
соеднинение будет по номенклатуре
Заранее спасибо

По теме из базы знаний

Восстановление последовательности партий по движениям регистраторов

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. anig99 2844 03.10.11 20:35 Сейчас в теме

(1) чисто в запросе это невозможно. Только через СКД, там можно объединять источники данных с передачей в параметры полей.

3. Adriann 04.10.11 11:13 Сейчас в теме

Нашел пример на СКД http://help1c.com/faq/view/962.html

4. Adriann 04.10.11 11:38 Сейчас в теме

Вроде так должно работать. Навеяно примером http://help1c.com/faq/view/964.html

ВЫБРАТЬ
	ПродажиСебестоимость.Период КАК Дата,
	ПродажиСебестоимость.Номенклатура КАК Номенклатура,
	ПродажиСебестоимость.ХарактеристикаНоменклатуры,
	ПродажиСебестоимость.ЗаказПокупателя,
	ВЫБОР
		КОГДА ПродажиСебестоимость.ДокументДвижения <> НЕОПРЕДЕЛЕНО
			ТОГДА ПродажиСебестоимость.ДокументДвижения
		ИНАЧЕ ПродажиСебестоимость.Регистратор
	КОНЕЦ КАК Регистратор,
	СУММА(ПродажиСебестоимость.Стоимость) КАК СтоимостьОборот
ПОМЕСТИТЬ втБезЦены
ИЗ
	РегистрНакопления.ПродажиСебестоимость КАК ПродажиСебестоимость

СГРУППИРОВАТЬ ПО
	ПродажиСебестоимость.Номенклатура,
	ПродажиСебестоимость.ХарактеристикаНоменклатуры,
	ПродажиСебестоимость.ЗаказПокупателя,
	ВЫБОР
		КОГДА ПродажиСебестоимость.ДокументДвижения <> НЕОПРЕДЕЛЕНО
			ТОГДА ПродажиСебестоимость.ДокументДвижения
		ИНАЧЕ ПродажиСебестоимость.Регистратор
	КОНЕЦ,
	ПродажиСебестоимость.Период

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	втБезЦены.Дата КАК Дата,
	МАКСИМУМ(ЦеныНоменклатуры.Период) КАК Период,
	втБезЦены.Номенклатура КАК Номенклатура,
	втБезЦены.ХарактеристикаНоменклатуры,
	втБезЦены.ЗаказПокупателя,
	втБезЦены.Регистратор,
	втБезЦены.СтоимостьОборот
ПОМЕСТИТЬ втМаксПериод
ИЗ
	втБезЦены КАК втБезЦены
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
		ПО втБезЦены.Номенклатура = ЦеныНоменклатуры.Номенклатура
			И втБезЦены.Дата >= ЦеныНоменклатуры.Период

СГРУППИРОВАТЬ ПО
	втБезЦены.Дата,
	втБезЦены.Номенклатура,
	втБезЦены.СтоимостьОборот,
	втБезЦены.ХарактеристикаНоменклатуры,
	втБезЦены.Регистратор,
	втБезЦены.ЗаказПокупателя

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Дата,
	Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	втМаксПериод.Период,
	втМаксПериод.Номенклатура,
	втМаксПериод.ХарактеристикаНоменклатуры,
	втМаксПериод.ЗаказПокупателя,
	втМаксПериод.Регистратор,
	втМаксПериод.СтоимостьОборот,
	ЦеныНоменклатуры.Цена
ИЗ
	втМаксПериод КАК втМаксПериод
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
		ПО втМаксПериод.Номенклатура = ЦеныНоменклатуры.Номенклатура
			И втМаксПериод.Период = ЦеныНоменклатуры.Период
ГДЕ
	ЦеныНоменклатуры.ТипЦен = &ТипЦен
АВТОУПОРЯДОЧИВАНИЕ

Показать

Оставьте свое сообщение

E-mail: