По счёту 98.01 нет значений субконто в РегистрБухгалтерии.Хозрасчетный.Субконто

&ИзменениеИКонтроль("СформироватьДвиженияРеализацияСобственныхТоваровУслуг")
Процедура Расш1_СформироватьДвиженияРеализацияСобственныхТоваровУслуг(ТаблицаВыручкиОтРеализации, ПараметрыРеализации, ЭтоВозврат, Движения, Отказ)
	Перем ТекстСодержанияПоТоварам;

	Если Не ЗначениеЗаполнено(ТаблицаВыручкиОтРеализации) Тогда
		Возврат;
	КонецЕсли;

	Период      = ПараметрыРеализации.Период;
	Организация = ПараметрыРеализации.Организация;

	Если ЭтоВозврат Тогда
		ТекстСодержанияПоТоварам = НСтр("ru = 'Возврат %1 от покупателя'");
	ИначеЕсли БухгалтерскийУчетКлиентСерверПереопределяемый.ДокументЯвляетсяРеализациейПрочегоИмущества(ПараметрыРеализации.Регистратор) Тогда
		ТекстСодержанияПоТоварам = НСтр("ru = 'Реализация прочего имущества'");
	Иначе
		ТекстСодержанияПоТоварам = НСтр("ru = 'Реализация %1'");
	КонецЕсли;

	Если БухгалтерскийУчетКлиентСерверПереопределяемый.ДокументЯвляетсяОтчетомКомитенту(ПараметрыРеализации.Регистратор) Тогда
		ТекстСодержанияПоУслугам = НСтр("ru = 'Оказание услуг по договору комиссии'");
	ИначеЕсли Документы.РеализацияТоваровУслуг.ЭтоВыполнениеСтроительныхРабот(ПараметрыРеализации.Регистратор) Тогда
		ТекстСодержанияПоУслугам = НСтр("ru = 'Строительные работы'");
	Иначе
		ТекстСодержанияПоУслугам = НСтр("ru = 'Реализация услуг'");
	КонецЕслИ;

	ОтражатьВНалоговомУчете  = УчетнаяПолитика.ПлательщикНалогаНаПрибыль(Организация, Период);

	ВычислятьСодержаниеПроводкиТовары = (СтрНайти(ТекстСодержанияПоТоварам, "%1") > 0);

	Для каждого СтрокаТаблицы Из ТаблицаВыручкиОтРеализации Цикл

		Проводка = Движения.Хозрасчетный.Добавить();

		Проводка.Период      = Период;
		Проводка.Организация = Организация;
		Проводка.Сумма       = СтрокаТаблицы.СуммаБУ;

		Если СтрокаТаблицы.ЭтоУслуга Тогда
			Проводка.Содержание = ТекстСодержанияПоУслугам;
		ИначеЕсли НЕ ВычислятьСодержаниеПроводкиТовары Тогда 
			Проводка.Содержание = ТекстСодержанияПоТоварам;
		Иначе
			Проводка.Содержание = СтрШаблон(ТекстСодержанияПоТоварам, БухгалтерскийУчетПовтИсп.НазваниеОбъектаПоСчетуУчета(СтрокаТаблицы.СчетУчета));
		КонецЕсли; 

		Проводка.СчетДт = СтрокаТаблицы.КорСчет;
		ЗаполнитьАналитикуСчетаРасчетов(Проводка, СтрокаТаблицы, "Дт", ОтражатьВНалоговомУчете, СтрокаТаблицы.СуммаБУ - СтрокаТаблицы.СуммаНУ);

		Проводка.СчетКт = СтрокаТаблицы.СчетДоходов;
		
		#Вставка
        Расш1_УстановкаДвиженияСубконтоСчета9801(ТаблицаВыручкиОтРеализации, СтрокаТаблицы, Проводка, ОтражатьВНалоговомУчете);
		#КонецВставки
		
		#Удаление
		ЗаполнитьАналитикуСчетаДохода(Проводка, СтрокаТаблицы, "Кт", ОтражатьВНалоговомУчете, СтрокаТаблицы.СуммаБУ - СтрокаТаблицы.СуммаНУ);
        #КонецУдаления
	КонецЦикла;

	Движения.Хозрасчетный.Записывать = Истина;

КонецПроцедуры  

&ИзменениеИКонтроль("ЗаполнитьАналитикуСчетаДохода")
Процедура Расш1_ЗаполнитьАналитикуСчетаДохода(Проводка, СтрокаТаблицы, ТипАналитики, ОтражатьВНалоговомУчете, СуммаВР)

	Счет = Проводка["Счет"+ТипАналитики];
	СвойстваСчета = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Счет);
	
	БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], 1,                   СтрокаТаблицы.Субконто);
	БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], "СтавкиНДС",         СтрокаТаблицы.СтавкаНДС);
	БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], "Номенклатура",      СтрокаТаблицы.Номенклатура);
	БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], "РеализуемыеАктивы", СтрокаТаблицы.Номенклатура);
	
	#Вставка 
	Если Счет = ПланыСчетов.Хозрасчетный.НайтиПоКоду("98.01") Тогда
		БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], 2, СтрокаТаблицы.КорСубконто2);
		БухгалтерскийУчет.УстановитьСубконто(Счет, Проводка["Субконто"+ТипАналитики], 3, СтрокаТаблицы.КорСубконто3);
	КонецЕсли;
	#КонецВставки

	Если СвойстваСчета.Количественный Тогда
		Проводка["Количество"+ТипАналитики] = СтрокаТаблицы.Количество;  
	КонецЕсли;

	Если СвойстваСчета.УчетПоПодразделениям Тогда
		Проводка["Подразделение"+ТипАналитики] = СтрокаТаблицы.Подразделение;
	КонецЕсли;

	Если ОтражатьВНалоговомУчете И СвойстваСчета.НалоговыйУчет Тогда
		Проводка["СуммаНУ"+ТипАналитики] = СтрокаТаблицы.СуммаНУ - СтрокаТаблицы.СуммаНДСРуб;
		Проводка["СуммаВР"+ТипАналитики] = СуммаВР;
		Проводка["СуммаПР"+ТипАналитики] = СтрокаТаблицы.СуммаБУ - СтрокаТаблицы.СуммаНУ - СуммаВР;
	КонецЕсли;

КонецПроцедуры

Процедура Расш1_УстановкаДвиженияСубконтоСчета9801(ТаблицаВыручкиОтРеализации, СтрокаТаблицы, Проводка, ОтражатьВНалоговомУчете)
	
	Если Проводка.СчетКт = ПланыСчетов.Хозрасчетный.НайтиПоКоду("98.01") Тогда
		
		Запрос = Новый Запрос;
		Запрос.Текст = 
		"ВЫБРАТЬ
		|	ДоходыБудущихПериодов.Ссылка КАК ДоходБудующегоПериода
		|ИЗ
		|	Справочник.ДоходыБудущихПериодов КАК ДоходыБудущихПериодов
		|ГДЕ
		|	ДоходыБудущихПериодов.Наименование = &Наименование";
		
		Запрос.УстановитьПараметр("Наименование", Строка(СтрокаТаблицы.Номенклатура));
		
		РезультатЗапроса = Запрос.Выполнить();
		ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать(); // формирую выборку записи из результата запроса
		ВыборкаДетальныеЗаписи.Следующий();
		
		МассивСтрок = Новый Массив;
		МассивСтрок.Добавить(СтрокаТаблицы);
		КопияТаблицаВыручкиОтРеализации = ТаблицаВыручкиОтРеализации.Скопировать(МассивСтрок); // создал копию таблицы 
		
		КопияТаблицаВыручкиОтРеализации.Колонки.Удалить("КорСубконто3");
		КопияТаблицаВыручкиОтРеализации.Колонки.Добавить("КорСубконто3", Новый ОписаниеТипов("СправочникСсылка.ДоходыБудущихПериодов")); // устанавливаю тип колонки		
		
		КопияТаблицаВыручкиОтРеализации.ЗаполнитьЗначения(ВыборкаДетальныеЗаписи.ДоходБудующегоПериода, "КорСубконто3"); // заполняю колонку значением
		ИзмененнаяСтрокаТаблицы = КопияТаблицаВыручкиОтРеализации[0]; 
		
		ЗаполнитьАналитикуСчетаДохода(Проводка, ИзмененнаяСтрокаТаблицы, "Кт", ОтражатьВНалоговомУчете, СтрокаТаблицы.СуммаБУ - СтрокаТаблицы.СуммаНУ); // подменяю 2-ой параметр
	Иначе
		ЗаполнитьАналитикуСчетаДохода(Проводка, СтрокаТаблицы, "Кт", ОтражатьВНалоговомУчете, СтрокаТаблицы.СуммаБУ - СтрокаТаблицы.СуммаНУ);
	КонецЕсли;	
	
КонецПроцедуры