1с Работа с остатками

Процедура ОбработкаПроведения(Отказ, Режим) 
	

    Запрос = Новый Запрос;
    Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
    Запрос.Текст =
        "ВЫБРАТЬ
        |   Таблица.Оборудование КАК Оборудование,
        |   СУММА(Таблица.Количество) КАК Количество
        |ПОМЕСТИТЬ Таблица
        |ИЗ
        |   Документ.Выдача.Таблица КАК Таблица
        |ГДЕ
        |   Таблица.Ссылка = &Ссылка
        |
        |СГРУППИРОВАТЬ ПО
        |   Таблица.Оборудование
        |
        |ИНДЕКСИРОВАТЬ ПО
        |   Оборудование
        |;
        |
        |////////////////////////////////////////////////////////////­////////////////////
        |ВЫБРАТЬ
        |   Таблица.Оборудование КАК Оборудование,
        |   Таблица.Количество КАК Количество
        |ИЗ
        |   Таблица КАК Таблица";
    Запрос.УстановитьПараметр("Ссылка", Ссылка);
    РезультатЗапроса = Запрос.Выполнить(); 
    

    Движения.РегистрОстаткаНаСкладе.Очистить();
    ВыборкаТаблица = РезультатЗапроса.Выбрать();
    Пока ВыборкаТаблица.Следующий() Цикл
        Движение = Движения.РегистрОстаткаНаСкладе.ДобавитьРасход();
        Движение.Период = Дата;
        Движение.Оборудование = ВыборкаТаблица.Оборудование;
        Движение.Количество = ВыборкаТаблица.Количество;
        Движение.Склад = Склад;
    КонецЦикла; 
    

    Движения.РегистрОстаткаНаСкладе.Записывать = Истина;
    Движения.Записать();
    
 
    Запрос.Текст =
        "ВЫБРАТЬ
        |   Остатки.Оборудование КАК Оборудование,
        |   ПРЕДСТАВЛЕНИЕССЫЛКИ(Остатки.Оборудование) КАК ОборудованиеПредставление,
        |   -Остатки.КоличествоОстаток КАК Дефицит
        |ИЗ
        |   РегистрНакопления.РегистрОстаткаНаСкладе.Остатки(
        |           &МоментВремени,
        |           Оборудование В
        |               (ВЫБРАТЬ
        |                   Таблица.Оборудование КАК Оборудование
        |               ИЗ
        |                   Таблица КАК Таблица)) КАК Остатки
        |ГДЕ
        |   Остатки.КоличествоОстаток < 0";
   
    ГраницаКонтроля = Новый Граница(МоментВремени(), ВидГраницы.Включая);
    Запрос.УстановитьПараметр("МоментВремени", ГраницаКонтроля);
    РезультатЗапроса = Запрос.Выполнить();
    

    Если Не РезультатЗапроса.Пустой() Тогда
        Отказ = Истина;
        ВыборкаОшибки = РезультатЗапроса.Выбрать();
        Пока ВыборкаОшибки.Следующий() Цикл
            Сообщение = Новый СообщениеПользователю;
            Сообщение.Текст = "Оборудования "+ВыборкаОшибки.ОборудованиеПредставление+" недостаточно в количестве "+ВыборкаОшибки.Дефицит+" шт.";
            Сообщение.Сообщить();
        КонецЦикла;
    КонецЕсли;
    

   КонецПроцедуры