1С ERP Разузлование спецификаций

Question

Добрый день, друзья!

Вопрос вроде когда то поднимался уже, но подскажите, пожалуйста еще раз:

Каким способом можно выполнить разузлование спецификаций (в ERP 2.5) более оптимально ? 
Желательно с использованием типового функционала (можно и без), а еще лучше с примером

Accepted Answer

В общем пока остановился на данном решении.

Если найдется оптимальнее - просьба сообщить.

Спасибо всем откликнувшимся !
[CODE]&НаСервере
Процедура РазузловатьНаСервере(Спецификация, Количество)
	
	Отчет.Материалы.Очистить();
		
	ПараметрыДерева = УправлениеДаннымиОбИзделияхКлиентСервер.ПараметрыДереваСпецификаций();
	
	ПараметрыДерева.Номенклатура               = Справочники.Номенклатура.ПустаяСсылка();
	ПараметрыДерева.ХарактеристикаНоменклатуры = Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка();
	ПараметрыДерева.Спецификация               = Спецификация;
	
	ПараметрыДерева.ПараметрыВыбораСпецификаций = УправлениеДаннымиОбИзделиях.ПараметрыВыбораСпецификаций(Новый Структура(), Обработки.ДеревоРесурсныхСпецификаций);
	
	ПараметрыДерева.Дата                         = ДатаОстатков;
	ПараметрыДерева.ПодразделениеДиспетчер       = Справочники.СтруктураПредприятия.ПустаяСсылка();
	ПараметрыДерева.НаправлениеДеятельности      = Справочники.НаправленияДеятельности.ПустаяСсылка();
	
	
	ПараметрыДерева.ДинамическоеСчитывание       = Истина;  
	
	МнимаяФорма = новый Структура("ДеревоВыводитьЭтапы, ДеревоВыводитьОперации, ДеревоВыводитьВыходныеИзделия,ДеревоВыводитьМатериалы,ДеревоВыводитьТрудозатраты,ДеревоВыводитьЗаголовкиГруппировок",
					           Ложь, Ложь, Ложь, Истина,Ложь,Ложь);

	УправлениеДаннымиОбИзделиях.ЗаполнитьНастройкиОтбораДереваСпецификации(ПараметрыДерева, МнимаяФорма);	
	
	ПараметрыДерева.РазузловыватьПолуфабрикаты = РазузловыватьПолуфабрикаты;
	
	ОсновноеИзделие = Справочники.РесурсныеСпецификации.ДанныеОсновногоИзделияСпецификации(Спецификация);
	
	ПараметрыДерева.Номенклатура = ОсновноеИзделие.Номенклатура;
	ПараметрыДерева.КоличествоВыходногоИзделия = Количество * ОсновноеИзделие.Количество;
	ПараметрыДерева.КоличествоУпаковокВыходногоИзделия = ложь;
	ПараметрыДерева.УпаковкаВыходногоИзделия = ложь;      
	
	ПараметрыДерева.ВыводитьОстаткиТоваров = Истина; 
	
	УправлениеДаннымиОбИзделиях.ПостроитьДеревоСпецификаций(ЭтотОбъект, ПараметрыДерева);
	
	РазвернутьДерево(ДеревоСпецификаций);	
	                  
КонецПроцедуры 

&НаСервере
Процедура РазвернутьДерево(СтрокаДерево)
	
	Для каждого ст из СтрокаДерево.ПолучитьЭлементы() Цикл

		Идентификатор =  ст.ПолучитьИдентификатор();
		
		УправлениеДаннымиОбИзделияхКлиентСервер.ДеревоСпецификацийПередРазворачиванием(ЭтотОбъект, Идентификатор, ложь);
		
		РазвернутьДерево(ст);
		
	КонецЦикла;
	
КонецПроцедуры
[/CODE]