api МЧД ФНС

Функция ДанныеДоверенностиXDTO(ДокументДиадок)
	
	Результат = Новый Структура;
	Результат.Вставить("ДанныеПригодны", Ложь);
	Результат.Вставить("ДанныеXDTO");
	Результат.Вставить("ВерсияДоверенности");
	
	СобытияМЧД = КонтурДиадок.СобытияМЧД(ДокументДиадок, Истина);
	Если Не ЗначениеЗаполнено(СобытияМЧД) Тогда 
		Возврат Результат;
	КонецЕсли;
	
	ИдентификаторДоверенности = СобытияМЧД[0].ИнформацияОДоверенности.Идентификатор;
	ИННДоверителя = СобытияМЧД[0].ИнформацияОДоверенности.Доверитель.ИНН; 
	
	МодульМЧД = ОбщегоНазначения.ОбщийМодуль("МашиночитаемыеДоверенности");
	#Если Сервер И Не Сервер Тогда // Фейк для автокомплита
		// 10.02.2026, С.Долинин. Возможно, нужно убрать фейк. Т.к. в ДО такого модуля может и нет.
		МодульМЧД = МашиночитаемыеДоверенности;
	#КонецЕсли // Конец фейковой директивы
	
	//  ПолныеДанныеДоверенности - Полные данные доверенности:
	//   * ДанныеВыгрузки - ДвоичныеДанные, Неопределено - Данные выгрузки
	//   * ДанныеПодписи - ДвоичныеДанные, Неопределено - Данные подписи
	//   * ДанныеАрхива - ДвоичныеДанные, Неопределено - Данные архива
	//   * СтатусПолучения - Строка - Статус получения
	//   * ТекстОтвета - Строка - Текст ответа сервера МЧД
	ПолныеДанныеДоверенности = МодульМЧД.ПолучитьПолныеДанныеДоверенностиНаСервереМЧД(
		ИдентификаторДоверенности, ИННДоверителя); 
	Если ПолныеДанныеДоверенности.ДанныеАрхива=Неопределено Тогда 
		Возврат Результат;
	КонецЕсли; 
	
	ВременныйКаталог = РаботаСФайламиБЭД.ВременныйКаталог();
	Попытка
		ЧтениеZipФайла = Новый ЧтениеZipФайла(ПолныеДанныеДоверенности.ДанныеАрхива.ОткрытьПотокДляЧтения());
		ЧтениеZipФайла.ИзвлечьВсе(ВременныйКаталог);
		ЧтениеZipФайла.Закрыть();
	Исключение
		ТекстОшибки = ОбработкаОшибок.ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
		РаботаСФайламиБЭД.УдалитьВременныеФайлы(ВременныйКаталог);
		ВызватьИсключение;
	КонецПопытки;
	
	ФайлыXML = НайтиФайлы(ВременныйКаталог, "*.xml");
	Если ФайлыXML.Количество()=0 Тогда
		ТекстОшибки = НСтр("ru = 'нет файла *.xml'");
		РаботаСФайламиБЭД.УдалитьВременныеФайлы(ВременныйКаталог);
		ВызватьИсключение(ТекстОшибки);
	КонецЕсли;
	
	ВерсияДоверенности = Неопределено;  
	ДанныеПригодны = Ложь;
	
	Для Каждого ОписаниеФайла Из ФайлыXML Цикл 
		
		ДвоичныеДанныеМЧД = Новый ДвоичныеДанные(ОписаниеФайла.ПолноеИмя);
		
		ЧтениеXML = Новый ЧтениеXML;
		ЧтениеXML.ОткрытьПоток(ДвоичныеДанныеМЧД.ОткрытьПотокДляЧтения());
		ДанныеXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML);    
		
		ДанныеПригодны = ОбщегоНазначенияДиадокКлиентСервер.ЗначениеСвойстваОбъекта(ДанныеXDTO, "ВерсФорм")="EMCHD_1"; // BSLLS:Typo-off 
		Если ДанныеПригодны Тогда  
			ВерсияДоверенности = "EMCHD_1";
			Прервать;
		КонецЕсли;
		
		ДанныеПригодны = ОбщегоНазначенияДиадокКлиентСервер.ЗначениеСвойстваОбъекта(ДанныеXDTO, "Документ.ОКУД")="0251222";  
		Если ДанныеПригодны Тогда  
			ВерсияДоверенности = "0251222";
			Прервать;
		КонецЕсли;
		
	КонецЦикла;  
	РаботаСФайламиБЭД.УдалитьВременныеФайлы(ВременныйКаталог); 
	
	Результат.ДанныеПригодны = ДанныеПригодны;
	Результат.ДанныеXDTO = ДанныеXDTO; 
	Результат.ВерсияДоверенности = ВерсияДоверенности;
	
	Возврат Результат;
	
КонецФункции