1С бухгалтерия запрос по себестоимости с НДС, как?

ВЫБРАТЬ
	СУММА(Продажи.Количество) КАК Количество,
	Продажи.Контрагент КАК Контрагент,
	Продажи.Договор КАК Договор,
	Продажи.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	Продажи.СтавкаНДС КАК СтавкаНДС,
	Продажи.Номенклатура КАК Номенклатура,
	СУММА(Продажи.ВыручкаБезНДС) КАК ВыручкаБезНДС,
	Продажи.Регистратор КАК Регистратор,
	Продажи.Организация КАК Организация,
	Продажи.Подразделение КАК Подразделение,
	Продажи.Период КАК Период,
	Продажи.Розница КАК Розница,
	Продажи.КонтрагентПредставление КАК КонтрагентПредставление,
	Продажи.ДоговорПредставление КАК ДоговорПредставление
ПОМЕСТИТЬ Продажи
ИЗ
	(ВЫБРАТЬ
		ХозрасчетныйОбороты.КоличествоОборотКт КАК Количество,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто1 ССЫЛКА Справочник.Контрагенты
				ТОГДА ХозрасчетныйОбороты.КорСубконто1
			ИНАЧЕ "Розничные покупатели"
		КОНЕЦ КАК Контрагент,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто2 ССЫЛКА Справочник.ДоговорыКонтрагентов
				ТОГДА ХозрасчетныйОбороты.КорСубконто2
			ИНАЧЕ "Розничная продажа"
		КОНЕЦ КАК Договор,
		ХозрасчетныйОбороты.Субконто1 КАК НоменклатурнаяГруппа,
		ХозрасчетныйОбороты.Субконто2 КАК СтавкаНДС,
		ХозрасчетныйОбороты.Субконто3 КАК Номенклатура,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто2 ССЫЛКА Справочник.ДоговорыКонтрагентов
					И ВЫРАЗИТЬ(ХозрасчетныйОбороты.КорСубконто2 КАК Справочник.ДоговорыКонтрагентов).УчетАгентскогоНДСПокупателем
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
			КОГДА ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_18
					ИЛИ ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_118
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт * 100 / 118
			КОГДА ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_10
					ИЛИ ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_110
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт * 100 / 110
			КОГДА ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_20
					ИЛИ ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_120
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт * 100 / 120
			КОГДА ХозрасчетныйОбороты.Субконто2 = &СтавкаНДС_0
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
			КОГДА ХозрасчетныйОбороты.Субконто2 = &БезНДС
				ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
		КОНЕЦ КАК ВыручкаБезНДС,
		ХозрасчетныйОбороты.Регистратор КАК Регистратор,
		ХозрасчетныйОбороты.Организация КАК Организация,
		ЕСТЬNULL(ХозрасчетныйОбороты.Подразделение, &ПустоеПодразделение) КАК Подразделение,
		ХозрасчетныйОбороты.ПериодДень КАК Период,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСчет В (&СчетаКассы)
				ТОГДА ИСТИНА
			ИНАЧЕ ЛОЖЬ
		КОНЕЦ КАК Розница,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто1 ССЫЛКА Справочник.Контрагенты
				ТОГДА ПРЕДСТАВЛЕНИЕССЫЛКИ(ХозрасчетныйОбороты.КорСубконто1)
			ИНАЧЕ "Розничные покупатели"
		КОНЕЦ КАК КонтрагентПредставление,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто2 ССЫЛКА Справочник.ДоговорыКонтрагентов
				ТОГДА ПРЕДСТАВЛЕНИЕССЫЛКИ(ХозрасчетныйОбороты.КорСубконто2)
			ИНАЧЕ "Розничная продажа"
		КОНЕЦ КАК ДоговорПредставление
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.Обороты(&НачалоПериода, &КонецПериода, Авто, Счет В (&СчетаВыручки), &НоменклатурнаяГруппаСтавкаНДСНоменклатура, {(Организация).* КАК Организация, (Подразделение).* КАК Подразделение, (Субконто1).* КАК НоменклатурнаяГруппа, (Субконто2) КАК СтавкаНДС, (Субконто3).* КАК Номенклатура, (КорСубконто1).* КАК Контрагент, (КорСубконто2).* КАК Договор}, КорСчет В (&СчетаРасчетовСПокупателями), ) КАК ХозрасчетныйОбороты
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОбороты.КоличествоОборотКт,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто1 ССЫЛКА Справочник.Контрагенты
				ТОГДА ХозрасчетныйОбороты.КорСубконто1
			ИНАЧЕ "Розничные покупатели"
		КОНЕЦ,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто2 ССЫЛКА Справочник.ДоговорыКонтрагентов
				ТОГДА ХозрасчетныйОбороты.КорСубконто2
			ИНАЧЕ "Розничная продажа"
		КОНЕЦ,
		ХозрасчетныйОбороты.Субконто1,
		NULL,
		ХозрасчетныйОбороты.Субконто2,
		ХозрасчетныйОбороты.СуммаОборотКт,
		ХозрасчетныйОбороты.Регистратор,
		ХозрасчетныйОбороты.Организация,
		ЕСТЬNULL(ХозрасчетныйОбороты.Подразделение, &ПустоеПодразделение),
		ХозрасчетныйОбороты.ПериодДень,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСчет В (&СчетаКассы)
				ТОГДА ИСТИНА
			ИНАЧЕ ЛОЖЬ
		КОНЕЦ,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто1 ССЫЛКА Справочник.Контрагенты
				ТОГДА ПРЕДСТАВЛЕНИЕССЫЛКИ(ХозрасчетныйОбороты.КорСубконто1)
			ИНАЧЕ "Розничные покупатели"
		КОНЕЦ,
		ВЫБОР
			КОГДА ХозрасчетныйОбороты.КорСубконто2 ССЫЛКА Справочник.ДоговорыКонтрагентов
				ТОГДА ПРЕДСТАВЛЕНИЕССЫЛКИ(ХозрасчетныйОбороты.КорСубконто2)
			ИНАЧЕ "Розничная продажа"
		КОНЕЦ
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.Обороты(&НачалоПериода, &КонецПериода, Авто, Счет В (&СчетаВыручкиЕНВД), &НоменклатурнаяГруппаНоменклатура, {(Организация).* КАК Организация, (Подразделение).* КАК Подразделение, (Субконто1).* КАК НоменклатурнаяГруппа, (Субконто2) КАК Номенклатура, (КорСубконто1).* КАК Контрагент, (КорСубконто2).* КАК Договор}, КорСчет В (&СчетаРасчетовСПокупателями), ) КАК ХозрасчетныйОбороты) КАК Продажи

СГРУППИРОВАТЬ ПО
	Продажи.Контрагент,
	Продажи.Договор,
	Продажи.НоменклатурнаяГруппа,
	Продажи.СтавкаНДС,
	Продажи.Номенклатура,
	Продажи.Регистратор,
	Продажи.Организация,
	Продажи.Подразделение,
	Продажи.Период,
	Продажи.Розница,
	Продажи.КонтрагентПредставление,
	Продажи.ДоговорПредставление

ИНДЕКСИРОВАТЬ ПО
	Продажи.Организация,
	Продажи.Подразделение,
	Продажи.Номенклатура,
	Продажи.НоменклатурнаяГруппа,
	Продажи.Регистратор
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ХозрасчетныйОбороты.Регистратор КАК Регистратор,
	ХозрасчетныйОбороты.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	ХозрасчетныйОбороты.Номенклатура КАК Номенклатура,
	ХозрасчетныйОбороты.Организация КАК Организация,
	СУММА(ХозрасчетныйОбороты.Количество) КАК Количество,
	СУММА(ХозрасчетныйОбороты.Стоимость) КАК Стоимость,
	ХозрасчетныйОбороты.Подразделение КАК Подразделение,
	ХозрасчетныйОбороты.Склад КАК Склад,
	ХозрасчетныйОбороты.Партия КАК Партия
ПОМЕСТИТЬ СебестоимостьОборот
ИЗ
	(ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.Регистратор КАК Регистратор,
		ХозрасчетныйОборотыДтКт.СубконтоДт1 КАК НоменклатурнаяГруппа,
		ХозрасчетныйОборотыДтКт.СубконтоКт1 КАК Номенклатура,
		ХозрасчетныйОборотыДтКт.Организация КАК Организация,
		ХозрасчетныйОборотыДтКт.КоличествоОборотКт КАК Количество,
		ХозрасчетныйОборотыДтКт.СуммаОборот КАК Стоимость,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение) КАК Подразделение,
		ВЫБОР
			КОГДА &ВедетсяСуммовойУчетПоСкладам
				ТОГДА ХозрасчетныйОборотыДтКт.СубконтоКт2
			ИНАЧЕ &ПустойСклад
		КОНЕЦ КАК Склад,
		НЕОПРЕДЕЛЕНО КАК Партия
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, Регистратор, СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетУчетаНоменклатурыБезПартии), &СубконтоНоменклатураСклад, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.Регистратор,
		ХозрасчетныйОборотыДтКт.СубконтоДт1,
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.КоличествоОборотКт,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		ВЫБОР
			КОГДА &ВедетсяСуммовойУчетПоСкладам
				ТОГДА ХозрасчетныйОборотыДтКт.СубконтоКт2
			ИНАЧЕ &ПустойСклад
		КОНЕЦ,
		ХозрасчетныйОборотыДтКт.СубконтоКт3
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, Регистратор, СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетУчетаНоменклатурыСПартиями), &СубконтоНоменклатураСкладПартии, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.Регистратор,
		ХозрасчетныйОборотыДтКт.СубконтоДт1,
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.КоличествоОборотКт,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		&ПустойСклад,
		НЕОПРЕДЕЛЕНО
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, Регистратор, СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетУчетаНоменклатурыБезСкладаБезПартии), &СубконтоНоменклатура, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.Регистратор,
		ХозрасчетныйОборотыДтКт.СубконтоДт1,
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.КоличествоОборотКт,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		&ПустойСклад,
		ХозрасчетныйОборотыДтКт.СубконтоКт2
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, Регистратор, СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетУчетаНоменклатурыСПартиямиБезСклада), &СубконтоНоменклатураПартии, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт) КАК ХозрасчетныйОбороты

СГРУППИРОВАТЬ ПО
	ХозрасчетныйОбороты.Регистратор,
	ХозрасчетныйОбороты.НоменклатурнаяГруппа,
	ХозрасчетныйОбороты.Номенклатура,
	ХозрасчетныйОбороты.Организация,
	ХозрасчетныйОбороты.Подразделение,
	ХозрасчетныйОбороты.Склад,
	ХозрасчетныйОбороты.Партия

ИНДЕКСИРОВАТЬ ПО
	ХозрасчетныйОбороты.Организация,
	ХозрасчетныйОбороты.Подразделение,
	ХозрасчетныйОбороты.Номенклатура,
	ХозрасчетныйОбороты.Склад,
	ХозрасчетныйОбороты.Партия
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ХозрасчетныйОбороты.Номенклатура КАК Номенклатура,
	ХозрасчетныйОбороты.Организация КАК Организация,
	СУММА(ХозрасчетныйОбороты.Наценка) КАК Наценка,
	ХозрасчетныйОбороты.Подразделение КАК Подразделение,
	ХозрасчетныйОбороты.Склад КАК Склад,
	ХозрасчетныйОбороты.Партия КАК Партия
ПОМЕСТИТЬ ТорговаяНаценка
ИЗ
	(ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.СубконтоКт1 КАК Номенклатура,
		ХозрасчетныйОборотыДтКт.Организация КАК Организация,
		ХозрасчетныйОборотыДтКт.СуммаОборот КАК Наценка,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение) КАК Подразделение,
		ВЫБОР
			КОГДА &ВедетсяСуммовойУчетПоСкладам
				ТОГДА ХозрасчетныйОборотыДтКт.СубконтоКт2
			ИНАЧЕ &ПустойСклад
		КОНЕЦ КАК Склад,
		ХозрасчетныйОборотыДтКт.СубконтоКт3 КАК Партия
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, , СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетТорговойНаценкиСПартиями), &СубконтоНоменклатураСкладПартии, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		ВЫБОР
			КОГДА &ВедетсяСуммовойУчетПоСкладам
				ТОГДА ХозрасчетныйОборотыДтКт.СубконтоКт2
			ИНАЧЕ &ПустойСклад
		КОНЕЦ,
		НЕОПРЕДЕЛЕНО
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, , СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетТорговойНаценкиБезПартии), &СубконтоНоменклатураСклад, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		&ПустойСклад,
		ХозрасчетныйОборотыДтКт.СубконтоКт2
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, , СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетТорговойНаценкиБезСкладаСПартиями), &СубконтоНоменклатураПартии, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ХозрасчетныйОборотыДтКт.СубконтоКт1,
		ХозрасчетныйОборотыДтКт.Организация,
		ХозрасчетныйОборотыДтКт.СуммаОборот,
		ЕСТЬNULL(ХозрасчетныйОборотыДтКт.ПодразделениеДт, &ПустоеПодразделение),
		&ПустойСклад,
		НЕОПРЕДЕЛЕНО
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(&НачалоПериода, &КонецПериода, , СчетДт В (&СчетаСебестоимости), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы), СчетКт В (&СчетТорговойНаценкиБезСкладаБезПартии), &СубконтоНоменклатура, {(Организация).* КАК Организация, (СубконтоДт1).* КАК НоменклатурнаяГруппа, (СубконтоКт1).* КАК Номенклатура, (ПодразделениеДт).* КАК Подразделение}) КАК ХозрасчетныйОборотыДтКт) КАК ХозрасчетныйОбороты

СГРУППИРОВАТЬ ПО
	ХозрасчетныйОбороты.Номенклатура,
	ХозрасчетныйОбороты.Организация,
	ХозрасчетныйОбороты.Подразделение,
	ХозрасчетныйОбороты.Склад,
	ХозрасчетныйОбороты.Партия
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Себестоимость.Номенклатура КАК Номенклатура,
	Себестоимость.Организация КАК Организация,
	Себестоимость.Подразделение КАК Подразделение,
	Себестоимость.Склад КАК Склад,
	Себестоимость.Партия КАК Партия,
	СУММА(Себестоимость.Стоимость) КАК Стоимость,
	СУММА(Себестоимость.Количество) КАК Количество
ПОМЕСТИТЬ СкорректированнаяСтоимость
ИЗ
	(ВЫБРАТЬ
		СебестоимостьОборот.Номенклатура КАК Номенклатура,
		СебестоимостьОборот.Организация КАК Организация,
		СебестоимостьОборот.Подразделение КАК Подразделение,
		СебестоимостьОборот.Склад КАК Склад,
		СебестоимостьОборот.Партия КАК Партия,
		СебестоимостьОборот.Стоимость КАК Стоимость,
		СебестоимостьОборот.Количество КАК Количество
	ИЗ
		СебестоимостьОборот КАК СебестоимостьОборот
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ТорговаяНаценка.Номенклатура,
		ТорговаяНаценка.Организация,
		ТорговаяНаценка.Подразделение,
		ТорговаяНаценка.Склад,
		ТорговаяНаценка.Партия,
		ТорговаяНаценка.Наценка,
		0
	ИЗ
		ТорговаяНаценка КАК ТорговаяНаценка) КАК Себестоимость

СГРУППИРОВАТЬ ПО
	Себестоимость.Номенклатура,
	Себестоимость.Организация,
	Себестоимость.Подразделение,
	Себестоимость.Склад,
	Себестоимость.Партия

ИНДЕКСИРОВАТЬ ПО
	Себестоимость.Организация,
	Себестоимость.Подразделение,
	Себестоимость.Номенклатура,
	Себестоимость.Склад,
	Себестоимость.Партия
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	СебестоимостьОборот.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	СкорректированнаяСтоимость.Номенклатура КАК Номенклатура,
	СкорректированнаяСтоимость.Организация КАК Организация,
	СкорректированнаяСтоимость.Подразделение КАК Подразделение,
	СкорректированнаяСтоимость.Склад КАК Склад,
	СУММА(ВЫБОР
			КОГДА СкорректированнаяСтоимость.Количество = 0
				ТОГДА 0
			ИНАЧЕ СкорректированнаяСтоимость.Стоимость * СебестоимостьОборот.Количество / СкорректированнаяСтоимость.Количество
		КОНЕЦ) КАК Стоимость,
	СебестоимостьОборот.Регистратор КАК Регистратор
ПОМЕСТИТЬ СебестоимостьПоДокументам
ИЗ
	СкорректированнаяСтоимость КАК СкорректированнаяСтоимость
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ СебестоимостьОборот КАК СебестоимостьОборот
		ПО СкорректированнаяСтоимость.Организация = СебестоимостьОборот.Организация
			И СкорректированнаяСтоимость.Подразделение = СебестоимостьОборот.Подразделение
			И СкорректированнаяСтоимость.Номенклатура = СебестоимостьОборот.Номенклатура
			И СкорректированнаяСтоимость.Склад = СебестоимостьОборот.Склад
			И СкорректированнаяСтоимость.Партия = СебестоимостьОборот.Партия

СГРУППИРОВАТЬ ПО
	СебестоимостьОборот.НоменклатурнаяГруппа,
	СкорректированнаяСтоимость.Номенклатура,
	СкорректированнаяСтоимость.Организация,
	СкорректированнаяСтоимость.Подразделение,
	СкорректированнаяСтоимость.Склад,
	СебестоимостьОборот.Регистратор

ИНДЕКСИРОВАТЬ ПО
	СкорректированнаяСтоимость.Организация,
	СкорректированнаяСтоимость.Подразделение,
	СкорректированнаяСтоимость.Номенклатура,
	СебестоимостьОборот.НоменклатурнаяГруппа,
	СебестоимостьОборот.Регистратор
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Продажи.Организация КАК Организация,
	Продажи.Подразделение КАК Подразделение,
	Продажи.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	Продажи.Номенклатура КАК Номенклатура,
	Продажи.Регистратор КАК Регистратор,
	СУММА(Продажи.Количество) КАК Количество
ПОМЕСТИТЬ ПродажиГруппировка
ИЗ
	Продажи КАК Продажи

СГРУППИРОВАТЬ ПО
	Продажи.Организация,
	Продажи.Подразделение,
	Продажи.Номенклатура,
	Продажи.НоменклатурнаяГруппа,
	Продажи.Регистратор

ИНДЕКСИРОВАТЬ ПО
	Продажи.Организация,
	Продажи.Подразделение,
	Продажи.Номенклатура,
	Продажи.НоменклатурнаяГруппа,
	Продажи.Регистратор
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	СебестоимостьПоДокументам.Номенклатура КАК Номенклатура,
	СебестоимостьПоДокументам.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	СебестоимостьПоДокументам.Организация КАК Организация,
	СебестоимостьПоДокументам.Подразделение КАК Подразделение,
	СебестоимостьПоДокументам.Склад КАК Склад,
	СебестоимостьПоДокументам.Стоимость КАК Стоимость,
	СебестоимостьПоДокументам.Регистратор КАК Регистратор
ПОМЕСТИТЬ Себестоимость
ИЗ
	СебестоимостьПоДокументам КАК СебестоимостьПоДокументам
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПродажиГруппировка КАК ПродажиГруппировка
		ПО СебестоимостьПоДокументам.Организация = ПродажиГруппировка.Организация
			И СебестоимостьПоДокументам.Подразделение = ПродажиГруппировка.Подразделение
			И СебестоимостьПоДокументам.Номенклатура = ПродажиГруппировка.Номенклатура
			И СебестоимостьПоДокументам.НоменклатурнаяГруппа = ПродажиГруппировка.НоменклатурнаяГруппа
			И СебестоимостьПоДокументам.Регистратор = ПродажиГруппировка.Регистратор

ИНДЕКСИРОВАТЬ ПО
	СебестоимостьПоДокументам.Организация,
	СебестоимостьПоДокументам.Подразделение,
	СебестоимостьПоДокументам.Номенклатура,
	СебестоимостьПоДокументам.НоменклатурнаяГруппа,
	СебестоимостьПоДокументам.Регистратор
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Продажи.Регистратор КАК Регистратор,
	Продажи.Период КАК Период,
	Продажи.Организация КАК Организация,
	Продажи.Подразделение КАК Подразделение,
	ЕСТЬNULL(Себестоимость.Склад, &ПустойСклад) КАК Склад,
	Продажи.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	Продажи.Номенклатура КАК Номенклатура,
	ПРЕДСТАВЛЕНИЕССЫЛКИ(Продажи.Номенклатура) КАК НоменклатураПредставление,
	Продажи.Контрагент КАК Контрагент,
	Продажи.КонтрагентПредставление КАК КонтрагентПредставление,
	Продажи.Договор КАК Договор,
	Продажи.ДоговорПредставление КАК ДоговорПредставление,
	Продажи.СтавкаНДС КАК СтавкаНДС,
	Продажи.ВыручкаБезНДС КАК ВыручкаБезНДС,
	Продажи.Розница КАК Розница,
	Продажи.Количество КАК Количество,
	Себестоимость.Стоимость КАК Стоимость
{ВЫБРАТЬ
	Количество,
	Контрагент.*,
	НоменклатурнаяГруппа.*,
	Договор.*,
	СтавкаНДС.*,
	Номенклатура.*,
	ВыручкаБезНДС,
	НоменклатураПредставление,
	Период,
	Регистратор.*,
	Стоимость,
	КонтрагентПредставление,
	ДоговорПредставление,
	Склад.*,
	Подразделение.*}
ИЗ
	Продажи КАК Продажи
		ЛЕВОЕ СОЕДИНЕНИЕ Себестоимость КАК Себестоимость
		ПО Продажи.Организация = Себестоимость.Организация
			И Продажи.Подразделение = Себестоимость.Подразделение
			И Продажи.Номенклатура = Себестоимость.Номенклатура
			И Продажи.НоменклатурнаяГруппа = Себестоимость.НоменклатурнаяГруппа
			И Продажи.Регистратор = Себестоимость.Регистратор
{ГДЕ
	Продажи.Розница,
	Себестоимость.Склад.*}