Формирование списка значений с представлениями

Форум Программирование Общие вопросы программирования (Dev)

1С:Управление торговлей 11

1. Alexponenta 02.09.21 17:49 Сейчас в теме

Я понимаю как в список выбора просто добавить значения на основании запроса.

Но... просто значения не совсем информативно для конечного пользователя.

Например в список передаются цены, но без указания вида цены. Т.е. человек видит только числа, но не имеет понятия к какой цене данное значение принадлежит.

Как это правильно реализовать. Например как это сделано тут (картинка)

Прикрепленные файлы:

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. spacecraft 02.09.21 18:25 Сейчас в теме

(1) сформировать нужное представление в списке значений.
Как вариант:

&НаСервереБезКонтекста
Функция ТоварыЦенаПодобратьЦены(Номенклатура)
	СписокЦен = Новый СписокЗначений;
	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	ЦеныНоменклатурыСрезПоследних.ВидЦены.Представление КАК ВидЦеныПредставление,
		|	ЦеныНоменклатурыСрезПоследних.Цена КАК Цена
		|ИЗ
		|	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, Номенклатура = &Номенклатура) КАК ЦеныНоменклатурыСрезПоследних";
	
	Запрос.УстановитьПараметр("Номенклатура", Номенклатура);
	РезультатЗапроса = Запрос.Выполнить();
	Выборка = РезультатЗапроса.Выбрать();
	Пока Выборка.Следующий() Цикл
		СписокЦен.Добавить(Выборка.Цена, СтрШаблон("%1 руб.(%2)",Выборка.Цена,Выборка.ВидЦеныПредставление));
	КонецЦикла;
	Возврат СписокЦен;
КонецФункции

&НаКлиенте
Процедура ТоварыЦенаНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	ТекДанные = Элемент.Родитель.ТекущиеДанные;
	СписокЦен = ТоварыЦенаПодобратьЦены(ТекДанные.Номенклатура);
	Если СписокЦен.Количество() > 0 Тогда
		ДанныеВыбора = СписокЦен;
		СтандартнаяОбработка = Ложь;
	КонецЕсли;
КонецПроцедуры

Показать

Оставьте свое сообщение

E-mail: