Ошибка обмена УТ11->БП 3.0 Счет-фактура полученный (налоговый агент) Проверка свойства 'РасчетнаяСтавка'

Процедура УОД_ДокументСчетФактураВыданныйПередОбработкойПРО(Объект, Отказ, ИмяПланаОбмена)

    ИсключаемыеТипыДокументовОснований = Новый Массив;
    ИсключаемыеТипыДокументовОснований.Добавить(Тип("ДокументСсылка.ВыкупВозвратнойТарыКлиентом"));
    ИсключаемыеТипыДокументовОснований.Добавить(Тип("ДокументСсылка.ЗаписьКнигиПродаж"));  
    ИсключаемыеТипыДокументовОснований.Добавить(Тип("ДокументСсылка.ПервичныйДокумент"));

    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
    |    СчетФактураВыданный.ДокументОснование КАК ДокументОснование
    |ИЗ
    |    Документ.СчетФактураВыданный КАК СчетФактураВыданный
    |ГДЕ
    |    СчетФактураВыданный.Ссылка = &Объект";

    Запрос.УстановитьПараметр("Объект", Объект.Ссылка);

    РезультатЗапроса = Запрос.Выполнить();

    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        ДокументОснование = ВыборкаДетальныеЗаписи.ДокументОснование;
    КонецЦикла; 
    НалогообложениеНДС = Неопределено; 
    ОснованиеДокументаОснования = Неопределено;
    Если Не ДокументОснование = Неопределено Тогда  
        Реквизиты = "";  
        Если ОбщегоНазначенияКлиентСервер.ЕстьРеквизитИлиСвойствоОбъекта(ДокументОснование, "ДокументОснование") Тогда
            Реквизиты = "ДокументОснование";                
        КонецЕсли;
        Если ОбщегоНазначенияКлиентСервер.ЕстьРеквизитИлиСвойствоОбъекта(ДокументОснование, "НалогообложениеНДС") Тогда
            Реквизиты =  Реквизиты + ?(ПустаяСтрока(Реквизиты),"",",") + "НалогообложениеНДС";
        КонецЕсли;     
        Если Не ПустаяСтрока(Реквизиты) Тогда
            СтруктураРеквизитов = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ДокументОснование, Реквизиты); 
        КонецЕсли;
        Если СтруктураРеквизитов <> Неопределено И СтруктураРеквизитов.Свойство("ДокументОснование") Тогда
            ОснованиеДокументаОснования = СтруктураРеквизитов.ДокументОснование;
        КонецЕсли;
        Если СтруктураРеквизитов <> Неопределено И СтруктураРеквизитов.Свойство("НалогообложениеНДС") Тогда
            НалогообложениеНДС = СтруктураРеквизитов.НалогообложениеНДС;
        КонецЕсли;
    КонецЕсли;    

    Если ИмяПланаОбмена = "СинхронизацияДанныхЧерезУниверсальныйФормат" 
        И ЗначениеЗаполнено(Объект.ДокументОснование) Тогда
        ДокументОснование = Объект.ДокументОснование;
        ИмяМетаданногоОснования = ДокументОснование.Метаданные().Имя;

        Запрос = Новый Запрос;
        Запрос.Текст = 
        "ВЫБРАТЬ
        |    ЕСТЬNULL(СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.ИмяОбъектаМетаданных = &ИмяОбъектаМетаданных
        |            ИЛИ НЕ СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.Ссылка.ИспользоватьОтборПоРазделамУчетаИДокументам, ЛОЖЬ) КАК ОснованиеПроходитПоФильтру,
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.Ссылка КАК Ссылка,
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.ИспользоватьОтборПоРазделамУчетаИДокументам КАК ИспользоватьОтборПоРазделамУчетаИДокументам,
        |    КОЛИЧЕСТВО(СинхронизацияДанныхЧерезУниверсальныйФормат.Ссылка) КАК КоличествоВариантовНастроек,
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.ВариантНастройки КАК ВариантНастройки
        |ИЗ
        |    ПланОбмена.СинхронизацияДанныхЧерезУниверсальныйФормат КАК СинхронизацияДанныхЧерезУниверсальныйФормат
        |        ЛЕВОЕ СОЕДИНЕНИЕ ПланОбмена.СинхронизацияДанныхЧерезУниверсальныйФормат.ВидыДокументов КАК СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов
        |        ПО (СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.Ссылка = СинхронизацияДанныхЧерезУниверсальныйФормат.Ссылка)
        |            И (СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.ИмяОбъектаМетаданных = &ИмяОбъектаМетаданных)
        |ГДЕ
        |    НЕ СинхронизацияДанныхЧерезУниверсальныйФормат.ПометкаУдаления
        |    И НЕ СинхронизацияДанныхЧерезУниверсальныйФормат.ВариантНастройки = """"
        |
        |СГРУППИРОВАТЬ ПО
        |    ЕСТЬNULL(СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.ИмяОбъектаМетаданных = &ИмяОбъектаМетаданных
        |            ИЛИ НЕ СинхронизацияДанныхЧерезУниверсальныйФорматВидыДокументов.Ссылка.ИспользоватьОтборПоРазделамУчетаИДокументам, ЛОЖЬ),
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.Ссылка,
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.ИспользоватьОтборПоРазделамУчетаИДокументам,
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.ВариантНастройки";
        #Вставка
        Запрос.Текст = Запрос.Текст + "
        |
        |УПОРЯДОЧИТЬ ПО
        |    СинхронизацияДанныхЧерезУниверсальныйФормат.Наименование";
        #КонецВставки

        Запрос.УстановитьПараметр("ИмяОбъектаМетаданных", ИмяМетаданногоОснования);
        РезультатЗапроса = Запрос.Выполнить();

        ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

        Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
            Если Не ВыборкаДетальныеЗаписи.ИспользоватьОтборПоРазделамУчетаИДокументам = Истина Тогда
                Продолжить;
            ИначеЕсли ВыборкаДетальныеЗаписи.ИспользоватьОтборПоРазделамУчетаИДокументам = Истина
                И ВыборкаДетальныеЗаписи.ОснованиеПроходитПоФильтру = Ложь Тогда    
                Отказ = Истина;
                Возврат;
            #Вставка
            ИначеЕсли ВыборкаДетальныеЗаписи.ИспользоватьОтборПоРазделамУчетаИДокументам = Истина
                И ВыборкаДетальныеЗаписи.ОснованиеПроходитПоФильтру = Истина Тогда    
                Отказ = Ложь;
                Прервать;
            #КонецВставки
            КонецЕсли; 
        КонецЦикла;
    КонецЕсли;

    Если ЗначениеЗаполнено(ДокументОснование) Тогда 
        Если НалогообложениеНДС <> Неопределено 
            И НалогообложениеНДС = ПредопределенноеЗначение("Перечисление.ТипыНалогообложенияНДС.ОблагаетсяНДССМежценовойРазницы") Тогда
            Отказ = Истина;
            Возврат;
        КонецЕсли;
        ТипДокументаОснования = ТипЗнч(Объект.ДокументОснование);
        Если ИсключаемыеТипыДокументовОснований.Найти(ТипДокументаОснования) <> Неопределено Тогда
            Отказ = Истина;
        ИначеЕсли ТипДокументаОснования = Тип("ДокументСсылка.РеализацияУслугПрочихАктивов") Тогда
            ХозяйственнаяОперация = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ДокументОснование, "ХозяйственнаяОперация");
            Если ХозяйственнаяОперация <> Перечисления.ХозяйственныеОперации.РеализацияКлиенту Тогда
                Отказ = Истина;
            КонецЕсли;
            ТипДоговора = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Объект.Договор, "ТипДоговора");
            Если НЕ ТипДоговора = Неопределено И ТипДоговора = ПредопределенноеЗначение("Перечисление.ТипыДоговоров.ПередачаВАренду") Тогда
                Отказ = Истина;
            КонецЕсли;
        ИначеЕсли ТипДокументаОснования = Тип("ДокументСсылка.КорректировкаРеализации") Тогда 
            Если ОснованиеДокументаОснования <> Неопределено Тогда
                Если ТипЗнч(ОснованиеДокументаОснования) = Тип("ДокументСсылка.АктВыполненныхРабот") 
                    ИЛИ ТипЗнч(ОснованиеДокументаОснования) = Тип("ДокументСсылка.ПервичныйДокумент") Тогда
                    Отказ = Истина;
                КонецЕсли;    
            КонецЕсли;
        ИначеЕсли ТипДокументаОснования = Тип("ДокументСсылка.РеализацияТоваровУслуг") Тогда
            Если ДокументОснование.Статус = Перечисления.СтатусыРеализацийТоваровУслуг.КПредоплате 
                ИЛИ ДокументОснование.ХозяйственнаяОперация = ПредопределенноеЗначение("Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности") Тогда
                Отказ = Истина;
            КонецЕсли;
        ИначеЕсли ТипДокументаОснования = Тип("ДокументСсылка.ОтчетКомиссионера") 
            ИЛИ ТипДокументаОснования = Тип("ДокументСсылка.ОтчетКомитенту")
            ИЛИ ТипДокументаОснования = Тип("ДокументСсылка.ОтчетПоКомиссииМеждуОрганизациями") Тогда
            ОбменДаннымиСобытияУТ.ДокументОтчетКомиссионераКомитентуПриОбработкеПРО(Объект.ДокументОснование, Отказ);
        ИначеЕсли  ТипДокументаОснования = Тип("ДокументСсылка.АвансовыйОтчет") Тогда 
            ОбменДаннымиСобытияУТ.ДокументАвансовыйОтчетПередОбработкойПРО(Объект.ДокументОснование, Отказ); 
        ИначеЕсли ТипДокументаОснования = Тип("ДокументСсылка.ВозвратТоваровОтКлиента") Тогда 
            Если ДокументОснование.ХозяйственнаяОперация = Перечисления.ХозяйственныеОперации.ВозвратТоваровЧерезКомиссионера Тогда
                Отказ = Истина;
            КонецЕсли;
        КонецЕсли;
    Иначе
        Отказ = Истина;
    КонецЕсли;

КонецПроцедуры

Процедура ДобавитьПКО_Документ_СчетФактураПолученныйНалоговыйАгент_Отп<wbr>­ (ПравилаКонвертации)
    ПравилоКонвертации = ОбменДаннымиXDTOСервер.ИнициализироватьПравилоКонвертацииОбъекта(ПравилаКонвертации);
    ПравилоКонвертации.ИмяПКО            = "Документ_СчетФактураПолученныйНалоговыйАгент_Отп";
    ПравилоКонвертации.ОбъектДанных      = Метаданные.Документы.СчетФактураПолученныйНалоговыйАгент;
    ПравилоКонвертации.ОбъектФормата     = "Документ.СчетФактураПолученный"; //@NON-NLS-1
    ПравилоКонвертации.ПриОтправкеДанных = "ПКО_Документ_СчетФактураПолученныйНалоговыйАгент_Отп_ПриОтп­равкеДанных";
    СвойстваШапки = ПравилоКонвертации.Свойства;
    ДобавитьПКС(СвойстваШапки, "Валюта",               "Валюта", , "Справочник_Валюты");
    ДобавитьПКС(СвойстваШапки, "",                     "ВидСчетаФактуры", 1);
    ДобавитьПКС(СвойстваШапки, "Дата",                 "ДатаПолучения");
    ДобавитьПКС(СвойстваШапки, "ДатаИсправления",      "ДатаИсправления");
    ДобавитьПКС(СвойстваШапки, "ДатаСоставления",      "ДатаВходящегоДокумента");
    ДобавитьПКС(СвойстваШапки, "",                     "ИННКонтрагента", 1);
    ДобавитьПКС(СвойстваШапки, "Исправление",          "Исправление");
    ДобавитьПКС(СвойстваШапки, "КодВидаОперации",      "КодВидаОперации");
    ДобавитьПКС(СвойстваШапки, "Контрагент",           "Контрагент", , "Справочник_Контрагенты");
    ДобавитьПКС(СвойстваШапки, "",                     "КППКонтрагента", 1);
    ДобавитьПКС(СвойстваШапки, "Номер",                "НомерВходящегоДокумента");
    ДобавитьПКС(СвойстваШапки, "НомерИсправления",     "НомерИсправления");
    ДобавитьПКС(СвойстваШапки, "Организация",          "Организация", , "Справочник_Организации_Отправка");
    ДобавитьПКС(СвойстваШапки, "",                     "СпособВыставления", 1);
    ДобавитьПКС(СвойстваШапки, "",                     "Сумма", 1);
    ДобавитьПКС(СвойстваШапки, "",                     "СуммаНДС", 1);
// ++
    ДобавитьПКС(СвойстваШапки, "",                     "СтавкаНДС", 1);
// --
    ДобавитьПКС(СвойстваШапки, "СчетФактураОснование", "ИсправляемыйСчетФактура", , "Документ_СчетФактураПолученный_Отправка");
    
    СвойстваТЧ = ДобавитьПКТЧ(ПравилоКонвертации, "", "ДокументыОснования");
    ДобавитьПКС(СвойстваТЧ, "", "ДокументОснование", 1);
    ДобавитьПКС(СвойстваТЧ, "", "ИсходныйДокумент", 1, "Документ_СчетФактураПолученныйНалоговыйАгент_Отп");
    
    СвойстваТЧ = ДобавитьПКТЧ(ПравилоКонвертации, "", "ДополнительныеРеквизиты");
    ДобавитьПКС(СвойстваТЧ, "", "ЗначениеСвойства", 1);
    ДобавитьПКС(СвойстваТЧ, "", "Свойство", 1, "Справочник_ДополнительныеРеквизиты");


КонецПроцедуры

Процедура ПКО_Документ_СчетФактураПолученныйНалоговыйАгент_Отп_ПриОтпр<wbr>­авкеДанных(ДанныеИБ, ДанныеXDTO, КомпонентыОбмена, СтекВыгрузки)
    Если СтекВыгрузки.Количество() > 1 Тогда
        Возврат;
    КонецЕсли;
    
    Если ВерсияФорматаЧислом(КомпонентыОбмена.ВерсияФорматаОбмена) >= ВерсияФорматаЧислом("1.7") Тогда
        ДанныеXDTO.Вставить("ИННКонтрагента", ДанныеИБ.ИННКонтрагента);
        ДанныеXDTO.Вставить("КППКонтрагента", ДанныеИБ.КППКонтрагента);
    КонецЕсли;
    
    // Документ основание
    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ДокументОснование,
        |    ИсходныйДокумент
        |ИЗ 
        |    Документ.СчетФактураПолученныйНалоговыйАгент.ДокументыОснования
        |ГДЕ 
        |    Ссылка = &Ссылка";
    
    Запрос.УстановитьПараметр("Ссылка", ДанныеИБ.Ссылка);
    ВыборкаТЧ = Запрос.Выполнить().Выбрать();
    
    ДокументыОснования = Новый ТаблицаЗначений();
    ДокументыОснования.Колонки.Добавить("ДокументОснование");
    ДокументыОснования.Колонки.Добавить("ИсходныйДокумент");
    
    Пока ВыборкаТЧ.Следующий() Цикл
        
        ДокументОснование = ВыборкаТЧ.ДокументОснование;
    
        ИмяПКО = ИмяПКОДляОбъектаДанных(КомпонентыОбмена, ДокументОснование, ДанныеИБ.Организация);
        
        Если НЕ (ЗначениеЗаполнено(ДокументОснование) И ЗначениеЗаполнено(ИмяПКО)) Тогда
            Продолжить;
        КонецЕсли;
            
        СтрокаОснование = ДокументыОснования.Добавить();
        СтрокаОснование.ДокументОснование = Новый Структура("Значение, ИмяПКО", ДокументОснование, ИмяПКО);
        Если ЗначениеЗаполнено(ВыборкаТЧ.ИсходныйДокумент) Тогда
            СтрокаОснование.ИсходныйДокумент = ВыборкаТЧ.ИсходныйДокумент;
        КонецЕсли;
    
    КонецЦикла;
    
    ДанныеXDTO.Вставить("ДокументыОснования", ДокументыОснования);
    ДанныеXDTO.Вставить("ВидСчетаФактуры",    "НалоговыйАгент");
    
    ВыгрузитьСпособВыставленияСчетаФактуры(ДанныеXDTO, ДанныеИБ.ПолученВЭлектронномВиде);
    
    ДанныеXDTO.Вставить("Сумма",    ДанныеИБ.ДокументыОснования.Итог("Сумма"));
    ДанныеXDTO.Вставить("СуммаНДС", ДанныеИБ.ДокументыОснования.Итог("СуммаНДС"));
    
    ТабДокументыОснования = ДанныеИБ.ДокументыОснования.Выгрузить();
    ТабДокументыОснования.Свернуть("СтавкаНДС");
    Если ТабДокументыОснования.Количество() = 1 Тогда
        СтавкаНДС = ТабДокументыОснования[0].СтавкаНДС; 
        // ++
        //Если ВерсияФорматаЧислом(КомпонентыОбмена.ВерсияФорматаОбмена) < ВерсияФорматаЧислом("1.17") Тогда
        //     ДанныеXDTO.Вставить("СтавкаНДС", СтавкаНДСПоСправочнику(СтавкаНДС));
        //Иначе    
        //     ДанныеXDTO.Вставить("СтавкаНДС", СтавкаНДС);
        //КонецЕсли;
        //ДанныеXDTO.Вставить("СтавкаНДС", СтавкаНДС);
        
        Если ВерсияФорматаЧислом(КомпонентыОбмена.ВерсияФорматаОбмена) >= ВерсияФорматаЧислом("1.17") Тогда 
            СтавкаНДССтруктура = Новый Структура;
            СтавкаНДССтруктура.Вставить("Значение", СтавкаНДС);
            СтавкаНДССтруктура.Вставить("ИмяПКО", "СправочникСсылка_СтавкиНДС_Отправка"); 
            ДанныеXDTO.Вставить("СтавкаНДС", СтавкаНДССтруктура);
        Иначе
            ДанныеXDTO.Вставить("СтавкаНДС", СтавкаНДСПоСправочнику(СтавкаНДС));
        КонецЕсли;  
        // --        
    КонецЕсли;
    
    ВыгрузитьДополнительныеРеквизитыИСведения(КомпонентыОбмена, ДанныеИБ, ДанныеXDTO);
КонецПроцедуры

    #Удаление
    ДобавитьПКС(СвойстваТЧ, "", "СтавкаНДС", 1); 
    #КонецУдаления