Можно ли использовать методы web сервиса http запросом?

 текURI						 = "http://tempuri.org/";
    текНаименованиеВебСервиса	 = "MessageService";
    текНаименованиеПорта		 = "BasicHttpBinding_IMessageService";
    
    // Соединение
	текСервис	 = WSСсылки.ТестовыйЕФРСБ.СоздатьWSПрокси(текURI, текНаименованиеВебСервиса, текНаименованиеПорта,,,Новый ЗащищенноеСоединениеOpenSSL);
	текСервис.Пользователь	 = Логин;
	текСервис.Пароль		 = Пароль;
	
	НачалоПериода	 = "2023-10-01T00:00:00";
	КонецПериода	 = "2023-10-20T00:00:00";
	ОтветОтСервера = текСервис.GetMessageIds(НачалоПериода, КонецПериода);

&НаКлиенте
Процедура ТестЕФРСБ(Команда)
	
	ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL;
	
	Заголовки = Новый Соответствие;
	Заголовки.Вставить("Content-Type", "application/json");
	Заголовки.Вставить("accept", "application/json");  
		
	ИмяМетода = "GET";
		
	АдресСервиса	 = "services.fedresurs.ru";
	АдресСтраницы	 = "/Bankruptcy/MessageServiceDemo/WebService.svc";
	
	HTTPСоединение	 = Новый HTTPСоединение(АдресСервиса,,,,,,ЗащищенноеСоединение);
  	HTTPЗапрос		 = Новый HTTPЗапрос(АдресСтраницы, Заголовки);
		
	Попытка
		HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
	Исключение
		// обработка исключения
	КонецПопытки; 	
	
	Если HTTPОтвет.КодСостояния = 401 Тогда
		ЗаголовокАвторизации = HTTPОтвет.Заголовки.Получить("WWW-Authenticate");
		Если НЕ ЗаголовокАвторизации = Неопределено Тогда
			
			ПараметрыАутентификации = Новый Структура;
			ЗаголовокАвторизации = СтрЗаменить(ЗаголовокАвторизации,"Digest","");
			МассивПараметров = СтрРазделить(ЗаголовокАвторизации,",");
			Для Каждого ТекПараметрСтрокой Из МассивПараметров Цикл
				
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "nonce");
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "opaque");
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "stale");
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "algorithm");
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "qop");
				ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, "realm");
				
			КонецЦикла;
			
			nc = 1;
			ПараметрыАутентификации.Вставить("uri", АдресСтраницы);
			ПараметрыАутентификации.Вставить("nc", Формат(nc,"ЧЦ=8; ЧДЦ=; ЧВН=; ЧГ=0"));
			ПараметрыАутентификации.Вставить("cnonce", НРег(СтрЗаменить(Строка(Новый УникальныйИдентификатор), "-", "")));
						
			Если ПараметрыАутентификации.Свойство("nonce") И ПараметрыАутентификации.Свойство("opaque") И ПараметрыАутентификации.Свойство("stale") 
					И ПараметрыАутентификации.Свойство("algorithm") И ПараметрыАутентификации.Свойство("qop") И ПараметрыАутентификации.Свойство("realm") Тогда
					
					HA1 = ПолучитьХеш(Логин+":"+ПараметрыАутентификации.realm+":"+Пароль);    
            		HA1 = ХексВСтроку(HA1);
		            
            		HA2 = ПолучитьХеш(ВРег(ИмяМетода)+":"+АдресСтраницы);
            		HA2 = ХексВСтроку(HA2);
			
					Если ПараметрыАутентификации.qop = "auth" Тогда
                		Response  = ПолучитьХеш(HA1+":"+ПараметрыАутентификации.nonce+":"+ПараметрыАутентификации.nc+":"+ПараметрыАутентификации.cnonce+":"+ПараметрыАутентификации.qop+":"+HA2);    
            		Иначе
                		Response  = ПолучитьХеш(HA1+":"+ПараметрыАутентификации.nonce+":"+HA2);
            		КонецЕсли;
            		Response = ХексВСтроку(Response);
					ПараметрыАутентификации.Вставить("response", Response);
					
					Заголовки = Новый Соответствие();
					Заголовки.Вставить("Content-Type", "application/json");
					Заголовки.Вставить("accept", "application/json");
										
					DigestЗапрос = "Digest username="""+Логин+""", realm="""+ПараметрыАутентификации.realm+""", nonce="""+ПараметрыАутентификации.nonce;
            		DigestЗапрос = DigestЗапрос+""", uri="""+ПараметрыАутентификации.uri+""", qop="""+ПараметрыАутентификации.qop+""", nc="""+ПараметрыАутентификации.nc;
            		DigestЗапрос = DigestЗапрос+""", cnonce="""+ПараметрыАутентификации.cnonce+""", response="""+ПараметрыАутентификации.response+""", opaque="""+ПараметрыАутентификации.opaque+"""";
					Заголовки.Вставить("Authorization", DigestЗапрос);
					
					ЗаполнитьЗначенияСвойств(Заголовки, ПараметрыАутентификации);
					
					HTTPЗапрос		 = Новый HTTPЗапрос(АдресСтраницы, Заголовки);
	
					Попытка
						HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
					Исключение
						// обработка исключения
					КонецПопытки; 
					
			КонецЕсли;
				
		КонецЕсли;
			
	КонецЕсли;
	    
		
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьХеш(Текст)
	
    ОбъектХеш = Новый ХешированиеДанных(ХешФункция.MD5);
    ОбъектХеш.Добавить(Текст);
    
    Возврат ОбъектХеш.ХешСумма;
	
КонецФункции

&НаКлиенте
Функция ХексВСтроку(Текст)
    
    Возврат НРег(СтрЗаменить(Строка(Текст), " ", ""));
    
КонецФункции

&НаКлиенте
Процедура ДобавитьЗначениеИзСтрокиПараметраАутентификации(ПараметрыАутентификации, ТекПараметрСтрокой, ИмяПараметра)
	
	Если НЕ СтрНайти(ТекПараметрСтрокой,ИмяПараметра) = 0 Тогда
		ПараметрыАутентификации.Вставить(ИмяПараметра, СтрЗаменить(СтрЗаменить(СокрЛП(ТекПараметрСтрокой), ИмяПараметра + "=", ""),"""",""));
	КонецЕсли;	
	
КонецПроцедуры