Как открыть форму внешней обработки из справочника "Внешние обработки"?

Функция ОткрытьВнешнююОбработкуПоКоду(Имя, Параметр = Неопределено) Экспорт
	ВыбраннаяСтрока = Справочники.ВнешниеОбработки.НайтиПоКоду(Имя);
	Если Не ЗначениеЗаполнено(ВыбраннаяСтрока) тогда
		Возврат Неопределено;
	КонецЕсли;
	ЭтоОбработка = ВыбраннаяСтрока.ВидОбработки = Перечисления.ВидыДополнительныхВнешнихОбработок.Обработка;
	ЭтоОтчет = ВыбраннаяСтрока.ВидОбработки = Перечисления.ВидыДополнительныхВнешнихОбработок.Отчет;
	Если НЕ (ЭтоОбработка ИЛИ ЭтоОтчет) Тогда
		Возврат Неопределено;
	КонецЕсли;
	Попытка
		ИмяФайла = ПолучитьИмяВременногоФайла();
		ДвоичныеДанные = ВыбраннаяСтрока.ХранилищеВнешнейОбработки.Получить();
		ДвоичныеДанные.Записать(ИмяФайла);
		Если ЭтоОбработка Тогда
			Форма = ВнешниеОбработки.ПолучитьФорму(ИмяФайла);
		Иначе
			Форма = ВнешниеОтчеты.ПолучитьФорму(ИмяФайла);
		КонецЕсли;
		Если Форма <> Неопределено Тогда
			Попытка
				Форма.Параметр = Параметр;
			Исключение
			КонецПопытки;
			Форма.Открыть();
		КонецЕсли;
		Попытка
			УдалитьФайлы(ИмяФайла);
		Исключение
		КонецПопытки;	
		Возврат Форма;
	Исключение
	КонецПопытки;
КонецФункции