СКД

ВЫБРАТЬ
	ВидыРаботПоЗаказуОбороты.Заказ КАК Заказ,
	ВидыРаботПоЗаказуОбороты.Подразделение КАК Подразделение,
	ВидыРаботПоЗаказуОбороты.ВремяОборот КАК Время,
	ВидыРаботПоЗаказуОбороты.ПериодДень КАК ПериодДень,
	ВидыРаботПоЗаказуОбороты.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ втВремяЗаданное
ИЗ
	РегистрНакопления.ВидыРаботПоЗаказу.Обороты(&НачалоПериода, &КонецПериода, Авто, ) КАК ВидыРаботПоЗаказуОбороты
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втВремяЗаданное.Заказ КАК Заказ,
	втВремяЗаданное.ПериодДень КАК ПериодДень
ПОМЕСТИТЬ втВремяАктуальные
ИЗ
	втВремяЗаданное КАК втВремяЗаданное

СГРУППИРОВАТЬ ПО
	втВремяЗаданное.Заказ,
	втВремяЗаданное.ПериодДень
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВидыРаботПоЗаказуОбороты.Заказ КАК Заказ,
	ВидыРаботПоЗаказуОбороты.Подразделение КАК Подразделение,
	ВидыРаботПоЗаказуОбороты.ВремяОборот КАК Время,
	ВидыРаботПоЗаказуОбороты.ПериодДень КАК ПериодДень,
	ВидыРаботПоЗаказуОбороты.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ втВремя
ИЗ
	РегистрНакопления.ВидыРаботПоЗаказу.Обороты(, , Авто, ) КАК ВидыРаботПоЗаказуОбороты
ГДЕ
	ВидыРаботПоЗаказуОбороты.Заказ В
			(ВЫБРАТЬ РАЗЛИЧНЫЕ
				втВремяАктуальные.Заказ
			ИЗ
				втВремяАктуальные КАК втВремяАктуальные
			ГДЕ
				втВремяАктуальные.ПериодДень >= &НачалоПериода
					И втВремяАктуальные.ПериодДень <= &КонецПериода				
				)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втВремя.ПериодДень КАК ПериодДень,
	втВремя.Подразделение КАК Подразделение
ПОМЕСТИТЬ втДеньИПодразденение
ИЗ
	втВремя КАК втВремя

СГРУППИРОВАТЬ ПО
	втВремя.ПериодДень,
	втВремя.Подразделение
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КоэффициентыСтатейПоПодразделениям.Период КАК Период,
	КоэффициентыСтатейПоПодразделениям.Подразделение КАК Подразделение,
	КоэффициентыСтатейПоПодразделениям.Коэффициент КАК Коэффициент
ПОМЕСТИТЬ втВсеКоэфф
ИЗ
	РегистрСведений.КоэффициентыСтатейПоПодразделениям КАК КоэффициентыСтатейПоПодразделениям
ГДЕ
	КоэффициентыСтатейПоПодразделениям.Период <= &КонецПериода
	И КоэффициентыСтатейПоПодразделениям.Подразделение В
			(ВЫБРАТЬ РАЗЛИЧНЫЕ
				втДеньИПодразденение.Подразделение
			ИЗ
				втДеньИПодразденение КАК втДеньИПодразденение)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втДеньИПодразденение.ПериодДень КАК ПериодДень,
	втДеньИПодразденение.Подразделение КАК Подразделение,
	МАКСИМУМ(втВсеКоэфф.Период) КАК Период
ПОМЕСТИТЬ втПодготовкаКоэфф
ИЗ
	втДеньИПодразденение КАК втДеньИПодразденение
		ЛЕВОЕ СОЕДИНЕНИЕ втВсеКоэфф КАК втВсеКоэфф
		ПО втДеньИПодразденение.Подразделение = втВсеКоэфф.Подразделение
			И втДеньИПодразденение.ПериодДень >= втВсеКоэфф.Период

СГРУППИРОВАТЬ ПО
	втДеньИПодразденение.Подразделение,
	втДеньИПодразденение.ПериодДень
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втПодготовкаКоэфф.ПериодДень КАК ПериодДень,
	втПодготовкаКоэфф.Подразделение КАК Подразделение,
	ЕСТЬNULL(втВсеКоэфф.Коэффициент, 1) КАК Коэффициент
ПОМЕСТИТЬ втВремяИКоэфф
ИЗ
	втПодготовкаКоэфф КАК втПодготовкаКоэфф
		ЛЕВОЕ СОЕДИНЕНИЕ втВсеКоэфф КАК втВсеКоэфф
		ПО втПодготовкаКоэфф.Подразделение = втВсеКоэфф.Подразделение
			И втПодготовкаКоэфф.Период = втВсеКоэфф.Период
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втВремя.Заказ КАК Заказ,
	втВремя.Подразделение КАК Подразделение,
	втВремя.Время КАК Время,
	втВремяИКоэфф.Коэффициент КАК Коэффициент,
	втВремя.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ втВремяИтог
ИЗ
	втВремя КАК втВремя
		ЛЕВОЕ СОЕДИНЕНИЕ втВремяИКоэфф КАК втВремяИКоэфф
		ПО втВремя.ПериодДень = втВремяИКоэфф.ПериодДень
			И втВремя.Подразделение = втВремяИКоэфф.Подразделение
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВыпускЗаказа.Заказ КАК Заказ,
	ВыпускЗаказа.Направление КАК Направление
ПОМЕСТИТЬ втНаправление
ИЗ
	Документ.ВыпускЗаказа КАК ВыпускЗаказа
ГДЕ
	ВыпускЗаказа.Заказ В
			(ВЫБРАТЬ РАЗЛИЧНЫЕ
				втВремяИтог.Заказ
			ИЗ
				втВремяИтог КАК втВремяИтог)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	втВремяИтог.Заказ КАК Заказ,
	втВремяИтог.Подразделение КАК Подразделение,
	втВремяИтог.Время КАК Время,
	втВремяИтог.Коэффициент КАК Коэффициент,
	втНаправление.Направление КАК Направление,
	втВремяИтог.Номенклатура КАК Номенклатура
ИЗ
	втВремяИтог КАК втВремяИтог
		ЛЕВОЕ СОЕДИНЕНИЕ втНаправление КАК втНаправление
		ПО втВремяИтог.Заказ = втНаправление.Заказ
ГДЕ
	втНаправление.Направление <> ""

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	втВремяИтог.Заказ,
	втВремяИтог.Подразделение,
	втВремяИтог.Время,
	втВремяИтог.Коэффициент,
	втНаправление.Направление,
	втВремяИтог.Номенклатура
ИЗ
	втВремяИтог КАК втВремяИтог
		ЛЕВОЕ СОЕДИНЕНИЕ втНаправление КАК втНаправление
		ПО втВремяИтог.Заказ = втНаправление.Заказ
ГДЕ
	втВремяИтог.Заказ = ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)