Пример многопоточной обработки (БСП)

// Процедура выполняет обработку в несколько потоков
// Параметры:
//  ВходящиеПараметры	- Структура - содержит переданные параметры для выполнения процедуры
//		* ОбработкаСсылка	- СправочникСсылка.ДополнительныеОтчетыИОбработки
//		* КоличествоПотоков - Число - Сколько потоков запускать
//		* УникальныйИдентификатор - ИдентификаторФормы
//  АдресРезультата		- Строка	- адрес результата выполнения фонового задания
//
Процедура ВыполнитьМногопоточно(ВходящиеПараметры, АдресРезультата) Экспорт
	
	// Задумка
	// 1. Получаем массив ВСЕХ объектов для обработки
	// 2. Разбиваем этот массив на порции(Массивы) согласно входящим параметрам
	// 3. Для каждой порции запускаем свое фоновое задание, которое будет выполнять экспортный метод ОбработатьОбъекты()
	// 3.1. Фоновые задания шлют сообщения фиксированного формата
	// 4. Ждем завершения выполнения фоновых заданий
	// 4.1. Проверяем статусы запущенных фоновых заданий, читаем сообщения. 
	// 4.2. Отправляем свои сообщения основному потоку
	// 5. В самом конце складываем итоговый результат работы всех ФЗ в АдресРезультата
	//
	// Общение между Фоновыми заданиями и основным процессом происходит посредством Объекта СообщениеПользователю и
	// Метода ФЗ.ПолучитьСообщенияПользователю(). Это реализовано в 
	// - ДлительныеОперации.СообщитьПрогресс()
	// - ДлительныеОперации.ПрочитатьПрогресс()
	
	Перем КоличествоПотоков, МинимальнаяПорция, ИдентификаторУправляющегоЗадания;
	
	МинимальнаяПорция = 100;
	
	ОбработкаСсылка = ВходящиеПараметры.ОбработкаСсылка;
	КоличествоПотоков = ВходящиеПараметры.КоличествоПотоков;
	УникальныйИдентификатор = ВходящиеПараметры.ИдентификаторФормы;
	
	// Для того чтобы в исполняющих фоновых заданиях понимать, что управляющее фоновое задание активно
	СеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФЗ = СеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	Если ФЗ <> Неопределено Тогда
		ИдентификаторУправляющегоЗадания = ФЗ.УникальныйИдентификатор;
	КонецЕсли;
	
	Если ВходящиеПараметры.Свойство("РазмерПорции") Тогда
		МинимальнаяПорция = ВходящиеПараметры.РазмерПорции;
	КонецЕсли;
	
	// 1. Получаем массив ВСЕХ объектов для обработки
	Объекты = Объекты(ВходящиеПараметры.ПараметрыОбработки);
	
	// Удаляем пришедшую коллекцию объектов, чтобы не гнать её в исполняющие фоновые задания
	Если ВходящиеПараметры.ПараметрыОбработки.Свойство("ДанныеДляОбработки") Тогда
		ВходящиеПараметры.ПараметрыОбработки.Удалить("ДанныеДляОбработки")
	КонецЕсли;
	
	// 2. Разбиваем этот массив на порции(Массивы) согласно входящим параметрам
	МассивПорций = РазбитьНаПорции(Объекты, КоличествоПотоков, МинимальнаяПорция);
	КоличествоПотоков = МассивПорций.Количество(); // Количество потоков может измениться после разбиение на порции
	
	ОбъектовВсего = Объекты.Количество();
	Объекты = Неопределено;
	
	// 3. Для каждой порции запускаем свое фоновое задание, которое будет выполнять экспортный метод ОбработатьОбъекты()
	// Таблица для хранения последних известных данных о запущенных нами фоновых заданиях
	// Почему так? Потому что будем ждать завершения фоновых заданий в последнем цикле может оказаться, что часть Фоновых заданий
	// Выполнена и сообщения от них уже все получены, поэтому мы храним данные последних сообщений ФЗ в таблице
	ДанныеФЗ = Новый ТаблицаЗначений;
	ДанныеФЗ.Колонки.Добавить("ИдентификаторЗадания");
	ДанныеФЗ.Колонки.Добавить("Обработано", Новый ОписаниеТипов("Число"));
	ДанныеФЗ.Колонки.Добавить("Процент", Новый ОписаниеТипов("Число"));
	ДанныеФЗ.Колонки.Добавить("АдресРезультата", Новый ОписаниеТипов("Строка"));
	
	Для Каждого Порция Из МассивПорций Цикл
		ПараметрыЗапуска = Новый Структура("Объекты, ПараметрыОбработки", Порция, ВходящиеПараметры.ПараметрыОбработки);
		ПараметрыЗапуска.Вставить("ИдентификаторУправляющегоЗадания", ИдентификаторУправляющегоЗадания);
		
		НаименованиеЗадания = НСтр("ru = 'Обработка объекта в потоке'");		
		ВыполняемыйМетод = "ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки";
		
		ПараметрыЗадания = Новый Структура;
		ПараметрыЗадания.Вставить("ИмяОбработки", ИспользуемоеИмяФайла);
		ПараметрыЗадания.Вставить("ИмяМетода", "ОбработатьОбъекты"); 
		ПараметрыЗадания.Вставить("ПараметрыВыполнения", ПараметрыЗапуска);
		ПараметрыЗадания.Вставить("ЭтоВнешняяОбработка", Истина);
		ПараметрыЗадания.Вставить("ДополнительнаяОбработкаСсылка", ОбработкаСсылка);
		
		ПараметрыВыполнения = ДлительныеОперации.ПараметрыВыполненияВФоне(УникальныйИдентификатор);
		ПараметрыВыполнения.НаименованиеФоновогоЗадания = НаименованиеЗадания;
		ПараметрыВыполнения.ЗапуститьВФоне = Истина;
		ПараметрыВыполнения.Вставить("ИдентификаторФормы", УникальныйИдентификатор); 
		
		СтруктураФоновогоЗадания = ДлительныеОперации.ВыполнитьВФоне(ВыполняемыйМетод, ПараметрыЗадания, ПараметрыВыполнения);
		
		Если СтруктураФоновогоЗадания.Статус = "Ошибка" Тогда
			Сообщить(СтруктураФоновогоЗадания.ПодробноеПредставлениеОшибки);
			Прервать;
		КонецЕсли;
		
		ЗаполнитьЗначенияСвойств(ДанныеФЗ.Добавить(), СтруктураФоновогоЗадания);
	КонецЦикла;
	
	// Ждем завершения всех заданий
	ЕстьАктивныеФЗ = Истина;
	ПроцентВыполненияПрошлойИтерации = 0;
	Пока ЕстьАктивныеФЗ Цикл
		ЕстьАктивныеФЗ = Ложь;
		
		// 4.1. Проверяем статусы запущенных фоновых заданий, читаем сообщения
		Для Каждого СтрокаТЗ ИЗ ДанныеФЗ Цикл
			
			ИдентификаторЗадания = СтрокаТЗ.ИдентификаторЗадания;
			ФоновоеЗадание = ФоновыеЗадания.НайтиПоУникальномуИдентификатору(ИдентификаторЗадания);
			
			Если ФоновоеЗадание.Состояние = СостояниеФоновогоЗадания.Активно Тогда
				ЕстьАктивныеФЗ = Истина;
			КонецЕсли;
			
			ПрогрессИСообщения = ДлительныеОперации.ПрочитатьПрогресс(ИдентификаторЗадания);
			
			Если ТипЗнч(ПрогрессИСообщения) = Тип("Структура") Тогда
				СтрокаТЗ.Процент = ПрогрессИСообщения.Процент;
				СтрокаТЗ.Обработано = ПрогрессИСообщения.ДополнительныеПараметры.Обработано;
			КонецЕсли;
			
		КонецЦикла; 
		
		// 4.2. Отправляем свои сообщения основному потоку
		Обработано = ДанныеФЗ.Итог("Обработано");
		ТекущийПроцентВыполнения = Цел(Обработано / ОбъектовВсего * 100);
		
		Если ТекущийПроцентВыполнения > ПроцентВыполненияПрошлойИтерации Тогда
			ДопПараметры = Новый Структура("Обработано", Обработано);
			ТекстСообщения = СтрШаблон("Обработано %1 из %2, потоков: %3", Обработано, ОбъектовВсего, КоличествоПотоков);
			ДлительныеОперации.СообщитьПрогресс(ТекущийПроцентВыполнения, ТекстСообщения, ДопПараметры);
		КонецЕсли;
		
		ПроцентВыполненияПрошлойИтерации = ТекущийПроцентВыполнения;
		
		ОбщегоНазначенияБТС.Пауза(1);

	КонецЦикла;
	
	// 5. В самом конце складываем итоговый результат работы всех ФЗ в АдресРезультата
	ИтоговыйРезультат = ОбъектРезультат();
	Для Каждого СтрокаТЗ ИЗ ДанныеФЗ Цикл
		
		РезультатФЗ = ПолучитьИзВременногоХранилища(СтрокаТЗ.АдресРезультата);
		
		Если РезультатФЗ <> Неопределено Тогда
			ОбщегоНазначенияКлиентСервер.ДополнитьТаблицу(РезультатФЗ, ИтоговыйРезультат);
			УдалитьИзВременногоХранилища(СтрокаТЗ.АдресРезультата); // Чтобы не мусорить
		КонецЕсли;
				
	КонецЦикла;
	
	ПоместитьВоВременноеХранилище(ИтоговыйРезультат, АдресРезультата);
	
КонецПроцедуры