Как определить кодировку в текстовом файле (имея в наличии только файл)?

Функция ОпределитьКодировкуФайла(ПутьКФайлу) Экспорт 
	мКодировок=Новый Массив;
	мКодировок.Добавить(КодировкаТекста.ANSI);
	мКодировок.Добавить(КодировкаТекста.OEM);
	мКодировок.Добавить(КодировкаТекста.UTF16);
	мКодировок.Добавить(КодировкаТекста.UTF8);	
	мНайденных=Новый Массив;
	Для каждого рКодировка Из мКодировок Цикл
		т=Новый ТекстовыйДокумент;
		т.Прочитать(ПутьКФайлу,рКодировка);
		стро=ВРег(т.ПолучитьТекст()); // ВРег это важно
		Если НЕ НайтиСимволыВнеДиапазона(стро) Тогда
			// если не найдено ни одного "битого" символа - искомая кодировка
			Возврат рКодировка;
		КонецЕсли;		
	КонецЦикла;
	Возврат КодировкаТекста.ANSI; // по умолчанию	
КонецФункции

Функция НайтиСимволыВнеДиапазона(ТекСтрока) 
	Для Поз = 1 По СтрДлина(ТекСтрока) Цикл
		ТекКод = КодСимвола(Сред(ТекСтрока, Поз, 1));
		Если (ТекКод  > 100 // до 100 разные знаки типа % - " и т.д.
			И ТекКод < 1040 // 1040  код символа А
			И НЕ ТекКод = 1025)  // 1025 код символа Ё (вне диапазона заглавных букв А-Я 1040-1071)
			ИЛИ ТекКод > 1071// 1071 код символа Я
			Тогда
			Возврат Истина;
		КонецЕсли; 
	КонецЦикла;
	Возврат Ложь;	
КонецФункции

// Возвращает наиболее подходящую кодировку текста, полученную путем сравнения с алфавитом.
//
// Параметры:
//  ДанныеТекста - ДвоичныеДанные - двоичные данные файла.
//
// Возвращаемое значение:
//  Строка - кодировка файла.
//
Функция КодировкаИзСоответствияАлфавиту(ДанныеТекста)
	
	Кодировки = РаботаСФайламиСлужебный.Кодировки();
	Кодировки.Удалить(Кодировки.НайтиПоЗначению("utf-8_WithoutBOM"));
	
	КодировкаKOI8R = Кодировки.НайтиПоЗначению("koi8-r");
	Кодировки.Сдвинуть(КодировкаKOI8R, -Кодировки.Индекс(КодировкаKOI8R));
	
	КодировкаWin1251 = Кодировки.НайтиПоЗначению("windows-1251");
	Кодировки.Сдвинуть(КодировкаWin1251, -Кодировки.Индекс(КодировкаWin1251));
	
	КодировкаUTF8 = Кодировки.НайтиПоЗначению("utf-8");
	Кодировки.Сдвинуть(КодировкаUTF8, -Кодировки.Индекс(КодировкаUTF8));
	
	СоответствующаяКодировка = "";
	МаксимальноеСоответствиеКодировки = 0;
	Для Каждого Кодировка Из Кодировки Цикл
		
		СоответствиеКодировки = ПроцентСоответствияАлфавиту(ДанныеТекста, Кодировка.Значение);
		Если СоответствиеКодировки > 0.95 Тогда
			Возврат Кодировка.Значение;
		КонецЕсли;
		
		Если СоответствиеКодировки > МаксимальноеСоответствиеКодировки Тогда
			СоответствующаяКодировка = Кодировка.Значение;
			МаксимальноеСоответствиеКодировки = СоответствиеКодировки;
		КонецЕсли;
		
	КонецЦикла;
	
	Возврат СоответствующаяКодировка;
	
КонецФункции

Функция ПроцентСоответствияАлфавиту(ДвоичныеДанные, ПроверяемаяКодировка)
	
	// АПК:1036-выкл, АПК:163-выкл - алфавит не требует проверки орфографии.
	Алфавит = "АаБбВвГгДдЕеЁёЖжЗзИиЙйКкЛлМмНнОоПпРрСсТтУуФфХхЦцЧчШшЩщЪъЫыЬ­ьЭэЮюЯя"
		+ "AaBbCcDdEeFfGgHhIiJjKkLlMmNnOoPpQqRrSsTtUuVvWwXxYyZz"
		+ "1234567890 ";
	// АПК:1036-вкл, АПК:163-вкл
	
	ПотокАлфавита = Новый ПотокВПамяти();
	ЗаписьАлфавита = Новый ЗаписьДанных(ПотокАлфавита);
	ЗаписьАлфавита.ЗаписатьСтроку(Алфавит, ПроверяемаяКодировка);
	ЗаписьАлфавита.Закрыть();
	
	ДанныеАлфавита = ПотокАлфавита.ЗакрытьИПолучитьДвоичныеДанные();
	ЧтениеДанныхАлфавита = Новый ЧтениеДанных(ДанныеАлфавита);
	БуферАлфавитаВКодировке = ЧтениеДанныхАлфавита.ПрочитатьВБуферДвоичныхДанных();
	
	Индекс = 0;
	СимволыАлфавита = Новый Массив;
	Пока Индекс <= БуферАлфавитаВКодировке.Размер - 1 Цикл
		
		ТекущийСимвол = БуферАлфавитаВКодировке[Индекс];
		
		// Символы кириллицы в кодировке UTF-8 - двухбайтовые.
		Если ПроверяемаяКодировка = "utf-8"
			И (ТекущийСимвол = 208
			Или ТекущийСимвол = 209) Тогда
			
			Индекс = Индекс + 1;
			ТекущийСимвол = Формат(ТекущийСимвол, "ЧН=0; ЧГ=") + Формат(БуферАлфавитаВКодировке[Индекс], "ЧН=0; ЧГ=");
		КонецЕсли;
		
		Индекс = Индекс + 1;
		СимволыАлфавита.Добавить(ТекущийСимвол);
		
	КонецЦикла;
	
	ЧтениеДанныхТекста = Новый ЧтениеДанных(ДвоичныеДанные);
	БуферДанныхТекста = ЧтениеДанныхТекста.ПрочитатьВБуферДвоичныхДанных(?(ПроверяемаяКодировка = "utf-8", 200, 100));
	РазмерБуфераТекста = БуферДанныхТекста.Размер;
	КоличествоСимволов = РазмерБуфераТекста;
	
	Индекс = 0;
	КоличествоВхождений = 0;
	Пока Индекс <= РазмерБуфераТекста - 1 Цикл
		
		ТекущийСимвол = БуферДанныхТекста[Индекс];
		Если ПроверяемаяКодировка = "utf-8"
			И (ТекущийСимвол = 208
			Или ТекущийСимвол = 209) Тогда
			
			// Если последний байт в буфере является первым байтом двухбайтового символа, игнорируем его.
			Если Индекс = РазмерБуфераТекста - 1 Тогда
				Прервать;
			КонецЕсли;
			
			Индекс = Индекс + 1;
			КоличествоСимволов = КоличествоСимволов - 1;
			ТекущийСимвол = Формат(ТекущийСимвол, "ЧН=0; ЧГ=") + Формат(БуферДанныхТекста[Индекс], "ЧН=0; ЧГ=");
			
		КонецЕсли;
		
		Индекс = Индекс + 1;
		Если СимволыАлфавита.Найти(ТекущийСимвол) <> Неопределено Тогда
			КоличествоВхождений = КоличествоВхождений + 1;
		КонецЕсли;
		
	КонецЦикла;
	
	Возврат ?(КоличествоСимволов = 0, 100, КоличествоВхождений/КоличествоСимволов);
	
КонецФункции

Функция ПолучитьТекстВПравильнойКодировке(ПутьКФайлу) Экспорт 
	ТабКодировок = Новый ТаблицаЗначений;
	ТабКодировок.Колонки.Добавить("Кодировка");
	ТабКодировок.Колонки.Добавить("КоличествоОтклонений",Новый ОписаниеТипов("Число"));
	ТабКодировок.Добавить().Кодировка = КодировкаТекста.ANSI;
    ТабКодировок.Добавить().Кодировка = КодировкаТекста.OEM;
    ТабКодировок.Добавить().Кодировка = КодировкаТекста.UTF16;
    ТабКодировок.Добавить().Кодировка = КодировкаТекста.UTF8;
    ТабКодировок.Добавить().Кодировка = КодировкаТекста.Системная;
    ТабКодировок.Добавить().Кодировка = "windows-1251";
    ТабКодировок.Добавить().Кодировка = "KOI8-R";
    ТабКодировок.Добавить().Кодировка = "cp866";
    ТабКодировок.Добавить().Кодировка = "x-mac-cyrillic";
	Док=Новый ТекстовыйДокумент;
	Для каждого тКодировка Из ТабКодировок Цикл
        Док.Прочитать(ПутьКФайлу,тКодировка.Кодировка);
		тТекст = Док.ПолучитьТекст();
		Найдено = СтрНайтиПоРегулярномуВыражению(тТекст,"[^A-Za-zA-Яа-я0-9\!""#$%&'\(\)*+-.\/\:\;<=>\?@\[\\\]^_\`\{\|\}\~№@\s\n\t]",,,1); //Ищем первое вхождение символа не из диапазона правильных
		Если Найдено.НачальнаяПозиция Тогда //если нашли то считаем количество таких отклонений
			Пока Найдено.НачальнаяПозиция Цикл
				тКодировка.КоличествоОтклонений = тКодировка.КоличествоОтклонений + 1;
				Найдено = СтрНайтиПоРегулярномуВыражению(тТекст,"[^A-Za-zA-Яа-я0-9\!""#$%&'\(\)*+-.\/\:\;<=>\?@\[\\\]^_\`\{\|\}\~№@\s\n\t]",,Найдено.НачальнаяПозиция+Найдено.Длина);
			КонецЦикла;
		Иначе //если не нашли то возвращаем текст в правильной кодировке
			Возврат тТекст;
		КонецЕсли;
	КонецЦикла;
	ТабКодировок.Сортировать("КоличествоОтклонений");//Сортируем таблицу по количеству отклонений
	Док.Прочитать(ПутьКФайлу,ТабКодировок[0].Кодировка);//и там где меньше отклонений считаем правильной
	Возврат Док.ПолучитьТекст();
КонецФункции