Добавить внешнюю печатную форму в обработку

Question

Добрый день, в УТ есть обработка "УправлениеПоступлением" в ней присутствует стандартная кнопка печати для документов "Приходный ордер на товары", которые расположены в динамическом списке "ОрдераВРаботе", мне нужно чтобы в списке выбора печати в обработке "УправлениеПоступлением" была видна моя внешняя печатная форма, каким образом можно её добавить? Для самого документа я добавил внешнюю печатную форму, форме списка и документа всё работает

Accepted Answer

(1)Я сделал через расширение, в модуле менеджера обработки "УправлениеПоступлением" в процедуре "ДобавитьКомандыПечати" добавил свою команду печати
[CODE]
&После("ДобавитьКомандыПечати")
Процедура Расш1_ДобавитьКомандыПечати(КомандыПечати)
	
	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.МенеджерПечати = "Документ.ПриходныйОрдерНаТовары";
	КомандаПечати.Идентификатор = "ЗаданиеНаОтборРазмещение";
	КомандаПечати.Представление = НСтр("ru = 'Задание на отбор'");
	КомандаПечати.ПроверкаПроведенияПередПечатью = Истина;
	КомандаПечати.МестоРазмещения = "ПодменюПечать";
	ТипыОбъектовПечати = Новый Массив;
	ТипыОбъектовПечати.Добавить(Тип("ДокументСсылка.ПриходныйОрдерНаТовары"));
	КомандаПечати.ТипыОбъектовПечати = ТипыОбъектовПечати;
	
КонецПроцедуры
[/CODE]
далее в модуле менеджера документа "ПриходныйОрдерНаТовары" в процедуре "Печать" добавил следующий код
[CODE]
&После("Печать")
Процедура Расш1_Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода)
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "ЗаданиеНаОтборРазмещение") Тогда
		
		ВнешняяОбработка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию("Задание на отбор");
		Если ВнешняяОбработка.Пустая() Тогда
			УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
				КоллекцияПечатныхФорм,
				"ЗаданиеНаОтборРазмещение",
				НСтр("ru = 'Задание на отбор"),
				Новый ТабличныйДокумент);
			Возврат;
		КонецЕсли;
		
		ДвоичныеДанные = ВнешняяОбработка.ХранилищеОбработки.Получить();
		ИмяФайла = ПолучитьИмяВременногоФайла("epf");
		ДвоичныеДанные.Записать(ИмяФайла);
		ВнешняяОбработка = ВнешниеОбработки.Создать(ИмяФайла, Ложь);
		
		ТабДок = ВнешняяОбработка.СформироватьПечатнуюФорму(МассивОбъектов, ОбъектыПечати);
		
		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
			КоллекцияПечатныхФорм,
			"ЗаданиеНаОтборРазмещение",
			НСтр("ru = 'Задание на отбор'"),
			ТабДок);
	КонецЕсли;
	
КонецПроцедуры
[/CODE]
После этого всё заработало.