Каким образом можно заблокировать пользователю доступ к настройке панели разделов?(типовая конфигурация БП)

// В корне расширения МодульПриложения
// Условия закомментруйте или пишите свою логику кому и как резать интерфейс

&После("ПриНачалеРаботыСистемы")
Процедура Расш1_ПриНачалеРаботыСистемы()
	
	Если Расш1_СереврПовторногоИсп.ЧтениеПодразделенийОграничено() Тогда
		Если Расш1_СереврПовторногоИсп.ОтображатьВсеПанелиИнтерфейсаПриЗапуске() Тогда  
			ОбновитьИнтерфейс = ОбщегоНазначенияВызовСервера.Расш1__ВыполнитьНастройкуПанелей(Ложь, Истина);
		Иначе
			ОбновитьИнтерфейс = ОбщегоНазначенияВызовСервера.Расш1__ВыполнитьНастройкуПанелей(Ложь, Ложь);
		КонецЕсли;
		Если ОбновитьИнтерфейс Тогда
			ОбновитьИнтерфейс();
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры


// В расширении расширяемый модуль сновной конфигурации ОбщегоНазначенияВызовСервера или создайте свой с флагом "ВызовСервера"
// Если это не зуп, то в коде ниже замените 
// Документ.ТабельУчетаРабочегоВремени на Документ.ЧегоТоТам и 
// ЖурналДокументов.Подработки на ЖурналДокументов.ЧегоТоТам

Функция Расш1__ВыполнитьНастройкуПанелей(ПолучатьСоставИзХранилища=Ложь, ВосстановитьНастройкуПанелей=Ложь) Экспорт
	
	Если ТекущийРежимЗапуска() = Неопределено Тогда
		Возврат Ложь;
	КонецЕсли;
	
	УстановитьПривилегированныйРежим(Истина);
		
	Если ПолучатьСоставИзХранилища Тогда
		НастройкиИнтерфейса = ХранилищеСистемныхНастроек.Загрузить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения");
		Если НастройкиИнтерфейса = Неопределено Тогда
			НастройкиИнтерфейса = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
		Иначе	
			НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав(); // Состав не то, что в конфигураторе, а то, что пользователь установил себе.
		КонецЕсли;
	Иначе
		НастройкиИнтерфейса = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
		НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав(); // С помощью пустого объекта настроек получим настройки состава, установленные в конфигураторе.
	КонецЕсли;
	
	Если НЕ ВосстановитьНастройкуПанелей Тогда
		
		// Очищаем настройки состава.
		НастройкиСостава.Верх.Очистить();
		НастройкиСостава.Лево.Очистить();
		НастройкиСостава.Низ.Очистить();
		НастройкиСостава.Право.Очистить();
		
		// Добавлем панели интерфейса
		ГруппаНастройкиСостава = Новый ГруппаНастройкиСоставаИнтерфейсаКлиентскогоПриложения;
		ГруппаНастройкиСостава.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельИзбранного"));
		ГруппаНастройкиСостава.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельОткрытых"));
		НастройкиСостава.Верх.Добавить(ГруппаНастройкиСостава);
		
		// Очищаем избранное
		Избранное = ХранилищеСистемныхНастроек.Загрузить("Общее/ИзбранноеРаботыПользователя");
		Если Избранное = Неопределено Тогда
			Избранное = Новый ИзбранноеРаботыПользователя;
		КонецЕсли;
		Пока Избранное.Количество() Цикл
			Избранное.Удалить(0);
		КонецЦикла;

		
		// Добавляем элементы в избранное 
		мНавигационныеСсылки = Новый Массив;
		мНавигационныеСсылки.Добавить("e1cib/list/Документ.ТабельУчетаРабочегоВремени");
		мНавигационныеСсылки.Добавить("e1cib/list/ЖурналДокументов.Подработки");
		
		Для каждого тНвСсылка Из мНавигационныеСсылки Цикл
			Элемент = Новый ЭлементИзбранногоРаботыПользователя;
			Элемент.НавигационнаяСсылка = тНвСсылка;
			Избранное.Добавить(Элемент);
		КонецЦикла;
		
		ХранилищеСистемныхНастроек.Сохранить("Общее/ИзбранноеРаботыПользователя", "", Избранное);
		  
	КонецЕсли;
	
	НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
  	ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", , НастройкиИнтерфейса); // Поместим объект настроек текущему пользователю в хранилище.
	
	Возврат Истина;
	
КонецФункции