При использовании внешней обработки происходит ошибка "произошла неисправимая ошибка на сервере 1с предприятие

Question

Добрый день! 
Подскажите пожалуйста, может кто сталкивался с данной ошибкой "Произошла неисправимая ошибка на сервере 1с предприятие" 
Ошибка возникает при использовании внешней обработки. 
Суть обработки почистить контактную информацию справочника партнеры. 
Обработка самопиская, программист я уровня ну совсем новичок. 
Заметила, что если обрабатывается какое-то небольшое количество элементов, то все замечательно, при большом количестве возникает ошибка 
Подскажите пожалуйста, что делаюне так. 
Текст обработки 
[1C-CODE]Запрос = Новый Запрос;
	

	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Партнеры.Ссылка КАК Ссылка,
		|	Партнеры.Наименование КАК Наименование,
		|	ПартнерыКонтактнаяИнформация.Ссылка КАК Ссылка1,
		|	Партнеры.CRM_СегментРынка КАК CRM_СегментРынка
		|ИЗ
		|	Справочник.Партнеры.КонтактнаяИнформация КАК ПартнерыКонтактнаяИнформация
		|		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Партнеры КАК Партнеры
		|		ПО ПартнерыКонтактнаяИнформация.Ссылка = Партнеры.Ссылка"	     ;
	РезультатЗапроса = Запрос.Выполнить();
	
	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
	
	   Номер = 1;
	
	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		Ссылка = ВыборкаДетальныеЗаписи.Ссылка;
        СсылкаОбъект = Ссылка.ПолучитьОбъект();
		 Если СсылкаОбъект.CRM_СегментРынка = Справочники.CRM_СегментыРынка.НайтиПоНаименованию("Розничный магазин")
		     Тогда 
		Для каждого СтрТч из СсылкаОбъект.КонтактнаяИнформация Цикл 
			СсылкаОбъект.КонтактнаяИнформация.Очистить();
			
				КонецЦикла;
	   СсылкаОбъект.Записать();
	   КонецЕсли;
     КонецЦикла;[/1C-CODE]

Accepted Answer

(1)[CODE]Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ РАЗЛИЧНЫЕ
|	ПартнерыКонтактнаяИнформация.Ссылка КАК Ссылка
|ИЗ
|	Справочник.Партнеры.КонтактнаяИнформация КАК ПартнерыКонтактнаяИнформация
|ГДЕ
|	ПартнерыКонтактнаяИнформация.Ссылка.CRM_СегментРынка = &СегментРынка";
Запрос.УстановитьПараметр("СегментРынка", Справочники.CRM_СегментыРынка.НайтиПоНаименованию("Розничный магазин"));
РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
	СправочникОбъект = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();
	СправочникОбъект.КонтактнаяИнформация.Очистить();
	СправочникОбъект.ОбменДанными.Загрузка = Истина;
	СправочникОбъект.Записать();
КонецЦикла;[/CODE]