ГосконтрактЕИС

Форум Программирование Общие вопросы программирования (Dev)

1. WWWWW 8 03.10.22 13:26 Сейчас в теме

Была старая обработка по загрузке реализации в 1с БУХ 3. Теперь при последнем обновлении на (3.0.121.25) Выдает такую ошибку:

Не удалось загрузить данные! {Общий модуль.РеализацияТоваровУслугФормы.Модуль(442)}:
Поле объекта не обнаружено (ГосконтрактЕИС)

Подскажите как можно эту исправить в обработке, что там вообще в этом параметре должно быть указанно или как его пропустить.

Найденные решения

13. a1ex4ndr 5 03.10.22 15:52 Сейчас в теме

в обработке ДанныеОбъекта это кто? Реквизит или таблица\масссив\соответствие?

14. a1ex4ndr 5 03.10.22 15:55 Сейчас в теме

(13) имеется в виду программно формируемый таблица\масссив\соответствие или таблица на форме?

16. WWWWW 8 03.10.22 16:49 Сейчас в теме

(14)Все разобрался)) Спасибо! Добавил ГосконтрактЕИС сюда:

ДанныеОбъекта = Новый Структура("Ссылка, Дата, ВидОперации, Организация, ДеятельностьНаПатенте,
	|Склад, ТипЦен, ВалютаДокумента, КурсВзаиморасчетов, КратностьВзаиморасчетов,
	|ГосконтрактЕИС,СуммаВключаетНДС, ДоговорКонтрагента,
	|ЭтоКомиссия, Реализация, ДокументБезНДС");

Остальные ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. a1ex4ndr 5 03.10.22 13:34 Сейчас в теме

Видимо госконтракт должен быть))
Напиши строку эту и как этот модуль вызывается из обработки.

3. WWWWW 8 03.10.22 13:44 Сейчас в теме

(2)Эту строку просит как раз таки не обработка а 1С. Видимо в обновлении какие то изменения внесли.

5. WWWWW 8 03.10.22 13:46 Сейчас в теме

4. a1ex4ndr 5 03.10.22 13:45 Сейчас в теме

строку скинь 442ю

6. WWWWW 8 03.10.22 13:47 Сейчас в теме

(4)

ЭлектронноеАктированиеБП.ДополнитьДанныеСтрокиСведениямиПоГосконтракту(СтрокаТабличнойЧасти, ДанныеОбъекта.ГосконтрактЕИС);

7. a1ex4ndr 5 03.10.22 14:59 Сейчас в теме

ГосконтрактЕИС в договоре есть такой реквизит, ДанныеОбъекта это к документу относится? В документе ЭтапГосконтрактаЕИС и ИдентификаторСтрокиГосконтрактаЕИС.

9. WWWWW 8 03.10.22 15:32 Сейчас в теме

(7)Везде читаю что данный функционал включен только в версии КОРП а у нас ПРОФ.
Скорее всего ДанныеОбъекта это к документу реализации и относится. Вижу в нем эти реквизиты. Как их допустим оставить пустыми чтобы данные загрузились?

8. a1ex4ndr 5 03.10.22 15:28 Сейчас в теме

Не, вру в договоре ГосударственныйКонтракт реквизит. Смотри ДанныеОбъекта откуда берет.

10. a1ex4ndr 5 03.10.22 15:38 Сейчас в теме

Если у тебя ЭлектронноеАктированиеБП.ДополнитьДанныеСтрокиСведениямиПоГосконтракту( из твоей обработки не вызывается - смотри что вызывается - и откуда вызывается этот метод, как то же туда передается ДанныеОбъекта.

12. WWWWW 8 03.10.22 15:41 Сейчас в теме

(10)в обработке так:

Процедура УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, Знач ДанныеОбъекта, Знач СчетаУчетаКЗаполнению)

	РеализацияТоваровУслугФормы.УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, ДанныеОбъекта, СчетаУчетаКЗаполнению);
	
	ЗаполнитьДобавленныеКолонкиСтрокиТаблицыУслуги(СтрокаТабличнойЧасти, ДанныеОбъекта);

КонецПроцедуры

В 1с было так:

Процедура УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, Знач ДанныеОбъекта, Знач СчетаУчетаКЗаполнению) Экспорт
	
	Результат = СчетаУчетаВДокументах.ЗаполнитьРеквизитыПриИзменении(
		Документы.РеализацияТоваровУслуг,
		СчетаУчетаКЗаполнению,
		ДанныеОбъекта,
		"Услуги",
		СтрокаТабличнойЧасти);
		
	ЗаполнитьЗначенияСвойств(СтрокаТабличнойЧасти, Результат);
	
	Если Не ЗначениеЗаполнено(ДанныеОбъекта.ТипЦен) Тогда
		ДанныеОбъекта.Вставить("СпособЗаполненияЦены", Перечисления.СпособыЗаполненияЦен.ПоПродажнымЦенам);
	КонецЕсли;	

	СведенияОНоменклатуре = БухгалтерскийУчетПереопределяемый.ПолучитьСведенияОНоменклатуре(
		СтрокаТабличнойЧасти.Номенклатура, ДанныеОбъекта, Ложь);
	Если СведенияОНоменклатуре = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	СтрокаТабличнойЧасти.Содержание	= СведенияОНоменклатуре.НаименованиеПолное;
	СтрокаТабличнойЧасти.Цена			= СведенияОНоменклатуре.Цена;
	СтрокаТабличнойЧасти.СтавкаНДС		= СведенияОНоменклатуре.СтавкаНДС;
	
	ОбработкаТабличныхЧастейКлиентСервер.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, 1);
	ОбработкаТабличныхЧастейКлиентСервер.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ДанныеОбъекта.СуммаВключаетНДС);

КонецПроцедуры

Показать

А стало так:

Процедура УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, Знач ДанныеОбъекта, Знач СчетаУчетаКЗаполнению) Экспорт
	
	Результат = СчетаУчетаВДокументах.ЗаполнитьРеквизитыПриИзменении(
		Документы.РеализацияТоваровУслуг,
		СчетаУчетаКЗаполнению,
		ДанныеОбъекта,
		"Услуги",
		СтрокаТабличнойЧасти);
		
	ЗаполнитьЗначенияСвойств(СтрокаТабличнойЧасти, Результат);
	
	Если Не ЗначениеЗаполнено(ДанныеОбъекта.ТипЦен) Тогда
		ДанныеОбъекта.Вставить("СпособЗаполненияЦены", Перечисления.СпособыЗаполненияЦен.ПоПродажнымЦенам);
	КонецЕсли;	

	СведенияОНоменклатуре = БухгалтерскийУчетПереопределяемый.ПолучитьСведенияОНоменклатуре(
		СтрокаТабличнойЧасти.Номенклатура, ДанныеОбъекта, Ложь);
	Если СведенияОНоменклатуре = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	СтрокаТабличнойЧасти.Содержание = СведенияОНоменклатуре.НаименованиеПолное;
	СтрокаТабличнойЧасти.Цена       = СведенияОНоменклатуре.Цена;
	СтрокаТабличнойЧасти.СтавкаНДС  = СведенияОНоменклатуре.СтавкаНДС;
	
	ЭлектронноеАктированиеБП.ДополнитьДанныеСтрокиСведениямиПоГосконтракту(СтрокаТабличнойЧасти, ДанныеОбъекта.ГосконтрактЕИС);
	
	ОбработкаТабличныхЧастейКлиентСервер.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, 1);
	ОбработкаТабличныхЧастейКлиентСервер.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ДанныеОбъекта.СуммаВключаетНДС);

КонецПроцедуры

Показать

11. WWWWW 8 03.10.22 15:39 Сейчас в теме

(8)там ссылка на СправочникСсылка.ГосКонтракты. У нас этот справочник даже неактивен

13. a1ex4ndr 5 03.10.22 15:52 Сейчас в теме

в обработке ДанныеОбъекта это кто? Реквизит или таблица\масссив\соответствие?

15. WWWWW 8 03.10.22 16:14 Сейчас в теме

(13)

Функция ОбработатьСтрокуНоменклатуры(Объект,Знач СтрокаТабличнойЧасти)
	// Получим общие параметры обработки для реквизитов документа
	//ПараметрыОбработки = РеализацияТоваровУслугФормыКлиент.ПодготовитьПараметрыОбработкиУслугиНоменклатураПриИзменении(
	//	ЭтаФорма, ТекущиеДанные);
	СтрокаТабличнойЧасти=СтрокаТабличнойЧастиВСтруктуру(СтрокаТабличнойЧасти);
	
	//Объект = Форма.Объект;
	ЭтоКомиссия = Ложь;
	
	ДанныеСтрокиТаблицы = Новый Структура("Номенклатура, Содержание, Количество,
	|Цена, Сумма, СтавкаНДС, СуммаНДС");
	ЗаполнитьЗначенияСвойств(ДанныеСтрокиТаблицы, СтрокаТабличнойЧасти);
	
	ДанныеОбъекта = Новый Структура("Ссылка, Дата, ВидОперации, Организация, ДеятельностьНаПатенте,
	|Склад, ТипЦен, ВалютаДокумента, КурсВзаиморасчетов, КратностьВзаиморасчетов,
	|СуммаВключаетНДС, ДоговорКонтрагента,
	|ЭтоКомиссия, Реализация, ДокументБезНДС");
	ЗаполнитьЗначенияСвойств(ДанныеОбъекта, Объект);
	ДанныеОбъекта.ЭтоКомиссия = ЭтоКомиссия;
	ДанныеОбъекта.Реализация  = Истина;
	
	ПараметрыЗаполненияСчетовУчета = РеализацияТоваровУслугФормыКлиентСервер.НачатьЗаполнениеСчетовУчета(
	"Услуги.Номенклатура",
	Объект,
	СтрокаТабличнойЧасти,
	ДанныеОбъекта,
	ДанныеСтрокиТаблицы);
	
	ПараметрыОбработки = Новый Структура();
	ПараметрыОбработки.Вставить("ДанныеСтрокиТаблицы", 	ДанныеСтрокиТаблицы);
	ПараметрыОбработки.Вставить("ДанныеОбъекта", 		ДанныеОбъекта);
	ПараметрыОбработки.Вставить("СчетаУчетаКЗаполнению", ПараметрыЗаполненияСчетовУчета.КЗаполнению);		
	
	// Дополнительные поля, требующиеся для заполнения добавленных колонок табличного поля текущей формы.
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("Всего", 0);
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("АналитикаУчета",          "");
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("АналитикаУчетаЗаполнена", Ложь);
	
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("СчетДоходов");
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("Субконто");
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("СчетУчетаНДСПоРеализации");
	ПараметрыОбработки.ДанныеСтрокиТаблицы.Вставить("СчетРасходов");
	
	
	//
	ЗаполнитьПараметрыОбъектаДляЗаполненияДобавленныхКолонок(Объект, ПараметрыОбработки.ДанныеОбъекта);
	
	УслугиНоменклатураПриИзмененииНаСервере(
		ПараметрыОбработки.ДанныеСтрокиТаблицы,
		ПараметрыОбработки.ДанныеОбъекта,
		ПараметрыОбработки.СчетаУчетаКЗаполнению);
	
	ЗаполнитьЗначенияСвойств(СтрокаТабличнойЧасти, ПараметрыОбработки.ДанныеСтрокиТаблицы);
	
	Возврат(СтрокаТабличнойЧасти);
КонецФункции // ()

Процедура УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, Знач ДанныеОбъекта, Знач СчетаУчетаКЗаполнению)

	РеализацияТоваровУслугФормы.УслугиНоменклатураПриИзмененииНаСервере(СтрокаТабличнойЧасти, ДанныеОбъекта, СчетаУчетаКЗаполнению);
	
	ЗаполнитьДобавленныеКолонкиСтрокиТаблицыУслуги(СтрокаТабличнойЧасти, ДанныеОбъекта);

КонецПроцедуры

Показать

14. a1ex4ndr 5 03.10.22 15:55 Сейчас в теме

(13) имеется в виду программно формируемый таблица\масссив\соответствие или таблица на форме?

16. WWWWW 8 03.10.22 16:49 Сейчас в теме

(14)Все разобрался)) Спасибо! Добавил ГосконтрактЕИС сюда:

ДанныеОбъекта = Новый Структура("Ссылка, Дата, ВидОперации, Организация, ДеятельностьНаПатенте,
	|Склад, ТипЦен, ВалютаДокумента, КурсВзаиморасчетов, КратностьВзаиморасчетов,
	|ГосконтрактЕИС,СуммаВключаетНДС, ДоговорКонтрагента,
	|ЭтоКомиссия, Реализация, ДокументБезНДС");

Оставьте свое сообщение

E-mail: