Продажи с клиентами которые не покупали

Question

(13)Здравствуйте, как правильно сделать соединение в запросе чтоб в отчете вышли данные по клиентам которые ничего не покупали и про товар который не продавался
пробовал несколько вариантов не прокатывает

[1C-CODE]ВЫБРАТЬ
	ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот КАК Количество,
	ВыручкаИСебестоимостьПродажОбороты.СуммаВыручкиОборот КАК Выручка,
	ВыручкаИСебестоимостьПродажОбороты.Регистратор КАК Регистратор,
	ВыручкаИСебестоимостьПродажОбороты.СуммаВыручкиОборот - ВЫБОР
		КОГДА СтоимостьТоваров.Стоимость = СтоимостьТоваров.СтоимостьБезНДС
			ТОГДА (СтоимостьТоваров.Стоимость + СтоимостьТоваров.СтоимостьДопРасходы) * ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот
		ИНАЧЕ (СтоимостьТоваров.Стоимость + СтоимостьТоваров.СтоимостьДопРасходы - СтоимостьТоваров.СтоимостьДопРасходыБезНДС) * ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот
	КОНЕЦ КАК Маржа,
	ВыручкаИСебестоимостьПродажОбороты.Период КАК Период,
	ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаНоменклатуры.МестоХранения КАК Склад,
	ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаПоПартнерам.Организация КАК Организация,
	ВЫБОР
		КОГДА СтоимостьТоваров.Стоимость = СтоимостьТоваров.СтоимостьБезНДС
			ТОГДА (СтоимостьТоваров.Стоимость + СтоимостьТоваров.СтоимостьДопРасходы) * ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот
		ИНАЧЕ (СтоимостьТоваров.Стоимость + СтоимостьТоваров.СтоимостьДопРасходы - СтоимостьТоваров.СтоимостьДопРасходыБезНДС) * ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот
	КОНЕЦ КАК Себестоимость,
	ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаПоПартнерам.Партнер КАК Партнер
ПОМЕСТИТЬ Продажи
ИЗ
	РегистрНакопления.ВыручкаИСебестоимостьПродаж.Обороты(&НачалоПериода, &КонецПериода, Регистратор, ) КАК ВыручкаИСебестоимостьПродажОбороты
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СтоимостьТоваров КАК СтоимостьТоваров
		ПО ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаНоменклатуры = СтоимостьТоваров.АналитикаУчетаНоменклатуры
			И ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаПоПартнерам.Организация = СтоимостьТоваров.Организация
			И (СтоимостьТоваров.Период = НАЧАЛОПЕРИОДА(ВыручкаИСебестоимостьПродажОбороты.Период, МЕСЯЦ))
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Продажи.Количество КАК Количество,
	Продажи.Выручка КАК Выручка,
	Продажи.Регистратор КАК Регистратор,
	Продажи.Маржа КАК Маржа,
	Продажи.Период КАК Период,
	Продажи.Склад КАК Склад,
	Продажи.Номенклатура КАК Номенклатура,
	Продажи.Организация КАК Организация,
	Продажи.Себестоимость КАК Себестоимость,
	Партнеры.Ссылка КАК Партнер
ИЗ
	Справочник.Партнеры КАК Партнеры
		ЛЕВОЕ СОЕДИНЕНИЕ Продажи КАК Продажи
		ПО Партнеры.Ссылка = Продажи.Партнер

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	Продажи.Количество,
	Продажи.Выручка,
	Продажи.Регистратор,
	Продажи.Маржа,
	Продажи.Период,
	Продажи.Склад,
	Товары.Ссылка,
	Продажи.Организация,
	Продажи.Себестоимость,
	Продажи.Партнер
ИЗ
	Справочник.Номенклатура КАК Товары
		ЛЕВОЕ СОЕДИНЕНИЕ Продажи КАК Продажи
		ПО (Продажи.Номенклатура.Ссылка = Продажи.Номенклатура)[/1C-CODE]

Accepted Answer

(6) Переводил одних с 7.7 на УТ11 тоже такая хотелка была. Отговаривать пытался, но пришлось делать...
Не вдаваясь в подробности и упрощенно можно как-то так 
[CODE]ВЫБРАТЬ
	Номенклатура.Ссылка КАК Номенклатура,
	Контрагенты.Ссылка КАК Контрагент
ПОМЕСТИТЬ ВТ_КонтрагентыНоменклатура
ИЗ
	Справочник.Номенклатура КАК Номенклатура,
	Справочник.Контрагенты КАК Контрагенты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_КонтрагентыНоменклатура.Контрагент КАК Контрагент,
	ВТ_КонтрагентыНоменклатура.Номенклатура КАК Номенклатура,
	ЕСТЬNULL(ВыручкаИСебестоимостьПродажОбороты.КоличествоОборот, 0) КАК КоличествоОборот
ИЗ
	ВТ_КонтрагентыНоменклатура КАК ВТ_КонтрагентыНоменклатура
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ВыручкаИСебестоимостьПродаж.Обороты КАК ВыручкаИСебестоимостьПродажОбороты
		ПО ВТ_КонтрагентыНоменклатура.Контрагент = ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаПоПартнерам.Контрагент
			И ВТ_КонтрагентыНоменклатура.Номенклатура = ВыручкаИСебестоимостьПродажОбороты.АналитикаУчетаНоменклатуры.Номенклатура[/CODE]Если номенклатуры и контрагентов много, то без дополнительных отборов по ним будут большие тормоза.