Штрихкод в управляемой форме в толстом клиенте.

Question

Всем привет.
Есть старая УТ 10.3 , есть в ней пара документов у которых на управляемых формах ( ну просто их проще дизайнить... ) 
Вот в одном из новых доков, потребовалось сделать печать этикетки со штрихкодом. 
Думал , все по старинке сделаю, но встретил проблему. 

Как делалось
[1C-CODE]

&НаСервере
Функция ПечатьЭтикеткиНаСервере()
	
	Об = РеквизитФормыВЗначение("Объект");
	
	СтруктураВозврат = Новый Структура;
	СтруктураВозврат.Вставить("Успех", Истина);
	
	ПринтерДляПечати = МДО_ОбщийМодуль.ОпределитьПринтерДляПользователя(ПараметрыСеанса.ТекущийПользователь);
	Если ПринтерДляПечати = "" Тогда
		СтруктураВозврат.Успех = Ложь;
		СтруктураВозврат.Вставить("Ошибка","Не задан принтер");
		Возврат СтруктураВозврат;
	КонецЕсли;
	
	Макет = Об.ПолучитьМакет("Этикетка");
	
	ТабДокумент = Новый ТабличныйДокумент;
	ТабДокумент.ВысотаСтраницы	=	370;
	ТабДокумент.ШиринаСтраницы	=	570;
	ТабДокумент.ПолеСверху 		= 	0;
	ТабДокумент.ПолеСправа 		= 	0;
	ТабДокумент.ПолеСнизу 		= 	0;
	ТабДокумент.ПолеСлева 		= 	0;
	ТабДокумент.АвтоМасштаб 	= 	Истина;
	ТабДокумент.ИмяПринтера		=	ПринтерДляПечати;
	ТабДокумент.ВерхнийКолонтитул.Выводить	=	Ложь;
	ТабДокумент.НижнийКолонтитул.Выводить	=	Ложь;
	  	
	Область = 	Макет.ПолучитьОбласть("Этикетка");	
	Для Каждого Товар из Объект.Товары Цикл
		Область.Параметры.Заполнить(Товар.Номенклатура);			
	КонецЦикла;
	
	КомпонентШК 			  =	Область.Рисунки.Штрихкод.Объект;
	КомпонентШК.ТипКода   	  = 4;
	КомпонентШК.АвтоТип   	  = Ложь;
	КомпонентШК.Сообщение     = Объект.Номер;
	ТабДокумент.Вывести(Область);
	
	ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц();
	
	СтруктураВозврат.Вставить("ТД",ТабДокумент);
	Возврат СтруктураВозврат;

КонецФункции

&НаКлиенте
Процедура ПечатьЭтикетки(Команда)
	
	Если Объект.Номер = "" Или Объект.Товары.Количество() = 0 Тогда
		ПоказатьОповещениеПользователя("Ошибка печати",,"Неверный номере или пустая таблица товаров");
		Возврат;
	КонецЕсли;
	
	Результат = ПечатьЭтикеткиНаСервере();
	Если НЕ Результат.успех Тогда
		ПоказатьОповещениеПользователя("Ошибка",,Результат.ошибка);
		Возврат;
	КонецЕсли;
	
	ТабДокумент = Результат.ТД;
	ТабДокумент.Показать();
	
КонецПроцедуры


[/1C-CODE]

Ну и разумеется ошибка начинается с этой части
[1C-CODE]
КомпонентШК 			  =	Область.Рисунки.Штрихкод.Объект;
КомпонентШК.ТипКода   	  = 4;
[/1C-CODE]
[IS-QUOTE]
{Документ.мд_Рекламация.Форма.ФормаДокумента.Форма(536)}: Значение не является значением объектного типа (ТипКода)
 КомпонентШК.ТипКода       = 4;
[/IS-QUOTE]

Прочел мега тону статей, понял, что в УФ это сделано через анус обезьяны и расстроился.
Теперь вопрос. Может кто делал такой изврат ... ? и поможет с кодом и компонентами для УТ...

Accepted Answer

(3)[CODE]Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт
	
	//Макет = ПолучитьМакет("КомпонентаПечатиШтрихкода");
	
	ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("ОбщийМакет.КомпонентаПечатиШтрихкода", "ШтрихКод", ТипВнешнейКомпоненты.Native);
	
	// Создадим объект внешней компоненты
	Если ПодключениеВыполнено Тогда
		ВнешняяКомпонента = Новый("AddIn.ШтрихКод.Barcode");
	Иначе
		Возврат Неопределено;
	КонецЕсли;
	
	// Если нет возможности рисовать
	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда
		// То картинку сформировать не сможем
		Возврат Неопределено;
	Иначе
		// Установим основные параметры компоненты
		// Если в системе установлен шрифт Tahoma
		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда
			// Выбираем его как шрифт для формирования картинки
			ВнешняяКомпонента.Шрифт = "Tahoma";
		Иначе
			// Шрифт Tahoma в системе отсутствует
			// Обойдем все доступные компоненте шрифты
			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл
				// Получим очередной шрифт, доступный компоненте
				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);
				// Если шрифт доступен
				Если ТекущийШрифт <> Неопределено Тогда
					// Они и будет шрифтом для формирования штри-кода
					ВнешняяКомпонента.Шрифт = ТекущийШрифт;
					Прервать;
				КонецЕсли;
			КонецЦикла;
		КонецЕсли;
		// Утановим размер шрифта
		ВнешняяКомпонента.РазмерШрифта = 12;
		
		Возврат ВнешняяКомпонента;
	КонецЕсли;
	
КонецФункции[/CODE]