Старнная работа ПОЛНОГО СОЕДИНЕНИЯ в запросе.

Question

Уважаемы форумчане. Помогите решить вопрос.
Платформа: 1С:Предприятие 8.3 (8.3.18.1334)
Конфигурация: Бухгалтерия предприятия, редакция 3.0 (3.0.102.11)
Решил написать простенький отчет по документу Путевой лист (не кидаться в меня сразу тухлыми помидорами, знаю что плохо делать запрос к документам, но тут надо было).
Делаю запрос к двум ТЧ в этом документе и связываю ПОЛНЫМ СОЕДИНЕНИЕМ.

ВЫБРАТЬ
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.Дата, ПутевойЛистМаршрут.Ссылка.Дата) КАК Дата,
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка, ПутевойЛистМаршрут.Ссылка) КАК ПутевойЛист,
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ТранспортноеСредство, ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство) КАК ТранспортноеСредство,
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ФизЛицо, ПутевойЛистМаршрут.Ссылка.ФизЛицо) КАК Сотрудник,
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ТранспортноеСредство.НормаРасхода, ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство.НормаРасхода) КАК НормаРасхода,
	СУММА(ПутевойЛистТопливо.Количество) КАК Количество,
	СУММА(ПутевойЛистМаршрут.Расстояние) КАК Расстояние,
	СУММА(ПутевойЛистМаршрут.Расход) КАК Расход
ИЗ
	Документ.ПутевойЛист.Маршрут КАК ПутевойЛистМаршрут
		ПОЛНОЕ СОЕДИНЕНИЕ Документ.ПутевойЛист.Топливо КАК ПутевойЛистТопливо
		ПО ПутевойЛистМаршрут.Ссылка = ПутевойЛистТопливо.Ссылка
ГДЕ
	ПутевойЛистМаршрут.Ссылка.Проведен
	И ПутевойЛистТопливо.Ссылка.Проведен
	И ПутевойЛистМаршрут.Ссылка.Дата >= &ДатаНач
	И ПутевойЛистМаршрут.Ссылка.Дата <= &ДатаКон
	И ПутевойЛистТопливо.Ссылка.Дата >= &ДатаНач
	И ПутевойЛистТопливо.Ссылка.Дата <= &ДатаКон

СГРУППИРОВАТЬ ПО
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.Дата, ПутевойЛистМаршрут.Ссылка.Дата),
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка, ПутевойЛистМаршрут.Ссылка),
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ТранспортноеСредство, ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство),
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ФизЛицо, ПутевойЛистМаршрут.Ссылка.ФизЛицо),
	ЕСТЬNULL(ПутевойЛистТопливо.Ссылка.ТранспортноеСредство.НормаРасхода, ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство.НормаРасхода)

УПОРЯДОЧИТЬ ПО
	Дата

Показать

Так вот выдает мне данный запрос не все нужные документы, а только те, в которых заполнена ТЧ Топливо. Если же ТЧ топливо не заполнено, а ТЧ Маршрут имеет значения - такой документ в выборку не попадает.

Переписал запрос через временные таблицы. Получилось вот так:

ВЫБРАТЬ
	ПутевойЛистТопливо.Ссылка.Дата КАК Дата,
	ПутевойЛистТопливо.Ссылка КАК Ссылка,
	ПутевойЛистТопливо.Ссылка.ТранспортноеСредство КАК ТранспортноеСредство,
	ПутевойЛистТопливо.Ссылка.ФизЛицо КАК ФизЛицо,
	ПутевойЛистТопливо.Ссылка.НормаРасхода КАК НормаРасхода,
	СУММА(ПутевойЛистТопливо.Количество) КАК Количество
ПОМЕСТИТЬ вт_Топливо
ИЗ
	Документ.ПутевойЛист.Топливо КАК ПутевойЛистТопливо
ГДЕ
	ПутевойЛистТопливо.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон
	И ПутевойЛистТопливо.Ссылка.ФизЛицо = &ФизЛицо
	И ПутевойЛистТопливо.Ссылка.Проведен

СГРУППИРОВАТЬ ПО
	ПутевойЛистТопливо.Ссылка.Дата,
	ПутевойЛистТопливо.Ссылка,
	ПутевойЛистТопливо.Ссылка.ТранспортноеСредство,
	ПутевойЛистТопливо.Ссылка.ФизЛицо,
	ПутевойЛистТопливо.Ссылка.НормаРасхода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПутевойЛистМаршрут.Ссылка.Дата КАК Дата,
	ПутевойЛистМаршрут.Ссылка КАК Ссылка,
	ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство КАК ТранспортноеСредство,
	ПутевойЛистМаршрут.Ссылка.ФизЛицо КАК ФизЛицо,
	ПутевойЛистМаршрут.Ссылка.НормаРасхода КАК НормаРасхода,
	СУММА(ПутевойЛистМаршрут.Расстояние) КАК Расстояние,
	СУММА(ПутевойЛистМаршрут.Расход) КАК Расход
ПОМЕСТИТЬ вт_Маршрут
ИЗ
	Документ.ПутевойЛист.Маршрут КАК ПутевойЛистМаршрут
ГДЕ
	ПутевойЛистМаршрут.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон
	И ПутевойЛистМаршрут.Ссылка.ФизЛицо = &ФизЛицо
	И ПутевойЛистМаршрут.Ссылка.Проведен

СГРУППИРОВАТЬ ПО
	ПутевойЛистМаршрут.Ссылка.Дата,
	ПутевойЛистМаршрут.Ссылка,
	ПутевойЛистМаршрут.Ссылка.ТранспортноеСредство,
	ПутевойЛистМаршрут.Ссылка.ФизЛицо,
	ПутевойЛистМаршрут.Ссылка.НормаРасхода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ЕСТЬNULL(вт_Маршрут.Дата, вт_Топливо.Дата) КАК Дата,
	ЕСТЬNULL(вт_Маршрут.Ссылка, вт_Топливо.Ссылка) КАК Ссылка,
	ЕСТЬNULL(вт_Маршрут.ТранспортноеСредство, вт_Топливо.ТранспортноеСредство) КАК ТранспортноеСредство,
	ЕСТЬNULL(вт_Маршрут.ФизЛицо, вт_Топливо.ФизЛицо) КАК ФизЛицо,
	ЕСТЬNULL(вт_Маршрут.НормаРасхода, вт_Топливо.НормаРасхода) КАК НормаРасхода,
	вт_Маршрут.Расстояние КАК Расстояние,
	вт_Маршрут.Расход КАК Расход,
	вт_Топливо.Количество КАК Количество
ИЗ
	вт_Топливо КАК вт_Топливо
		ПОЛНОЕ СОЕДИНЕНИЕ вт_Маршрут КАК вт_Маршрут
		ПО (вт_Топливо.Ссылка = вт_Маршрут.Ссылка)

УПОРЯДОЧИТЬ ПО
	Дата

Показать

Второй запрос отрабатывает как надо.
Кстати в первом запросе не использовал для дат МЕЖДУ, т.к. тоже не отрабатывало, а надо было быстро не стал разбираться.

В итоге 2 вопроса:
1. Почему в первом запросе не работает ПОЛНОЕ СОЕДИНЕНИЕ?
2. Почему в первом запросе не работает оператор МЕЖДУ?

Accepted Answer

(1) из-за отбора в поле где, полное соединение превращается во внутреннее
и что бы этого не происходило, переделайте условия в такой вид:
[CODE]ЕстьNULL(ПутевойЛистМаршрут.Ссылка.Проведен,Истина)
И ЕстьNULL(ПутевойЛистТопливо.Ссылка.Проведен,Истина)
И ЕстьNULL(ПутевойЛистМаршрут.Ссылка.Дата,&ДатаНач) >= &ДатаНач
И ЕстьNULL(ПутевойЛистТопливо.Ссылка.Дата,&ДатаНач) >= &ДатаНач
// и т.д.[/CODE]
PS а т.к. у вас есть неявное соединение с справочником (дважды!), то лучше сделайте его явным (единожды!):[CODE]ИЗ
    Документ.ПутевойЛист как спр
        левое соединенние
    Документ.ПутевойЛист.Маршрут КАК ПутевойЛистМаршрут
        ПО ПутевойЛистМаршрут.Ссылка = спр.Ссылка
            левое СОЕДИНЕНИЕ
    Документ.ПутевойЛист.Топливо КАК ПутевойЛистТопливо
        ПО ПутевойЛистТопливо.Ссылка = спр.Ссылка
ГДЕ
    спр.Проведен
    И спр.Дата >= &ДатаНач
    И спр.Дата <= &ДатаКон
    и (ПутевойЛистМаршрут.Ссылка Есть НЕ NULL или ПутевойЛистТопливо.Ссылка Есть НЕ NULL)[/CODE]