Ошибка при вызове метода контекста (ПолучитьФайлы)

Процедура КомандаВыгрузить(Команда)
	
	ОчиститьСообщения();
	Если Объект.ПлатежныеДокументы.Количество() > 0 Тогда
		
		АдресФайлаВоВременномХранилище = ВыгрузитьДокументы();
		
		Если ПодключитьРасширениеРаботыСФайлами() Тогда
			// Вариант для установленного расширения для работы с файлами
			
			Если НЕ ЗначениеЗаполнено(Объект.ФайлВыгрузки) Тогда
				ОбщегоНазначенияКлиентСервер.СообщитьПользователю(
					НСтр("ru = 'Не указан файл данных для выгрузки из 1С:Бухгалтерии'")
					,, "Объект.ФайлВыгрузки");
				Возврат;
			КонецЕсли;
			
			ЭтоКаталог = Ложь;
			Если Прав(СокрЛП(Объект.ФайлВыгрузки), 1) = "\"
				ИЛИ Прав(СокрЛП(Объект.ФайлВыгрузки), 1) = "/" Тогда
				ЭтоКаталог   = Истина;
			ИначеЕсли Прав(СокрЛП(Объект.ФайлВыгрузки), 4) <> ".txt" Тогда
				ФайлВыгрузки = Новый Файл(Объект.ФайлВыгрузки);
				ЭтоКаталог   = ФайлВыгрузки.Существует() И ФайлВыгрузки.ЭтоКаталог();
			КонецЕсли;
			
			Если ЭтоКаталог Тогда
				ТекстСообщения = НСтр("ru = 'Файл данных для выгрузки из 1С:Бухгалтерии не корректен - выбран ""каталог"".
					|Выберите файл выгрузки'");
				ОбщегоНазначенияКлиентСервер.СообщитьПользователю(
					ТекстСообщения
					,, "Объект.ФайлВыгрузки");
				
				Возврат;
			КонецЕсли;
			
			ПередаваемыеФайлы = Новый Массив;
			ПереданныеФайлы   = Новый Массив;
			МассивВызовов 	  = Новый Массив;
			
			ОписаниеФайла = Новый ОписаниеПередаваемогоФайла(Объект.ФайлВыгрузки, АдресФайлаВоВременномХранилище);
			
			ПередаваемыеФайлы.Добавить(ОписаниеФайла);
			
			МассивВызовов.Добавить(Новый Массив);
			
			МассивВызовов[0].Добавить("ПолучитьФайлы");
			МассивВызовов[0].Добавить(ПередаваемыеФайлы);
			МассивВызовов[0].Добавить(ПереданныеФайлы);
			МассивВызовов[0].Добавить("");
			МассивВызовов[0].Добавить(Ложь);
			
			Если ЗапроситьРазрешениеПользователя(МассивВызовов) Тогда
				
				ПолучитьФайлы(ПередаваемыеФайлы, ПереданныеФайлы,, Ложь);
				ТекстЗаголовока = НСтр("ru = 'Данные успешно выгружены в файл'");
				
				#Если НЕ ВебКлиент Тогда
				ПоказатьОповещениеПользователя(
					ТекстЗаголовока, "file:///" + СтрЗаменить(СокрЛП(Объект.ФайлВыгрузки), "\", "/"),
					Объект.ФайлВыгрузки, Элементы.КомандаВыгрузить.Картинка);
				#Иначе
				ПоказатьОповещениеПользователя(
					ТекстЗаголовока,,
					Объект.ФайлВыгрузки, Элементы.КомандаВыгрузить.Картинка);
				#КонецЕсли
				
			КонецЕсли;
			
		Иначе
			// Веб клиент без расширения для работы с файлами
			Попытка
				
				ПолучитьФайл(АдресФайлаВоВременномХранилище, "1c_to_kl.txt", Истина);
				
			Исключение
				ШаблонСообщения = НСтр("ru = 'При записи файла возникла ошибка
										|%1'");
				ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ШаблонСообщения,
					КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));
				
				ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);
				ОписаниеОшибки = ИнформацияОбОшибке();
				
				ЗаписатьОшибкуВЖурнал(ТекстСообщения, ОписаниеОшибки);
				
			КонецПопытки;
			
		КонецЕсли;
		
		ЭкспортПроизведен = Истина;
		
	Иначе
		
		Если Объект.НачПериода = Объект.КонПериода Тогда
			ТекстПериода = Формат(Объект.НачПериода, "ДФ=dd.MM.yyyy");
		Иначе
			ТекстПериода = НСтр("ru = 'период с %1 по %2'");
			ТекстПериода = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ТекстПериода,
				Формат(Объект.НачПериода, "ДФ=dd.MM.yyyy"), 
				Формат(Объект.КонПериода, "ДФ=dd.MM.yyyy"));
		КонецЕсли;
		
		ТекстСообщения = НСтр("ru = 'Отсутствуют платежные поручения за %1
			|по счету %2
			|(%3).
			|
			|Попробуйте изменить период или указать другой банковский счет.'");
			
		ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			ТекстСообщения,
			ТекстПериода,
			Объект.БанковскийСчет,
			Объект.Организация);
			
		Предупреждение(ТекстСообщения);
		
	КонецЕсли;
	
	УправлениеФормой(ЭтаФорма);
	
КонецПроцедуры