Условное оформление табличной части документа по реквизитам номенклатуры

Question

Клиент хочет выделять номенклатурные позиции с галочкой "Выгодно" красным шрифтом.
Но вот беда - в таблице значений для условного оформления нельзя использовать реквизиты полей таблицы.
Придется создавать под них реквизиты (программно) и заполнять их, отслеживая изменения номенклатуры.
По другому никак?

Вот такой код не работает:

[1C-CODE]
	ЭлементОформления = УсловноеОформление.Элементы.Добавить();
	Элемент = ЭлементОформления.Оформление.Элементы.Найти("ЦветТекста");
	Элемент.Значение = WebЦвета.Красный;
	Элемент.Использование = Истина;
	ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	ЭлементОтбора.Использование = Истина;
	ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("ТЧНоменклатура.Номенклатура.дор_Выгодно");
	ЭлементОтбора.ПравоеЗначение = истина;
	ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
	ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("ТЧНоменклатураНоменклатура");
	ПолеОформления.Использование = Истина;
[/1C-CODE]

Accepted Answer

В общем тупо добавил реквизиты в табличную часть. Розница, редакция 3.0 (3.0.3.147)

Пересчет реквизитов модуль дор_К:
[CODE]
&НаКлиенте
Процедура ПересчитатьРеквизитыРаскраскиНоменклатурыДокумента(Форма, ТаблицаТоваров, ИмяПоляНоменклатуры) Экспорт

	М = Новый Массив();                           

	Для Каждого Строка ИЗ ТаблицаТоваров Цикл
		ТекНоменклатура = Строка[ИмяПоляНоменклатуры];                     
		М.Добавить(ТекНоменклатура);
	КонецЦикла;

	РеквизитыВсе = дор_С.ЗначенияРеквизитовОбъектов(М, "дор_Выгодно, дор_МинМаксЗаполнено"); 

	Для Каждого Строка ИЗ ТаблицаТоваров Цикл
		ТекНоменклатура = Строка[ИмяПоляНоменклатуры];                     
		РеквизитыТекущие = РеквизитыВсе[ТекНоменклатура];
		Если РеквизитыТекущие <> Неопределено Тогда
			Строка.дор_МинМаксЗаполнено = РеквизитыТекущие.дор_МинМаксЗаполнено;
			Строка.дор_Выгодно = РеквизитыТекущие.дор_Выгодно;
		КонецЕсли;
	КонецЦикла;
	
КонецПроцедуры
[/CODE]
На сервере Дор_С:
[CODE]
Процедура РаскраситьНоменклатуруСписка(Форма, СписокЗапасы, ПутьКТЧНоменклатуры, ИдентификаторПоляНоменклатуры, ИмяПоляРаскраскиНоменклатуры) Экспорт
	Перем УсловноеОформление;     
	
	
	Если ТипЗнч(СписокЗапасы) = Тип("ДинамическийСписок") Тогда
		УсловноеОформление = СписокЗапасы.КомпоновщикНастроек.ФиксированныеНастройки.УсловноеОформление;
		ПутьКНоменклатуре = ИдентификаторПоляНоменклатуры;
	Иначе                                                      
		//Также нужно добавить реквизиты
		УсловноеОформление = Форма.УсловноеОформление;
		НовыеРеквизиты = Новый Массив;
		НовыеРеквизиты.Добавить(Новый РеквизитФормы("дор_МинМаксЗаполнено", Новый ОписаниеТипов("Булево"), ПутьКТЧНоменклатуры, "", ложь));
		НовыеРеквизиты.Добавить(Новый РеквизитФормы("дор_Выгодно", Новый ОписаниеТипов("Булево"), ПутьКТЧНоменклатуры, "", ложь));
		Форма.ИзменитьРеквизиты(НовыеРеквизиты); 
		ПутьКНоменклатуре = ПутьКТЧНоменклатуры; // + ?(ЗначениеЗаполнено(ИдентификаторПоляНоменклатуры), "." +  ИдентификаторПоляНоменклатуры, "");

	КонецЕсли;
	
	
	//=== Оформление поля мин-макс
	ЭлементОформления = УсловноеОформление.Элементы.Добавить();
	Элемент = ЭлементОформления.Оформление.Элементы.Найти("ЦветФона");
	Элемент.Значение = WebЦвета.СеребристоСерый;
	Элемент.Использование = Истина;
	ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	ЭлементОтбора.Использование = Истина;
	ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ПутьКНоменклатуре + ".дор_МинМаксЗаполнено");
	ЭлементОтбора.ПравоеЗначение = Ложь;
	ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
	ПолеОформления.Поле = Новый ПолеКомпоновкиДанных(ИмяПоляРаскраскиНоменклатуры);
	ПолеОформления.Использование = Истина;

	//=== Оформление поля выгодно      
	
	ЭлементОформления = УсловноеОформление.Элементы.Добавить();
	Элемент = ЭлементОформления.Оформление.Элементы.Найти("ЦветТекста");
	Элемент.Значение = WebЦвета.Красный;
	Элемент.Использование = Истина;
	ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	ЭлементОтбора.Использование = Истина;
	ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ПутьКНоменклатуре +  ".дор_Выгодно");
	ЭлементОтбора.ПравоеЗначение = истина;
	ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
	ПолеОформления.Поле = Новый ПолеКомпоновкиДанных(ИмяПоляРаскраскиНоменклатуры);
	ПолеОформления.Использование = Истина;

КонецПроцедуры

[/CODE]

В форме списка номенклатуры:
[CODE]
&НаСервере
Процедура M_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)     

	дор_С.РаскраситьНоменклатуруСписка(ЭтаФорма, СписокЗапасы, "СписокЗапасы", "Номенклатура", "Наименование");
	
КонецПроцедуры


[/CODE]



В форме документа установки цен:

[CODE]
&НаСервере
Процедура M_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	
	дор_С.РаскраситьНоменклатуруСписка(ЭтаФорма, ТЧНоменклатура, "ТЧНоменклатура", "Номенклатура", "ТЧНоменклатураНоменклатура");
	
КонецПроцедуры

&НаКлиенте
Процедура M_ОбновитьНомераСтрок() Экспорт
	Сч = 0;
	Для Каждого Строка ИЗ ТЧНоменклатура Цикл
		Сч = Сч + 1;
		Строка.дор_НомерСтроки = Сч;
	КонецЦикла;            
	//Раскрашиваем
	дор_К.ПересчитатьРеквизитыРаскраскиНоменклатурыДокумента(ЭтаФорма, ТЧНоменклатура, "Номенклатура");
КонецПроцедуры


&НаКлиенте
&После("ОбновитьКоличествоЗаписейПоДокументу")
Процедура M_ОбновитьКоличествоЗаписейПоДокументу()
	M_ОбновитьНомераСтрок();
КонецПроцедуры

&НаКлиенте
Процедура M_ПриОткрытииПосле(Отказ)
	M_ОбновитьНомераСтрок();
КонецПроцедуры


&НаКлиенте
&После("ОбработатьЗаполненияДокументаПриОткрытии")
Процедура M_ОбработатьЗаполненияДокументаПриОткрытии(Результат, ДополнительныеПараметры)
	//Если документ грузится фоновым заданием
	M_ОбновитьНомераСтрок();
КонецПроцедуры


[/CODE]

И в обработке печати ценников:
[CODE]

&НаСервере
Процедура M_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	дор_С.РаскраситьНоменклатуруСписка(ЭтаФорма, Объект.Товары, "Объект.Товары", "Номенклатура", "ТоварыНоменклатура");
КонецПроцедуры

&НаКлиенте
Процедура ОбновитьРеквизитыТоваров() Экспорт
	дор_К.ПересчитатьРеквизитыРаскраскиНоменклатурыДокумента(ЭтаФорма, Объект.Товары, "Номенклатура");
КонецПроцедуры

&НаКлиенте
&После("ОповещениеПодборПроизведен")
Процедура M_ОповещениеПодборПроизведен(РезультатЗакрытия, ДополнительныеПараметры)
	ОбновитьРеквизитыТоваров();
КонецПроцедуры


&НаКлиенте
Процедура M_ЗаполнитьПоОтборуПосле(Команда)
	ОбновитьРеквизитыТоваров();
КонецПроцедуры

&НаКлиенте
&После("ОповещениеЗаполнитьТаблицуТоваров")
Процедура M_ОповещениеЗаполнитьТаблицуТоваров(Результат, ДополнительныеПараметры)
	ОбновитьРеквизитыТоваров();
КонецПроцедуры

&НаКлиенте
Процедура M_ПриОткрытииПосле(Отказ)
	ОбновитьРеквизитыТоваров();
КонецПроцедуры

&НаКлиенте
&После("ЗаполнитьПоПакетамЦенников")
Процедура M_ЗаполнитьПоПакетамЦенников(СтруктураТоваров, Параметры)
	ОбновитьРеквизитыТоваров();
КонецПроцедуры
[/CODE]

Процедура раскраски используется общая для номенклатуры и документа.
Реквизиты получаются одним типовым запросом по всей номенклатуре документа и обновляются в цикле по строкам.