Добавить свой реквизит на печатную форму.

Функция СформироватьПечатнуюФормуВетеринарнойСправки(ОписаниеКоманды) Экспорт
	
	#Если Не ВебКлиент Тогда
	АдресаПечатныхФорм = УправлениеПечатьюУВСВызовСервера.СформироватьПечатнуюФормуВетеринарнойСправки(ОписаниеКоманды.ОбъектыПечати);
	
	Для Каждого ТекЭлемент Из АдресаПечатныхФорм Цикл
		ДвоичныеДанные = ПолучитьИзВременногоХранилища(ТекЭлемент.Значение);
		ИмяВременногоФайлаPDF = ПолучитьИмяВременногоФайла("pdf");
		ДвоичныеДанные.Записать(ИмяВременногоФайлаPDF);
		ОбщегоНазначенияКлиент.ЗапуститьПрограмму(ИмяВременногоФайлаPDF);
	КонецЦикла;
	#КонецЕсли
	
КонецФункции

-----

Функция СформироватьПечатнуюФормуВетеринарнойСправки(ОбъектыПечати) Экспорт
	
	Возврат Документы.ВСД.СформироватьПечатнуюФормуВетеринарнойСправки(ОбъектыПечати);
	
КонецФункции

-----

Функция СформироватьПечатнуюФормуВетеринарнойСправки(МассивДокументов) Экспорт
	
	ТипОбъекта = ОбщегоНазначения.ИмяТаблицыПоСсылке(МассивДокументов[0]);
	
	Запрос = Новый Запрос;
	Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	
	СоздатьВТТаблицаДокументов(Запрос.МенеджерВременныхТаблиц, ТипОбъекта, МассивДокументов);
	
	Запрос.Текст = 
		"ВЫБРАТЬ РАЗРЕШЕННЫЕ
		|	ТаблицаДокументов.ВСД КАК ВСД,
		|	ТаблицаДокументов.ВСД.GUID_Меркурий КАК GUID_Меркурий,
		|	ТаблицаДокументов.ВСД.Представление КАК ПредставлениеДокумента
		|ИЗ
		|	ТаблицаДокументов КАК ТаблицаДокументов
		|ГДЕ
		|	ТаблицаДокументов.ВСД.ТипВСД <> ЗНАЧЕНИЕ(Справочник.ТипыВСД.ПроизводственныйВСД)
		|	И ТаблицаДокументов.ВСД.ТипДокумента <> ЗНАЧЕНИЕ(Справочник.ТипыДокументов.БумажныйДокумент)";
		
	РезультатЗапроса = Запрос.Выполнить();
	
	АдресаПечатныхФорм = Новый Соответствие;
	Выборка = РезультатЗапроса.Выбрать();
	Пока Выборка.Следующий() Цикл
		АдресПечатнойФормы = ИнтеграцияВетисAPIОбработкаПартий.ПолучитьФайлВетСправки(Выборка.ВСД);
		СтрокаСообщенияОбОшибке = НСтр("ru = 'Ошибка получения файла для документа: %1. %2'");
		Если АдресПечатнойФормы = Неопределено Тогда
			СтрокаСообщенияОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(СтрокаСообщенияОбОшибке, Выборка.ПредставлениеДокумента);
			ОбщегоНазначенияКлиентСервер.СообщитьПользователю(СтрокаСообщенияОбОшибке);
		ИначеЕсли АдресПечатнойФормы.Свойство("СообщениеОбОшибке") Тогда
			СтрокаСообщенияОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(СтрокаСообщенияОбОшибке, Выборка.ПредставлениеДокумента, АдресПечатнойФормы.СообщениеОбОшибке);
			ОбщегоНазначенияКлиентСервер.СообщитьПользователю(СтрокаСообщенияОбОшибке);
		Иначе
			АдресаПечатныхФорм.Вставить("ВСД " + Выборка.GUID_Меркурий, АдресПечатнойФормы.Путь);
		КонецЕсли;
	КонецЦикла;
	
	Возврат АдресаПечатныхФорм;
КонецФункции