Подзапрос в конструкции ВЫБОР в запросе

Форум Программирование Общие вопросы программирования (Dev)

1С:Бухгалтерия 3.0 Платформа 1С v8.3 Запросы

1. 300_po_vstrechke 1498 29.12.21 11:14 Сейчас в теме

Добрейшего времени суток камрады.
Возможно ли построить следующую конструкцию в запросе:

ВЫБОР
	КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ПоступлениеТоваровУслуг)
		ТОГДА ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор.СпособОтраженияРасходовПоАмортизации
	КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ПоступлениеВАренду)
		ТОГДА ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор.СпособОтраженияРасходовПоАмортизации
	КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ВводНачальныхОстатков)
		ТОГДА (ВЫБРАТЬ
					ВводНачальныхОстатковОС.СпособОтраженияРасходовПоАмортизации 
				ИЗ
					Документ.ВводНачальныхОстатков.ОС КАК ВводНачальныхОстатковОС
				ГДЕ
					ВводНачальныхОстатковОС.Ссылка = ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор
					И ВводНачальныхОстатковОС.ОсновноеСредство = ПервоначальныеСведенияОСБухгалтерскийУчет.ОсновноеСредство)
КОНЕЦ

Показать

У меня вылетает ошибка. Хелп. БП 8.3

По теме из базы знаний

Вознаграждение за ответ

Сумма: 0 $m

Добавили:
300_po_vstrechke (1.31 $m)

Получили:

Sashares (1 $m), ImHunter (0.31 $m)

Показать полностью

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. Sashares 34 29.12.21 11:17 Сейчас в теме +1 $m

(1)Нет конечно.
Значение оператора Выбор это значение какого-то одного поля в условной строке условной таблицы.
Вы же в одно поле выборку пытаетесь засунуть.

П.С. Даже если вы сравнили поле составного типа с определенным типом, при получении реквизитов от него стоит использовать Выразить.

3. 300_po_vstrechke 1498 29.12.21 11:20 Сейчас в теме

(2)

Вы же в одно поле выборку пытаетесь засунуть.

Чисто теоретически поставить ПЕРВЫЕ 1? (попробовал не помогло)

4. Sashares 34 29.12.21 11:22 Сейчас в теме

(3)Нет.
Выполнить левое соединение с документом ввода остатков и взять значение из этой таблицы.

7. 300_po_vstrechke 1498 29.12.21 12:40 Сейчас в теме

(2)

определенным типом, при получени

Не сразу понял про выразить.
Всем спасибо.
Итог:

ВЫБРАТЬ
	ВводНачальныхОстатковОС.Ссылка КАК Ссылка,
	ВводНачальныхОстатковОС.ОсновноеСредство КАК ОсновноеСредство,
	ВводНачальныхОстатковОС.СпособОтраженияРасходовПоАмортизации КАК СпособОтраженияРасходовПоАмортизации
ПОМЕСТИТЬ ВТ_ВводОстатков
ИЗ
	Документ.ВводНачальныхОстатков.ОС КАК ВводНачальныхОстатковОС
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор КАК Регистратор,
	ПервоначальныеСведенияОСБухгалтерскийУчет.ОсновноеСредство КАК ОсновноеСредство,
	ВЫБОР
		КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ПринятиеКУчетуОС)
			ТОГДА ВЫРАЗИТЬ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор КАК Документ.ПринятиеКУчетуОС).СпособыОтраженияРасходовПоАмортизации
		КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ПоступлениеВАренду)
			ТОГДА ВЫРАЗИТЬ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор КАК Документ.ПоступлениеВАренду).СпособОтраженияРасходовПоАмортизации
		КОГДА ТИПЗНАЧЕНИЯ(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор) = ТИП(Документ.ВводНачальныхОстатков)
			ТОГДА ВТ_ВводОстатков.СпособОтраженияРасходовПоАмортизации
	КОНЕЦ КАК СпособАмортизации
ИЗ
	РегистрСведений.ПервоначальныеСведенияОСБухгалтерскийУчет КАК ПервоначальныеСведенияОСБухгалтерскийУчет
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ВводОстатков КАК ВТ_ВводОстатков
		ПО ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор = ВТ_ВводОстатков.Ссылка
			И ПервоначальныеСведенияОСБухгалтерскийУчет.ОсновноеСредство = ВТ_ВводОстатков.ОсновноеСредство

Показать

5. ImHunter 315 29.12.21 12:02 Сейчас в теме +0.31 $m

КОГДА ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор ссылка Документ.ПоступлениеТоваровУслуг
ТОГДА выразить(ПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор как Документ.ПоступлениеТоваровУслуг).СпособОтраженияРасходовПоАмортизации

6. 300_po_vstrechke 1498 29.12.21 12:21 Сейчас в теме

(5) Да, спасибо, что поправили.

Оставьте свое сообщение

E-mail: