Не отображается заголовок параметра СКД с типом "Стандартный период

1. Pyryrym 27.06.22 15:26 Сейчас в теме
В СКД создаю на вкладке "параметры" параметр, устанавливаю там заголовок, также на устанавливаю заголовок на вкладке настройки - параметры, но в шапке отчете выводится поле периода без периода. В режиме отладки у параметра заголовок указан. Подскажите, пожалуйста, почему заголовок может не выводиться.
По теме из базы знаний
Найденные решения
6. petleon 6 27.06.22 16:47 Сейчас в теме
(5) возможно кэш остался... Также можно проверить вкладку Другие настройки...
Еще как вариант может форма стандартная иметь похожий реквизит... Попробуйте переименовать параметр, например в ПериодОтчета...
14. Pyryrym 28.06.22 10:14 Сейчас в теме
(13) В общем, проблема с формой отчета была. Поскольку в моем ее не было, а конфигурация на БСП, отчет брал общую форму, где была настройка с заголовком
Остальные ответы
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
2. petleon 6 27.06.22 16:11 Сейчас в теме
(1)скриншоты в студию, пожалуйста, а то ничего не понятно
3. Pyryrym 27.06.22 16:24 Сейчас в теме
(2) Вот, заголовок указан везде, но в шапке не выводится
Прикрепленные файлы:
4. petleon 6 27.06.22 16:30 Сейчас в теме
(3) На вкладке Параметры достаточно указать заголовок, а в остальных местах убрать: очистить Представление у пользовательской настройки элемента, очистить в настройках отчета заголовок для параметра Период.
5. Pyryrym 27.06.22 16:37 Сейчас в теме
(4) везде убрал, кроме вкладки Параметры, заголовок не появился
7. spacecraft 27.06.22 16:50 Сейчас в теме
(1) возможна ошибка кэширования по имени отчета.
Дайте отчету другое название. Если это внешний отчет, то заменить имя и синоним.
8. Pyryrym 27.06.22 16:56 Сейчас в теме
(6)
(7)

Сделал новый внешний отчет, где назвал период Б, только простой запрос остался. Не выводится
9. petleon 6 27.06.22 17:01 Сейчас в теме
(8) мистика... киньте сюда *.erf- файл
12. Pyryrym 27.06.22 17:03 Сейчас в теме
(9) Кидаю
Прикрепленные файлы:
Тест.erf
13. petleon 6 28.06.22 08:11 Сейчас в теме
(12) у меня параметр отображается... попробуйте залить его во внешние обработки.
14. Pyryrym 28.06.22 10:14 Сейчас в теме
(13) В общем, проблема с формой отчета была. Поскольку в моем ее не было, а конфигурация на БСП, отчет брал общую форму, где была настройка с заголовком
16. petleon 6 28.06.22 10:48 Сейчас в теме
(14) как я и говорил в (6)...
17. Pyryrym 28.06.22 10:52 Сейчас в теме
(16) Да, я просто тогда не понял, а переименование ни к чему не привело.
10. spacecraft 27.06.22 17:02 Сейчас в теме
(8) тогда кеш чистить нужно.
11. Pyryrym 27.06.22 17:02 Сейчас в теме
15. Sashares 34 28.06.22 10:18 Сейчас в теме
(1)А в форме отчета включен вывод заголовков?
Прикрепленные файлы:
6. petleon 6 27.06.22 16:47 Сейчас в теме
(5) возможно кэш остался... Также можно проверить вкладку Другие настройки...
Еще как вариант может форма стандартная иметь похожий реквизит... Попробуйте переименовать параметр, например в ПериодОтчета...
18. Ankare 91 28.04.23 12:57 Сейчас в теме
Не претендую на последнюю инстанцию, но поделюсь опытом как решил задачу вывода заголовков стандартных периодов на БСПшную форму отчета на УТ 11.4.14.181

подмена процедуры "ВывестиПериодыНастроек" общего модуля "ОтчетыСервер"

&ИзменениеИКонтроль("ВывестиПериодыНастроек")
Процедура Лот_ВывестиПериодыНастроек(Форма, ЭлементыНастроек, ИменаРеквизитов)
	НайденныеЭлементы = ЭлементыНастроек.НайтиСтроки(Новый Структура("ЭтоПериод, СвойствоНастройки", Истина, "Значение"));
	Если НайденныеЭлементы.Количество() = 0 Тогда 
		Возврат;
	КонецЕсли;

	Элементы = Форма.Элементы;
	ИменаРеквизитовПредопределенных = ИменаРеквизитов.Предопределенных.Период;

	ВариантПредставления = Форма.НастройкиОтчета.ВариантПредставленияПериода;
	ЭтоСтандартноеПредставление = (ВариантПредставления = Перечисления.ВариантыПредставленияПериода.Стандартный);

	Для Каждого Элемент Из НайденныеЭлементы Цикл 
		СвязанныеЭлементы = ЭлементыНастроек.НайтиСтроки(Новый Структура("ИндексНастройки", Элемент.ИндексНастройки));
		Для Каждого СвязанныйЭлемент Из СвязанныеЭлементы Цикл 
			СвязанныйЭлемент.Поле.Видимость = (СвязанныйЭлемент.СвойствоНастройки = "Использование");
		КонецЦикла;

		Период = ИнициализироватьПериод(Форма, Элемент.ИндексНастройки);

		Поле = Элемент.Поле;
		Родитель = Поле.Родитель; // ГруппаФормы

		СледующийЭлемент = Неопределено;
		ИндексЭлемента = Родитель.ПодчиненныеЭлементы.Индекс(Поле);
		Если Родитель.ПодчиненныеЭлементы.Количество() > ИндексЭлемента + 1 Тогда 
			СледующийЭлемент = Родитель.ПодчиненныеЭлементы.Получить(ИндексЭлемента + 1);
		КонецЕсли;

		ИмяРеквизита = Форма.ПутьКДаннымЭлементов.ПоИндексу[Элемент.ИндексНастройки];
		Если ИменаРеквизитовПредопределенных.Найти(ИмяРеквизита) <> Неопределено Тогда 
			НайденныйЭлемент = Элементы.Найти(ИмяРеквизита);
			Элементы.Переместить(НайденныйЭлемент, Родитель, СледующийЭлемент);
			НайденныйЭлемент.Видимость = Истина;

			Для Каждого ЭлементПериода Из НайденныйЭлемент.ПодчиненныеЭлементы Цикл 
				ТипЭлементаПериода = ТипЗнч(ЭлементПериода);

				Если ТипЭлементаПериода = Тип("ПолеФормы") Тогда 
					ЭлементПериода.Заголовок = ЗаголовокЭлементаПериода(ЭлементПериода.Имя, Поле.Заголовок);
					ЭлементПериода.Подсказка = ЭлементПериода.Заголовок;
					ЭлементПериода.ПодсказкаВвода = ЭлементПериода.Заголовок;
#Вставка
					Если НЕ СтрНайти(ЭлементПериода.Имя, "ДатаНачала") = 0 Тогда 
						ЭлементПериода.Заголовок = Поле.Заголовок;
						ЭлементПериода.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Авто;
					КонецЕсли;
#КонецВставки
				КонецЕсли;

				Если ЭтоСтандартноеПредставление Тогда 
					ЭлементПериода.Видимость = ТипЭлементаПериода <> Тип("КнопкаФормы")
					Или (ТипЭлементаПериода = Тип("КнопкаФормы")
					И СтрНачинаетсяС(ЭлементПериода.ИмяКоманды, "ВыбратьПериод"));
				Иначе
					ЭлементПериода.Видимость = (ТипЭлементаПериода = Тип("КнопкаФормы")
					Или ТипЭлементаПериода = Тип("ГруппаФормы"));
				КонецЕсли;

				УстановитьСвойстваКнопкиВыбораПериода(ЭлементПериода, Период, ЭтоСтандартноеПредставление);

			КонецЦикла;

			Продолжить;
		КонецЕсли;

		ШаблонИмениЭлемента = СтрЗаменить(Поле.Имя, "Значение", "%1%2");

		Группа = ГруппаЭлементовПериода(Элементы, Родитель, СледующийЭлемент, ШаблонИмениЭлемента, Поле.Заголовок);

		ДобавитьКомандуСдвигаПериода(Форма, Группа, ШаблонИмениЭлемента, ЭтоСтандартноеПредставление, -1);
		ДобавитьПолеПериода(Элементы, Группа, ШаблонИмениЭлемента, "ДатаНачала", Поле.Заголовок, ЭтоСтандартноеПредставление);

		ИмяЭлемента = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ШаблонИмениЭлемента, "Разделитель");
		Разделитель = Элементы.Найти(ИмяЭлемента);
		Если Разделитель = Неопределено Тогда 
			Разделитель = Элементы.Добавить(ИмяЭлемента, Тип("ДекорацияФормы"), Группа);
		КонецЕсли;
		Разделитель.Вид = ВидДекорацииФормы.Надпись;
		Разделитель.Заголовок = Символ(8211); // Среднее тире (en dash).
		Разделитель.Видимость = ЭтоСтандартноеПредставление;

		ДобавитьПолеПериода(Элементы, Группа, ШаблонИмениЭлемента, "ДатаОкончания", Поле.Заголовок, ЭтоСтандартноеПредставление);
		ДобавитьКомандуВыбораПериода(Форма, Группа, ШаблонИмениЭлемента, Период, ЭтоСтандартноеПредставление);
		ДобавитьКомандуСдвигаПериода(Форма, Группа, ШаблонИмениЭлемента, ЭтоСтандартноеПредставление);
	КонецЦикла;
КонецПроцедуры
Показать
Прикрепленные файлы:
wolfalan; user1707828; RomanIvanov; user1559729; osin_d79@mail.ru; asid; +6 Ответить
19. medm 39 16.06.23 17:30 Сейчас в теме
Коллеги. Если кому-то еще актуально я сделал по-другому.
У меня внешний отчет.
В модуле объекта в параметрах регистрации делаем определяю
ПараметрыРегистрации.ОпределитьНастройкиФормы = Истина;


А дальше:
Процедура ОпределитьНастройкиФормы(Форма, КлючВарианта, Настройки) Экспорт
	
	Настройки.События.Вставить("ПослеЗаполненияПанелиБыстрыхНастроек", Истина);
	
КонецПроцедуры

// Параметры:
//   Форма - ФормаКлиентскогоПриложения
//   ПараметрыЗаполнения - Структура
//
Процедура ПослеЗаполненияПанелиБыстрыхНастроек(Форма, ПараметрыЗаполнения) Экспорт
	
	Для каждого ТекЭлемент Из Форма.Элементы Цикл
		
		Если НЕ СтрНайти(ТекЭлемент.Имя, "ДатаНачала") = 0 
			И ОбщегоНазначенияКлиентСервер.ЕстьРеквизитИлиСвойствоОбъекта(ТекЭлемент, "ПоложениеЗаголовка") Тогда
			ТекЭлемент.Заголовок = СтрЗаменить(ТекЭлемент.Заголовок, "(дата начала)", "");
			ТекЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Авто;
		КонецЕсли;
		
	КонецЦикла;
	
КонецПроцедуры
Показать
vladir; kyrasol; user1050439; kpdozer; SkAt91; soulu; _Farsh_; RomanIvanov; asg.aleks; Aleasoft; Hatson; twiny; alex.nakhabov; Pyryrym; +14 Ответить
20. SkAt91 19.10.23 15:42 Сейчас в теме
(19) Спасибо, долго искал это решение!
21. user1050439 7 30.11.23 12:04 Сейчас в теме
22. user870613 11.12.23 22:02 Сейчас в теме
(19) Вот это круто! Спасибо!
Оставьте свое сообщение
Вакансии
Программист 1С
Москва
зарплата от 180 000 руб. до 220 000 руб.
Полный день

Аналитик 1С / Бизнес-аналитик
Нижний Новгород
зарплата от 100 000 руб. до 250 000 руб.
Временный (на проект)

Программист 1С
Москва
зарплата от 250 000 руб.
Полный день

Программист 1C
Волгоград
зарплата от 200 000 руб.
Полный день

Аналитик
Санкт-Петербург
зарплата от 200 000 руб. до 250 000 руб.
Полный день