Выбор только тех автомобилей, которые относятся к данному клиенту

Question

Имеется справочник "Клиенты" с табличной частью "Автомобиль" с такими полями как "Наименование", "НомерДоговора", "Количество". Имеется документ "ОказаниеУслуг" с полями на форме "Клиент" (СправочникСсылка.Клиенты) и "Автомобиль" (СправочникСсылка.Автомобили). Необходимо при выборе клиента из справочника в поле "Автомобиль" выводить список Автомобилей принадлежащих данному клиенту для дальнейшего выбора.

Accepted Answer

[CODE]  //СЛУЖЕБНАЯ ПРОЦЕДУРА
  //Получаем список автомобилей клиента и загружаем их в список выбора
  &НаСервере
  Процедура СформироватьСписокАвтомобилейКлиентаНаСервере()
	  
	  Запрос = Новый Запрос;
	  Запрос.Текст = 
	  "ВЫБРАТЬ
	  |	КлиентыАвтомобили.Автомобиль КАК Автомобиль
	  |ИЗ
	  |	Справочник.Клиенты.Автомобили КАК КлиентыАвтомобили
	  |ГДЕ
	  |	КлиентыАвтомобили.Ссылка = &КлиентСсылка";
	  
	  Запрос.УстановитьПараметр("КлиентСсылка", Объект.Клиент);
	  
	  РезультатЗапроса = Запрос.Выполнить().Выгрузить();
	  
	  массАвтомобилейКлиента = РезультатЗапроса.ВыгрузитьКолонку("Автомобиль");
	  
	  //Очищаем переменную в объекте
	  Объект.Автомобиль = Справочники.Автомобили.ПустаяСсылка();
	  
	  //Очищаем список выбора и загружаем полученные значения
	  Элементы.Автомобиль.СписокВыбора.Очистить();
	  Элементы.Автомобиль.СписокВыбора.ЗагрузитьЗначения(массАвтомобилейКлиента);
	  
  КонецПроцедуры
  
  
  //ОБРАБОТЧИКИ СОБЫТИЙ ЭЛЕМЕНТОВ ФОРМЫ
  &НаСервере
  Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	  //Заполняем список  значениями по клиенту 
	  Если ЗначениеЗаполнено(Объект.Клиент) Тогда 
		  СформироватьСписокАвтомобилейКлиентаНаСервере(); 
	  КонецЕсли;
  КонецПроцедуры
  
  &НаКлиенте
  Процедура КлиентПриИзменении(Элемент)
	  //При изменении клиента получаем его список автомобилей
	  СформироватьСписокАвтомобилейКлиентаНаСервере();
  КонецПроцедуры
[/CODE]

у реквизита формы Автомобили, в палитре свойств поставить флажок  "Режим выбора из списка"