Вывод результата запроса в зависимости от условий

Question

Доброго всем.
Нужен совет в таком вопросе. Например делаем выборку к справочнику "Соглашения", в выборку могут попасть как типовые(поле реквизита - партнер пустое) соглашения, так и индивидуальные(т.е. привязанные к партнеру), отбор производится по реквизиту, вид операции в справочнике Соглашения. Также могут отобраться только типовые соглашения, в виду отсутствия у партнера заключенных индивидуальных.

Получаем 2 варианта результата:
1)
Соглашение типовое 1
Соглашение типовое 2 и т.д.
Соглашение индивидуальное 1
Соглашение индивидуальное 2 и т.д.
2)
Соглашение типовое 1
Соглашение типовое 2 и т.д.

Вопрос такой, как в самом запросе, с применением каких условий, вывести в результат, в случае если есть и индивидуальные и типовые(вар 1), только индивидуальные, а если индивидуальных нет, то типовые автоматом сами выведутся.
Это конечно можно все обыграть уже обрабатывая сам результат выборки, выгрузить в таблицу и искать строки по условию, но хочется уже самим запросом сделать эту проверку и отфильтровать лишнее и получить готовый результат.

Я пытался так. Сделал два вложенных запроса и в запросе с индивидуальными добавил поле ЭтоИндивидульный и приравнивал его к 1, а в вложенном к типовым 0 и это все по итогу поместил эти оба запроса во временную таблицу ВТ
И потом пытался анализировать итог временной таблицы в запросе, через конструкцию ВЫБОР, ТОГДА, КОГДА и если итог ЭтоИндивидульный > 0 , тогда условие ВТ.ЭтоИндивидуальный = 1 ИНАЧЕ ВТ.ЭтоИндивидуальный = 0. Но выдает ошибку на подсчете Итога.

Accepted Answer

(8) вчера чуть ошибся по памяти). вложенные запросы это было в первоначальной версии, потом модифицировал через выбор и обошелся без внутренних запросов

        "ВЫБРАТЬ
        |        СпрСоглашенияСКлиентами.Ссылка КАК Соглашение,
        |        СпрСоглашенияСКлиентами.ВидЦен КАК ВидЦены,  
        |        СпрСоглашенияСКлиентами.Склад КАК Склад, 
        |        СпрСоглашенияСКлиентами.Валюта КАК Валюта,
        |       ВЫБОР
        |          КОГДА СпрСоглашенияСКлиентами.Партнер = ЗНАЧЕНИЕ(Справочник.Партнеры.ПустаяСсылка)
        |              ТОГДА 0
        |          ИНАЧЕ 1
        |        КОНЕЦ КАК ИндивидуальноеСоглашение
        |ПОМЕСТИТЬ ВТ_Соглашения
        |    ИЗ
        |        Справочник.СоглашенияСКлиентами КАК СпрСоглашенияСКлиентами
        |    ГДЕ
        |        СпрСоглашенияСКлиентами.Организация = &Организация 
        |       И НЕ СпрСоглашенияСКлиентами.Ссылка.ПометкаУдаления
        |        И ВЫБОР
        |            КОГДА СпрСоглашенияСКлиентами.ДатаНачалаДействия <> &ПустаяДата
        |                ТОГДА СпрСоглашенияСКлиентами.ДатаНачалаДействия <= &НачДата
        |            ИНАЧЕ СпрСоглашенияСКлиентами.ДатаНачалаДействия = &ПустаяДата
        |        КОНЕЦ
        |        И ВЫБОР
        |            КОГДА СпрСоглашенияСКлиентами.ДатаОкончанияДействия <> &ПустаяДата
        |                ТОГДА СпрСоглашенияСКлиентами.ДатаОкончанияДействия >= &КонДата
        |            ИНАЧЕ СпрСоглашенияСКлиентами.ДатаОкончанияДействия = &ПустаяДата
        |        КОНЕЦ
        |        И СпрСоглашенияСКлиентами.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыСоглашенийСКлиентами.Действует)
        |        И СпрСоглашенияСКлиентами.Партнер В (&МассивПартнеров) 
        |        И СпрСоглашенияСКлиентами.Контрагент В (&МассивКонтрагентов)
        |        И СпрСоглашенияСКлиентами.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияРекламныхМатериалов)
        |;
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ВТ_Соглашения.Соглашение КАК Соглашение,
        |    ВТ_Соглашения.ВидЦены КАК ВидЦены,  
        |    ВТ_Соглашения.Валюта КАК Валюта,
        |    ВТ_Соглашения.Склад КАК Склад        
        |ИЗ
        |    ВТ_Соглашения КАК ВТ_Соглашения
        |ГДЕ 
        |    ВТ_Соглашения.ИндивидуальноеСоглашение В
        |    (ВЫБРАТЬ 
        |         МАКСИМУМ(ВТ_Соглашения.ИндивидуальноеСоглашение)
        |     ИЗ  ВТ_Соглашения КАК ВТ_Соглашения
        |     )    
        |";

Показать