Помогите разобраться, в чем ошибка

Question

Здравствуйте. В этом году заканчиваю 11 класс, хотел на лето найти стажировку, начать набирать навыки и опыт. Откликнулся на кучу вакансий, везде отказываются брать новичка. Но несколько недель назад получил предложение выполнить тестовую задачу. Суть задачи: есть форма обработки со списком заказов клиентов (динамический список). Нужно добавить на форму кнопку, по которой будут создаваться реализации товаров по выбранным заказам, и настроить условное оформление, чтоб заказы, по которым созданы реализации, подсвечивались. С задачей долго возился, но в итоге сделал (огромное спасибо [URL=https://infostart.ru/profile/2107191/]user2107191[/URL] за подсказку, где и что нужно смотреть). Сдал задачу работодателю, в понедельник ответом получил письмо с содержанием : "К большому сожалению не можем взять вас на стажировку, в коде допущено много ошибок и ваше решение не является решением по стандартам разработки 1с специалист". Попросил указать, в чем именно заключаются ошибки, чтобы поработать над их исправлением, ответа так и не получил. Подскажите, плиз, в чем заключаются ошибки? Где можно почитать стандарты разработки 1с специалист? Нашел руководство разработчика, но не знаю, в какой главе смотреть то, что мне нужно (поэтому начал шерстить с самого начала). Решение задачи прикладываю. (функция ПолучитьПосленийНомерРеализаций() ничего не возвращает, добавил ее чтоб присваивался номер реализации, без нее номер создавался 00-000000, и при повторном создании реализаций программа выдавала ошибку номер не уникален 00-000000) [1C-CODE]&НаСервере
Процедура РеализацияТоваровУслугНаСервере(МассивЗаказов)                                      
	Если МассивЗаказов.Количество() > 0 Тогда
		СписокРеализацийПоЗаказам = ПолучичтьРеализацииПоЗаказам(МассивЗаказов);
		Для Каждого ДокументЗаказ Из МассивЗаказов Цикл  
			ЕстьРеализация = ?(СписокРеализацийПоЗаказам.Найти(ДокументЗаказ) = Неопределено, Ложь, Истина);
			Если ЕстьРеализация Тогда
				Продолжить;
			КонецЕсли;
			ДокРеализация = Документы.РеализацияТоваровУслуг.СоздатьДокумент();
			ЗаполнитьЗначенияСвойств(ДокРеализация, ДокументЗаказ);
			ДокРеализация.ВалютаВзаиморасчетов = ДокументЗаказ.Валюта;  
			ДокРеализация.ДатаВозвратаМногооборотнойТары = МногооборотнаяТараСервер.РассчитатьДатуВозвратаМногооборотнойТары(
			ДокРеализация,
			ДокументЗаказ.СрокВозвратаМногооборотнойТары,
			Ложь,
			Справочники.ПроизводственныеКалендари.ПустаяСсылка()); 
			ПродажиСервер.ЗаполнитьБанковскиеСчетаПоДоговору(ДокРеализация.Договор, ДокРеализация.БанковскийСчетОрганизации, ДокРеализация.БанковскийСчетКонтрагента);    
			Если Не ЗначениеЗаполнено(ДокРеализация.БанковскийСчетОрганизации) Тогда
				СтруктураПараметров = ДенежныеСредстваСервер.ПараметрыЗаполненияБанковскогоСчетаОрганизацииПоУмолчанию();
				СтруктураПараметров.Организация    		= ДокРеализация.Организация;
				СтруктураПараметров.БанковскийСчет		= ДокРеализация.БанковскийСчетОрганизации;
				ДокРеализация.БанковскийСчетОрганизации = ЗначениеНастроекПовтИсп.ПолучитьБанковскийСчетОрганизацииПоУмолчанию(СтруктураПараметров);
			КонецЕсли;
			Если Не ЗначениеЗаполнено(ДокРеализация.БанковскийСчетКонтрагента) Тогда
				ДокРеализация.БанковскийСчетКонтрагента = ЗначениеНастроекПовтИсп.ПолучитьБанковскийСчетКонтрагентаПоУмолчанию(ДокРеализация.Контрагент, , ДокРеализация.БанковскийСчетКонтрагента);
			КонецЕсли;
			СкладОтгрузки = ДокРеализация.Склад;  
			ДокРеализация.ЗаказКлиента = ДокументЗаказ;
			ДокРеализация.ВариантОформленияПродажи = Перечисления.ВариантыОформленияПродажи.РеализацияТоваровУслуг;
			ДокРеализация.РеализацияПоЗаказам = Истина; 
			ДокРеализация.Статус = Перечисления.СтатусыРеализацийТоваровУслуг.Отгружено;
			ПараметрыЗаполнения = Новый Структура;
			ПараметрыЗаполнения.Вставить("ВариантОформления", ДокРеализация.ВариантОформленияПродажи);
			ПараметрыЗаполнения.Вставить("ПараметрыОформления", Неопределено);
			МассивЗаказовПараметр = Новый Массив;
			МассивЗаказовПараметр.Добавить(ДокументЗаказ);
			Документы.РеализацияТоваровУслуг.ЗаполнитьПоОстаткамЗаказов(
			ДокРеализация,
			ДокРеализация.Товары,
			ДокРеализация.СкидкиНаценки,
			?(СкладОтгрузки=Неопределено, Справочники.Склады.ПустаяСсылка(), СкладОтгрузки),
			МассивЗаказовПараметр,
			ПараметрыЗаполнения);
			ДокРеализация.ВариантОформленияПродажи = ?(ЗначениеЗаполнено(ДокРеализация.ВариантОформленияПродажи), 
			ДокРеализация.ВариантОформленияПродажи,
			Перечисления.ВариантыОформленияПродажи.РеализацияТоваровУслуг);
			ЗаказыСервер.ЗаполнитьЗаказВШапкеПоЗаказамВТабличнойЧасти(ДокРеализация.ЗаказКлиента, ДокРеализация.Товары, "ЗаказКлиента");
			СкидкиРассчитаны = (ДокРеализация.СкидкиНаценки.Количество() > 0);
			
			ПараметрыУказанияСерий = НоменклатураСервер.ПараметрыУказанияСерий(ДокРеализация, Документы.РеализацияТоваровУслуг);
			НоменклатураСервер.ЗаполнитьСерииПоFEFO(ДокРеализация,ПараметрыУказанияСерий, Ложь); 
			
			СтруктураОснование = Документы.РеализацияТоваровУслуг.СтруктураОснованияДляПечати(ДокРеализация);
			ЗаполнитьЗначенияСвойств(ДокРеализация, СтруктураОснование); 
			ДокРеализация.ДополнительныеСвойства.Вставить("НеобходимостьЗаполненияКассыПриФОИспользоватьНесколькоКассЛожь", Ложь);
			ДокРеализация.ДополнительныеСвойства.Вставить("НеобходимостьЗаполненияСчетаПриФОИспользоватьНесколькоСчетовЛожь", Ложь);  
			ДокРеализация.Автор = Пользователи.ТекущийПользователь();
			ОтветственныеЛицаСервер.ЗаполнитьМенеджера(ДокРеализация, Ложь);   
			
			СкладГруппа = Справочники.Склады.ЭтоГруппаИСкладыИспользуютсяВТЧДокументовПродажи(ДокРеализация.Склад);
			СкладыСервер.ЗаполнитьСкладыВТабличнойЧасти(ДокРеализация.Склад, СкладГруппа, ДокРеализация.Товары, Ложь);   
			ДокРеализация.Номер = ПолучитьПосленийНомерРеализаций();
			ДокРеализация.Записать(РежимЗаписиДокумента.Проведение);                                  
		КонецЦикла;
	КонецЕсли;
	УстановитьУсловноеОформление();
КонецПроцедуры 

&НаСервере
Функция ПолучичтьРеализацииПоЗаказам(МассивЗаказов)
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("МассивЗаказов", МассивЗаказов);
	Запрос.Текст = "ВЫБРАТЬ
	|	ЗаказКлиента КАК ЗаказКлиента
	|ИЗ
	|	Документ.РеализацияТоваровУслуг
	|ГДЕ
	|	ЗаказКлиента В(&МассивЗаказов)
	|	И Проведен";
	Возврат Запрос.Выполнить().Выгрузить();
КонецФункции

&НаСервере
Функция ПолучитьПосленийНомерРеализаций()
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("ПараметрГод", Год(ТекущаяДатаСеанса()));
	Запрос.Текст = "Выбрать Максимум(Номер) Из Документ.РеализацияТоваровУслуг Где ГОД(Дата) = &ПараметрГод И Номер Подобно(""00%"")";
	ТаблицаЗапроса = Запрос.Выполнить().Выгрузить();
КонецФункции

&НаКлиенте
Процедура РеализацияТоваровУслуг(Команда)
	ВыделенныеЗаказы = Элементы.СписокЗаказов.ВыделенныеСтроки;
	РеализацияТоваровУслугНаСервере(ВыделенныеЗаказы);
КонецПроцедуры

&НаСервере
Процедура УстановитьУсловноеОформление()
	Запрос = Новый Запрос("ВЫБРАТЬ
	|	РеализацияТоваровУслуг.ЗаказКлиента КАК ЗаказКлиента
	|ИЗ
	|	Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
	|ГДЕ
	|   РеализацияТоваровУслуг.Ссылка.Проведен
	|	И РеализацияТоваровУслуг.ЗаказКлиента В(&МассивЗаказов)");
	
	Схема = Элементы.СписокЗаказов.ПолучитьИсполняемуюСхемуКомпоновкиДанных();	
	Настройки = Элементы.СписокЗаказов.ПолучитьИсполняемыеНастройкиКомпоновкиДанных();	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных();
	МакетКомпоновки = КомпоновщикМакета.Выполнить(Схема, Настройки, , ,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	Результат = ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
	МассивЗаказов = Результат.ВыгрузитьКолонку("Ссылка");
	
	Запрос.УстановитьПараметр("МассивЗаказов", МассивЗаказов);
	ТабРезультат = Запрос.Выполнить().Выгрузить();
	
	СписокДокументовУО = Новый СписокЗначений;
	СписокДокументовУО.ЗагрузитьЗначения(ТабРезультат.ВыгрузитьКолонку("ЗаказКлиента"));
	
	УсловноеОформление.Элементы.Очистить();
	
	ЭлементОформления = УсловноеОформление.Элементы.Добавить();
	ЭлементОформления.Использование = Истина;
	ЭлементОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.БледноЗеленый); 
	ЭлементОформления.Оформление.УстановитьЗначениеПараметра("Видимость", Истина);
	
	ОтборЭлемента = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ОтборЭлемента.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("СписокЗаказов.Ссылка");
	ОтборЭлемента.ПравоеЗначение = СписокДокументовУО;
	ОтборЭлемента.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке;
	ОтборЭлемента.Использование = Истина;
	
	ОформляемоеПоле      = ЭлементОформления.Поля.Элементы.Добавить();
	ОформляемоеПоле.Поле = Новый ПолеКомпоновкиДанных("СписокЗаказов"); 
	ОформляемоеПоле.Использование = Истина;
КонецПроцедуры
[/1C-CODE]

Accepted Answer

Не утверждаю, что причина отказа в этом, но.... РТУ делается на основании заказа, поэтому нет необходимости заполнять все вручную как у тебя. Посмотри материал https://its.1c.ru/db/metod8dev/content/3562/hdoc