Одинаковые штрихкоды у разной номенклатуры

Форум Программирование Общие вопросы программирования (Dev)

1С:Розница 2 1С:Розница 3.0 Запросы Внешняя обработка (ert,epf)

1. user2021225 01.04.24 17:49 Сейчас в теме

Розница, редакция 3.0 (3.0.7.95)
Включена галочка "Использовать неуникальные штрихкоды товара". Теперь в базе имеются несколько разных позиций с одинаковыми ШК (Пример на скриншоте)
Вопрос: есть ли способ вывести список таких ШК, к которым привязано несколько номенклатур

Прикрепленные файлы:

По теме из базы знаний

Найденные решения

8. Vadim-SH 02.04.24 08:39 Сейчас в теме

(6)

ВЫБРАТЬ
	ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод,
	КОЛИЧЕСТВО(ШтрихкодыНоменклатуры.Штрихкод) КАК КоличествоШК
ПОМЕСТИТЬ ВТКоличествоШК
ИЗ
	РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры

СГРУППИРОВАТЬ ПО
	ШтрихкодыНоменклатуры.Штрихкод

ИМЕЮЩИЕ
	КОЛИЧЕСТВО(ШтрихкодыНоменклатуры.Штрихкод) > 1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод,
	ШтрихкодыНоменклатуры.Номенклатура КАК Номенклатура,
	ШтрихкодыНоменклатуры.ЕдиницаИзмерения КАК ЕдиницаИзмерения
ИЗ
	РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТКоличествоШК КАК ВТКоличествоШК
		ПО ШтрихкодыНоменклатуры.Штрихкод = ВТКоличествоШК.Штрихкод

Показать

Остальные ответы

Подписаться на ответы Инфостарт бот

Свернуть все

3. пользователь 01.04.24 22:57

Сообщение было скрыто модератором.

...

9. starjevschik 02.04.24 08:48 Сейчас в теме

(3) откуда знаешь, что он хочет получить? Он тебе сказал лично? А почему он это только тебе сказал, а всем задал общий неконкретный вопрос? Я исхожу из того, что человек спрашивает именно то, что ему нужно узнать, а как иначе? догадываться, что ему на самом деле нужно?

2. starjevschik 01.04.24 22:37 Сейчас в теме

Конечно есть, и не один. Например, эту задачу можно использовать как простенький тест на понимание запросов... можно запрограммировать перебор всей номенклатуры с подсчетом количества ШК... можно нанять специально необученную девочку и посадить ее считать дубли... можно выгрузить все хозяйство в ексель и тренировать навыки работы с ним... в общем варианты есть.

4. user2021225 02.04.24 06:58 Сейчас в теме

(2) без комментариев...

Уточнение задачи, написал запрос, но он выводит только ту номенклатуру у которой в справочнике добавлено больше одного ШК, меня интересуют только не уникалье ШК и к какой номенклатуре они привязаны

5. nomad_irk 80 02.04.24 08:07 Сейчас в теме

(1)

Вопрос: есть ли способ вывести список таких ШК, к которым привязано несколько номенклатур

Их есть несколько, в (2) некоторые из них перечислены.
(4)

написал запрос, но он выводит только ту номенклатуру у которой в справочнике добавлено больше одного ШК

Значит, запрос написан не верно для решения вашей задачи.

Если вы хотите помощи, показывайте, что вы наделали или будем дальше наблюдать за битвой экстрасенсов.

6. user2021225 02.04.24 08:31 Сейчас в теме

(5) Такой запрос

|ВЫБРАТЬ
|Номенклатура.Штрихкод КАК Номенклатура,
|КОЛИЧЕСТВО(Номенклатура.Штрихкод) КАК КоличествоДублей
|ИЗ
| РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры
| СГРУППИРОВАТЬ ПО
|ШтрихкодыНоменклатуры.Номенклатура
|ИМЕЮЩИЕ КОЛИЧЕСТВО(Номенклатура.Штрихкод) > 1

Показать

Но вывод в корне не такой как я хочу видеть в итоге.

ps\ Только начинаю осваивать функционал запросов, поэтому попрошу диванных экспертов оставить критику при себе, принимаются только конструктивные советы, не раздувайте топик

7. nomad_irk 80 02.04.24 08:35 Сейчас в теме

(6)Если вам нужны ШК для разной номенклатуры, то и группировать нужно по ШК, а не по номенклатуре.

Так вы получите список неуникальных ШК во временную таблицу, соединив еще раз с таблицей хранения ШК вы получите номенклатуру, к которой они привязаны.

Так понятно или расписывать текст запроса?

8. Vadim-SH 02.04.24 08:39 Сейчас в теме

(6)

ВЫБРАТЬ
	ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод,
	КОЛИЧЕСТВО(ШтрихкодыНоменклатуры.Штрихкод) КАК КоличествоШК
ПОМЕСТИТЬ ВТКоличествоШК
ИЗ
	РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры

СГРУППИРОВАТЬ ПО
	ШтрихкодыНоменклатуры.Штрихкод

ИМЕЮЩИЕ
	КОЛИЧЕСТВО(ШтрихкодыНоменклатуры.Штрихкод) > 1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод,
	ШтрихкодыНоменклатуры.Номенклатура КАК Номенклатура,
	ШтрихкодыНоменклатуры.ЕдиницаИзмерения КАК ЕдиницаИзмерения
ИЗ
	РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТКоличествоШК КАК ВТКоличествоШК
		ПО ШтрихкодыНоменклатуры.Штрихкод = ВТКоличествоШК.Штрихкод

Показать

10. user2021225 02.04.24 12:03 Сейчас в теме

(7) Механизм понятен, но я не знаю как это на языке запроса реализовать, с этим прошу помочь

11. user2021225 02.04.24 12:04 Сейчас в теме

(8) Отредактировал ответ, это практически то что я хотел видеть. Спасибо!!

12. Vadim-SH 02.04.24 12:51 Сейчас в теме

(11) Все верно - 13 больше одного.
Запрос выдает не число, а соответствие ШК - Номенклатура, др. измерения.
У меня нет Розницы, поэтому регистр с ШК может немного отличатся.
Попробуйте вот такой запрос:


ВЫБРАТЬ
	ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод,
	ШтрихкодыНоменклатуры.Номенклатура КАК Номенклатура,
	ШтрихкодыНоменклатуры.Характеристика КАК Характеристика,
	ШтрихкодыНоменклатуры.Упаковка КАК Упаковка
ИЗ
	РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры
ГДЕ
	ШтрихкодыНоменклатуры.Штрихкод В
			(ВЫБРАТЬ
				ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод
			ИЗ
				РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры
			СГРУППИРОВАТЬ ПО
				ШтрихкодыНоменклатуры.Штрихкод
			ИМЕЮЩИЕ
				КОЛИЧЕСТВО(ШтрихкодыНоменклатуры.Штрихкод) > 1)

Показать

13. user2021225 02.04.24 13:43 Сейчас в теме

(12) Да все верно, спасибо за решение

Оставьте свое сообщение

E-mail: